arch/arm/include/asm/assembler.h

   1 /*
   2  *  arch/arm/include/asm/assembler.h
   3  *
   4  *  Copyright (C) 1996-2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  This file contains arm architecture specific defines
  11  *  for the different processors.
  12  *
  13  *  Do not include any C declarations in this file - it is included by
  14  *  assembler source.
  15  */
  16 #ifndef __ASM_ASSEMBLER_H__
  17 #define __ASM_ASSEMBLER_H__
  18
  19 #ifndef __ASSEMBLY__
  20 #error "Only include this from assembly code"
  21 #endif
  22
  23 #include <asm/ptrace.h>
  24 #include <asm/opcodes-virt.h>
  25 #include <asm/asm-offsets.h>
  26 #include <asm/page.h>
  27 #include <asm/thread_info.h>
  28 #include <asm/uaccess-asm.h>
  29
  30 #define IOMEM(x)        (x)
  31
  32 /*
  33  * Endian independent macros for shifting bytes within registers.
  34  */
  35 #ifndef __ARMEB__
  36 #define lspull          lsr
  37 #define lspush          lsl
  38 #define get_byte_0      lsl #0
  39 #define get_byte_1      lsr #8
  40 #define get_byte_2      lsr #16
  41 #define get_byte_3      lsr #24
  42 #define put_byte_0      lsl #0
  43 #define put_byte_1      lsl #8
  44 #define put_byte_2      lsl #16
  45 #define put_byte_3      lsl #24
  46 #else
  47 #define lspull          lsl
  48 #define lspush          lsr
  49 #define get_byte_0      lsr #24
  50 #define get_byte_1      lsr #16
  51 #define get_byte_2      lsr #8
  52 #define get_byte_3      lsl #0
  53 #define put_byte_0      lsl #24
  54 #define put_byte_1      lsl #16
  55 #define put_byte_2      lsl #8
  56 #define put_byte_3      lsl #0
  57 #endif
  58
  59 /* Select code for any configuration running in BE8 mode */
  60 #ifdef CONFIG_CPU_ENDIAN_BE8
  61 #define ARM_BE8(code...) code
  62 #else
  63 #define ARM_BE8(code...)
  64 #endif
  65
  66 /*
  67  * Data preload for architectures that support it
  68  */
  69 #if __LINUX_ARM_ARCH__ >= 5
  70 #define PLD(code...)    code
  71 #else
  72 #define PLD(code...)
  73 #endif
  74
  75 /*
  76  * This can be used to enable code to cacheline align the destination
  77  * pointer when bulk writing to memory.  Experiments on StrongARM and
  78  * XScale didn't show this a worthwhile thing to do when the cache is not
  79  * set to write-allocate (this would need further testing on XScale when WA
  80  * is used).
  81  *
  82  * On Feroceon there is much to gain however, regardless of cache mode.
  83  */
  84 #ifdef CONFIG_CPU_FEROCEON
  85 #define CALGN(code...) code
  86 #else
  87 #define CALGN(code...)
  88 #endif
  89
  90 #define IMM12_MASK 0xfff
  91
  92 /*
  93  * Enable and disable interrupts
  94  */
  95 #if __LINUX_ARM_ARCH__ >= 6
  96         .macro  disable_irq_notrace
  97         cpsid   i
  98         .endm
  99
 100         .macro  enable_irq_notrace
 101         cpsie   i
 102         .endm
 103 #else
 104         .macro  disable_irq_notrace
 105         msr     cpsr_c, #PSR_I_BIT | SVC_MODE
 106         .endm
 107
 108         .macro  enable_irq_notrace
 109         msr     cpsr_c, #SVC_MODE
 110         .endm
 111 #endif
 112
 113 #if __LINUX_ARM_ARCH__ < 7
 114         .macro  dsb, args
 115         mcr     p15, 0, r0, c7, c10, 4
 116         .endm
 117
 118         .macro  isb, args
 119         mcr     p15, 0, r0, c7, c5, 4
 120         .endm
 121 #endif
 122
 123         .macro asm_trace_hardirqs_off, save=1
 124 #if defined(CONFIG_TRACE_IRQFLAGS)
 125         .if \save
 126         stmdb   sp!, {r0-r3, ip, lr}
 127         .endif
 128         bl      trace_hardirqs_off
 129         .if \save
 130         ldmia   sp!, {r0-r3, ip, lr}
 131         .endif
 132 #endif
 133         .endm
 134
 135         .macro asm_trace_hardirqs_on, cond=al, save=1
 136 #if defined(CONFIG_TRACE_IRQFLAGS)
 137         /*
 138          * actually the registers should be pushed and pop'd conditionally, but
 139          * after bl the flags are certainly clobbered
 140          */
 141         .if \save
 142         stmdb   sp!, {r0-r3, ip, lr}
 143         .endif
 144         bl\cond trace_hardirqs_on
 145         .if \save
 146         ldmia   sp!, {r0-r3, ip, lr}
 147         .endif
 148 #endif
 149         .endm
 150
 151         .macro disable_irq, save=1
 152         disable_irq_notrace
 153         asm_trace_hardirqs_off \save
 154         .endm
 155
 156         .macro enable_irq
 157         asm_trace_hardirqs_on
 158         enable_irq_notrace
 159         .endm
 160 /*
 161  * Save the current IRQ state and disable IRQs.  Note that this macro
 162  * assumes FIQs are enabled, and that the processor is in SVC mode.
 163  */
 164         .macro  save_and_disable_irqs, oldcpsr
 165 #ifdef CONFIG_CPU_V7M
 166         mrs     \oldcpsr, primask
 167 #else
 168         mrs     \oldcpsr, cpsr
 169 #endif
 170         disable_irq
 171         .endm
 172
 173         .macro  save_and_disable_irqs_notrace, oldcpsr
 174 #ifdef CONFIG_CPU_V7M
 175         mrs     \oldcpsr, primask
 176 #else
 177         mrs     \oldcpsr, cpsr
 178 #endif
 179         disable_irq_notrace
 180         .endm
 181
 182 /*
 183  * Restore interrupt state previously stored in a register.  We don't
 184  * guarantee that this will preserve the flags.
 185  */
 186         .macro  restore_irqs_notrace, oldcpsr
 187 #ifdef CONFIG_CPU_V7M
 188         msr     primask, \oldcpsr
 189 #else
 190         msr     cpsr_c, \oldcpsr
 191 #endif
 192         .endm
 193
 194         .macro restore_irqs, oldcpsr
 195         tst     \oldcpsr, #PSR_I_BIT
 196         asm_trace_hardirqs_on cond=eq
 197         restore_irqs_notrace \oldcpsr
 198         .endm
 199
 200 /*
 201  * Assembly version of "adr rd, BSYM(sym)".  This should only be used to
 202  * reference local symbols in the same assembly file which are to be
 203  * resolved by the assembler.  Other usage is undefined.
 204  */
 205         .irp    c,,eq,ne,cs,cc,mi,pl,vs,vc,hi,ls,ge,lt,gt,le,hs,lo
 206         .macro  badr\c, rd, sym
 207 #ifdef CONFIG_THUMB2_KERNEL
 208         adr\c   \rd, \sym + 1
 209 #else
 210         adr\c   \rd, \sym
 211 #endif
 212         .endm
 213         .endr
 214
 215 /*
 216  * Get current thread_info.
 217  */
 218         .macro  get_thread_info, rd
 219  ARM(   mov     \rd, sp, lsr #THREAD_SIZE_ORDER + PAGE_SHIFT    )
 220  THUMB( mov     \rd, sp                 )
 221  THUMB( lsr     \rd, \rd, #THREAD_SIZE_ORDER + PAGE_SHIFT       )
 222         mov     \rd, \rd, lsl #THREAD_SIZE_ORDER + PAGE_SHIFT
 223         .endm
 224
 225 /*
 226  * Increment/decrement the preempt count.
 227  */
 228 #ifdef CONFIG_PREEMPT_COUNT
 229         .macro  inc_preempt_count, ti, tmp
 230         ldr     \tmp, [\ti, #TI_PREEMPT]        @ get preempt count
 231         add     \tmp, \tmp, #1                  @ increment it
 232         str     \tmp, [\ti, #TI_PREEMPT]
 233         .endm
 234
 235         .macro  dec_preempt_count, ti, tmp
 236         ldr     \tmp, [\ti, #TI_PREEMPT]        @ get preempt count
 237         sub     \tmp, \tmp, #1                  @ decrement it
 238         str     \tmp, [\ti, #TI_PREEMPT]
 239         .endm
 240
 241         .macro  dec_preempt_count_ti, ti, tmp
 242         get_thread_info \ti
 243         dec_preempt_count \ti, \tmp
 244         .endm
 245 #else
 246         .macro  inc_preempt_count, ti, tmp
 247         .endm
 248
 249         .macro  dec_preempt_count, ti, tmp
 250         .endm
 251
 252         .macro  dec_preempt_count_ti, ti, tmp
 253         .endm
 254 #endif
 255
 256 #define USER(x...)                              \
 257 9999:   x;                                      \
 258         .pushsection __ex_table,"a";            \
 259         .align  3;                              \
 260         .long   9999b,9001f;                    \
 261         .popsection
 262
 263 #ifdef CONFIG_SMP
 264 #define ALT_SMP(instr...)                                       \
 265 9998:   instr
 266 /*
 267  * Note: if you get assembler errors from ALT_UP() when building with
 268  * CONFIG_THUMB2_KERNEL, you almost certainly need to use
 269  * ALT_SMP( W(instr) ... )
 270  */
 271 #define ALT_UP(instr...)                                        \
 272         .pushsection ".alt.smp.init", "a"                       ;\
 273         .long   9998b                                           ;\
 274 9997:   instr                                                   ;\
 275         .if . - 9997b == 2                                      ;\
 276                 nop                                             ;\
 277         .endif                                                  ;\
 278         .if . - 9997b != 4                                      ;\
 279                 .error "ALT_UP() content must assemble to exactly 4 bytes";\
 280         .endif                                                  ;\
 281         .popsection
 282 #define ALT_UP_B(label)                                 \
 283         .equ    up_b_offset, label - 9998b                      ;\
 284         .pushsection ".alt.smp.init", "a"                       ;\
 285         .long   9998b                                           ;\
 286         W(b)    . + up_b_offset                                 ;\
 287         .popsection
 288 #else
 289 #define ALT_SMP(instr...)
 290 #define ALT_UP(instr...) instr
 291 #define ALT_UP_B(label) b label
 292 #endif
 293
 294 /*
 295  * Instruction barrier
 296  */
 297         .macro  instr_sync
 298 #if __LINUX_ARM_ARCH__ >= 7
 299         isb
 300 #elif __LINUX_ARM_ARCH__ == 6
 301         mcr     p15, 0, r0, c7, c5, 4
 302 #endif
 303         .endm
 304
 305 /*
 306  * SMP data memory barrier
 307  */
 308         .macro  smp_dmb mode
 309 #ifdef CONFIG_SMP
 310 #if __LINUX_ARM_ARCH__ >= 7
 311         .ifeqs "\mode","arm"
 312         ALT_SMP(dmb     ish)
 313         .else
 314         ALT_SMP(W(dmb)  ish)
 315         .endif
 316 #elif __LINUX_ARM_ARCH__ == 6
 317         ALT_SMP(mcr     p15, 0, r0, c7, c10, 5) @ dmb
 318 #else
 319 #error Incompatible SMP platform
 320 #endif
 321         .ifeqs "\mode","arm"
 322         ALT_UP(nop)
 323         .else
 324         ALT_UP(W(nop))
 325         .endif
 326 #endif
 327         .endm
 328
 329 #if defined(CONFIG_CPU_V7M)
 330         /*
 331          * setmode is used to assert to be in svc mode during boot. For v7-M
 332          * this is done in __v7m_setup, so setmode can be empty here.
 333          */
 334         .macro  setmode, mode, reg
 335         .endm
 336 #elif defined(CONFIG_THUMB2_KERNEL)
 337         .macro  setmode, mode, reg
 338         mov     \reg, #\mode
 339         msr     cpsr_c, \reg
 340         .endm
 341 #else
 342         .macro  setmode, mode, reg
 343         msr     cpsr_c, #\mode
 344         .endm
 345 #endif
 346
 347 /*
 348  * Helper macro to enter SVC mode cleanly and mask interrupts. reg is
 349  * a scratch register for the macro to overwrite.
 350  *
 351  * This macro is intended for forcing the CPU into SVC mode at boot time.
 352  * you cannot return to the original mode.
 353  */
 354 .macro safe_svcmode_maskall reg:req
 355 #if __LINUX_ARM_ARCH__ >= 6 && !defined(CONFIG_CPU_V7M)
 356         mrs     \reg , cpsr
 357         eor     \reg, \reg, #HYP_MODE
 358         tst     \reg, #MODE_MASK
 359         bic     \reg , \reg , #MODE_MASK
 360         orr     \reg , \reg , #PSR_I_BIT | PSR_F_BIT | SVC_MODE
 361 THUMB(  orr     \reg , \reg , #PSR_T_BIT        )
 362         bne     1f
 363         orr     \reg, \reg, #PSR_A_BIT
 364         badr    lr, 2f
 365         msr     spsr_cxsf, \reg
 366         __MSR_ELR_HYP(14)
 367         __ERET
 368 1:      msr     cpsr_c, \reg
 369 2:
 370 #else
 371 /*
 372  * workaround for possibly broken pre-v6 hardware
 373  * (akita, Sharp Zaurus C-1000, PXA270-based)
 374  */
 375         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, \reg
 376 #endif
 377 .endm
 378
 379 /*
 380  * STRT/LDRT access macros with ARM and Thumb-2 variants
 381  */
 382 #ifdef CONFIG_THUMB2_KERNEL
 383
 384         .macro  usraccoff, instr, reg, ptr, inc, off, cond, abort, t=TUSER()
 385 9999:
 386         .if     \inc == 1
 387         \instr\()b\t\cond\().w \reg, [\ptr, #\off]
 388         .elseif \inc == 4
 389         \instr\t\cond\().w \reg, [\ptr, #\off]
 390         .else
 391         .error  "Unsupported inc macro argument"
 392         .endif
 393
 394         .pushsection __ex_table,"a"
 395         .align  3
 396         .long   9999b, \abort
 397         .popsection
 398         .endm
 399
 400         .macro  usracc, instr, reg, ptr, inc, cond, rept, abort
 401         @ explicit IT instruction needed because of the label
 402         @ introduced by the USER macro
 403         .ifnc   \cond,al
 404         .if     \rept == 1
 405         itt     \cond
 406         .elseif \rept == 2
 407         ittt    \cond
 408         .else
 409         .error  "Unsupported rept macro argument"
 410         .endif
 411         .endif
 412
 413         @ Slightly optimised to avoid incrementing the pointer twice
 414         usraccoff \instr, \reg, \ptr, \inc, 0, \cond, \abort
 415         .if     \rept == 2
 416         usraccoff \instr, \reg, \ptr, \inc, \inc, \cond, \abort
 417         .endif
 418
 419         add\cond \ptr, #\rept * \inc
 420         .endm
 421
 422 #else   /* !CONFIG_THUMB2_KERNEL */
 423
 424         .macro  usracc, instr, reg, ptr, inc, cond, rept, abort, t=TUSER()
 425         .rept   \rept
 426 9999:
 427         .if     \inc == 1
 428         \instr\()b\t\cond \reg, [\ptr], #\inc
 429         .elseif \inc == 4
 430         \instr\t\cond \reg, [\ptr], #\inc
 431         .else
 432         .error  "Unsupported inc macro argument"
 433         .endif
 434
 435         .pushsection __ex_table,"a"
 436         .align  3
 437         .long   9999b, \abort
 438         .popsection
 439         .endr
 440         .endm
 441
 442 #endif  /* CONFIG_THUMB2_KERNEL */
 443
 444         .macro  strusr, reg, ptr, inc, cond=al, rept=1, abort=9001f
 445         usracc  str, \reg, \ptr, \inc, \cond, \rept, \abort
 446         .endm
 447
 448         .macro  ldrusr, reg, ptr, inc, cond=al, rept=1, abort=9001f
 449         usracc  ldr, \reg, \ptr, \inc, \cond, \rept, \abort
 450         .endm
 451
 452 /* Utility macro for declaring string literals */
 453         .macro  string name:req, string
 454         .type \name , #object
 455 \name:
 456         .asciz "\string"
 457         .size \name , . - \name
 458         .endm
 459
 460         .irp    c,,eq,ne,cs,cc,mi,pl,vs,vc,hi,ls,ge,lt,gt,le,hs,lo
 461         .macro  ret\c, reg
 462 #if __LINUX_ARM_ARCH__ < 6
 463         mov\c   pc, \reg
 464 #else
 465         .ifeqs  "\reg", "lr"
 466         bx\c    \reg
 467         .else
 468         mov\c   pc, \reg
 469         .endif
 470 #endif
 471         .endm
 472         .endr
 473
 474         .macro  ret.w, reg
 475         ret     \reg
 476 #ifdef CONFIG_THUMB2_KERNEL
 477         nop
 478 #endif
 479         .endm
 480
 481         .macro  bug, msg, line
 482 #ifdef CONFIG_THUMB2_KERNEL
 483 1:      .inst   0xde02
 484 #else
 485 1:      .inst   0xe7f001f2
 486 #endif
 487 #ifdef CONFIG_DEBUG_BUGVERBOSE
 488         .pushsection .rodata.str, "aMS", %progbits, 1
 489 2:      .asciz  "\msg"
 490         .popsection
 491         .pushsection __bug_table, "aw"
 492         .align  2
 493         .word   1b, 2b
 494         .hword  \line
 495         .popsection
 496 #endif
 497         .endm
 498
 499 #ifdef CONFIG_KPROBES
 500 #define _ASM_NOKPROBE(entry)                            \
 501         .pushsection "_kprobe_blacklist", "aw" ;        \
 502         .balign 4 ;                                     \
 503         .long entry;                                    \
 504         .popsection
 505 #else
 506 #define _ASM_NOKPROBE(entry)
 507 #endif
 508
 509 #endif /* __ASM_ASSEMBLER_H__ */