arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15 #include <asm/memory.h>
  16 #ifdef CONFIG_AEABI
  17 #include <asm/unistd-oabi.h>
  18 #endif
  19
  20         .equ    NR_syscalls, __NR_syscalls
  21
  22 #ifdef CONFIG_NEED_RET_TO_USER
  23 #include <mach/entry-macro.S>
  24 #else
  25         .macro  arch_ret_to_user, tmp1, tmp2
  26         .endm
  27 #endif
  28
  29 #include "entry-header.S"
  30
  31 saved_psr       .req    r8
  32 #if defined(CONFIG_TRACE_IRQFLAGS) || defined(CONFIG_CONTEXT_TRACKING)
  33 saved_pc        .req    r9
  34 #define TRACE(x...) x
  35 #else
  36 saved_pc        .req    lr
  37 #define TRACE(x...)
  38 #endif
  39
  40         .section .entry.text,"ax",%progbits
  41         .align  5
  42 #if !(IS_ENABLED(CONFIG_TRACE_IRQFLAGS) || IS_ENABLED(CONFIG_CONTEXT_TRACKING) || \
  43         IS_ENABLED(CONFIG_DEBUG_RSEQ))
  44 /*
  45  * This is the fast syscall return path.  We do as little as possible here,
  46  * such as avoiding writing r0 to the stack.  We only use this path if we
  47  * have tracing, context tracking and rseq debug disabled - the overheads
  48  * from those features make this path too inefficient.
  49  */
  50 ret_fast_syscall:
  51 __ret_fast_syscall:
  52  UNWIND(.fnstart        )
  53  UNWIND(.cantunwind     )
  54         disable_irq_notrace                     @ disable interrupts
  55         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  56         cmp     r2, #TASK_SIZE
  57         blne    addr_limit_check_failed
  58         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  59         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  60         bne     fast_work_pending
  61
  62
  63         /* perform architecture specific actions before user return */
  64         arch_ret_to_user r1, lr
  65
  66         restore_user_regs fast = 1, offset = S_OFF
  67  UNWIND(.fnend          )
  68 ENDPROC(ret_fast_syscall)
  69
  70         /* Ok, we need to do extra processing, enter the slow path. */
  71 fast_work_pending:
  72         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  73         /* fall through to work_pending */
  74 #else
  75 /*
  76  * The "replacement" ret_fast_syscall for when tracing, context tracking,
  77  * or rseq debug is enabled.  As we will need to call out to some C functions,
  78  * we save r0 first to avoid needing to save registers around each C function
  79  * call.
  80  */
  81 ret_fast_syscall:
  82 __ret_fast_syscall:
  83  UNWIND(.fnstart        )
  84  UNWIND(.cantunwind     )
  85         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
  86 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
  87         /* do_rseq_syscall needs interrupts enabled. */
  88         mov     r0, sp                          @ 'regs'
  89         bl      do_rseq_syscall
  90 #endif
  91         disable_irq_notrace                     @ disable interrupts
  92         ldr     r2, [tsk, #TI_ADDR_LIMIT]
  93         cmp     r2, #TASK_SIZE
  94         blne    addr_limit_check_failed
  95         ldr     r1, [tsk, #TI_FLAGS]            @ re-check for syscall tracing
  96         tst     r1, #_TIF_SYSCALL_WORK | _TIF_WORK_MASK
  97         beq     no_work_pending
  98  UNWIND(.fnend          )
  99 ENDPROC(ret_fast_syscall)
 100
 101         /* Slower path - fall through to work_pending */
 102 #endif
 103
 104         tst     r1, #_TIF_SYSCALL_WORK
 105         bne     __sys_trace_return_nosave
 106 slow_work_pending:
 107         mov     r0, sp                          @ 'regs'
 108         mov     r2, why                         @ 'syscall'
 109         bl      do_work_pending
 110         cmp     r0, #0
 111         beq     no_work_pending
 112         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
 113         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
 114         b       local_restart                   @ ... and off we go
 115 ENDPROC(ret_fast_syscall)
 116
 117 /*
 118  * "slow" syscall return path.  "why" tells us if this was a real syscall.
 119  * IRQs may be enabled here, so always disable them.  Note that we use the
 120  * "notrace" version to avoid calling into the tracing code unnecessarily.
 121  * do_work_pending() will update this state if necessary.
 122  */
 123 ENTRY(ret_to_user)
 124 ret_slow_syscall:
 125 #if IS_ENABLED(CONFIG_DEBUG_RSEQ)
 126         /* do_rseq_syscall needs interrupts enabled. */
 127         enable_irq_notrace                      @ enable interrupts
 128         mov     r0, sp                          @ 'regs'
 129         bl      do_rseq_syscall
 130 #endif
 131         disable_irq_notrace                     @ disable interrupts
 132 ENTRY(ret_to_user_from_irq)
 133         ldr     r2, [tsk, #TI_ADDR_LIMIT]
 134         cmp     r2, #TASK_SIZE
 135         blne    addr_limit_check_failed
 136         ldr     r1, [tsk, #TI_FLAGS]
 137         tst     r1, #_TIF_WORK_MASK
 138         bne     slow_work_pending
 139 no_work_pending:
 140         asm_trace_hardirqs_on save = 0
 141
 142         /* perform architecture specific actions before user return */
 143         arch_ret_to_user r1, lr
 144         ct_user_enter save = 0
 145
 146         restore_user_regs fast = 0, offset = 0
 147 ENDPROC(ret_to_user_from_irq)
 148 ENDPROC(ret_to_user)
 149
 150 /*
 151  * This is how we return from a fork.
 152  */
 153 ENTRY(ret_from_fork)
 154         bl      schedule_tail
 155         cmp     r5, #0
 156         movne   r0, r4
 157         badrne  lr, 1f
 158         retne   r5
 159 1:      get_thread_info tsk
 160         b       ret_slow_syscall
 161 ENDPROC(ret_from_fork)
 162
 163 /*=============================================================================
 164  * SWI handler
 165  *-----------------------------------------------------------------------------
 166  */
 167
 168         .align  5
 169 #ifdef CONFIG_HARDEN_BRANCH_HISTORY
 170 ENTRY(vector_bhb_loop8_swi)
 171         sub     sp, sp, #PT_REGS_SIZE
 172         stmia   sp, {r0 - r12}
 173         mov     r8, #8
 174 1:      b       2f
 175 2:      subs    r8, r8, #1
 176         bne     1b
 177         dsb
 178         isb
 179         b       3f
 180 ENDPROC(vector_bhb_loop8_swi)
 181
 182         .align  5
 183 ENTRY(vector_bhb_bpiall_swi)
 184         sub     sp, sp, #PT_REGS_SIZE
 185         stmia   sp, {r0 - r12}
 186         mcr     p15, 0, r8, c7, c5, 6   @ BPIALL
 187         isb
 188         b       3f
 189 ENDPROC(vector_bhb_bpiall_swi)
 190 #endif
 191         .align  5
 192 ENTRY(vector_swi)
 193 #ifdef CONFIG_CPU_V7M
 194         v7m_exception_entry
 195 #else
 196         sub     sp, sp, #PT_REGS_SIZE
 197         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 198 3:
 199  ARM(   add     r8, sp, #S_PC           )
 200  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 201  THUMB( mov     r8, sp                  )
 202  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 203         mrs     saved_psr, spsr                 @ called from non-FIQ mode, so ok.
 204  TRACE( mov     saved_pc, lr            )
 205         str     saved_pc, [sp, #S_PC]           @ Save calling PC
 206         str     saved_psr, [sp, #S_PSR]         @ Save CPSR
 207         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 208 #endif
 209         zero_fp
 210         alignment_trap r10, ip, __cr_alignment
 211         asm_trace_hardirqs_on save=0
 212         enable_irq_notrace
 213         ct_user_exit save=0
 214
 215         /*
 216          * Get the system call number.
 217          */
 218
 219 #if defined(CONFIG_OABI_COMPAT)
 220
 221         /*
 222          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 223          * value to determine if it is an EABI or an old ABI call.
 224          */
 225 #ifdef CONFIG_ARM_THUMB
 226         tst     saved_psr, #PSR_T_BIT
 227         movne   r10, #0                         @ no thumb OABI emulation
 228  USER(  ldreq   r10, [saved_pc, #-4]    )       @ get SWI instruction
 229 #else
 230  USER(  ldr     r10, [saved_pc, #-4]    )       @ get SWI instruction
 231 #endif
 232  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 233
 234 #elif defined(CONFIG_AEABI)
 235
 236         /*
 237          * Pure EABI user space always put syscall number into scno (r7).
 238          */
 239 #elif defined(CONFIG_ARM_THUMB)
 240         /* Legacy ABI only, possibly thumb mode. */
 241         tst     saved_psr, #PSR_T_BIT           @ this is SPSR from save_user_regs
 242         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 243  USER(  ldreq   scno, [saved_pc, #-4]   )
 244
 245 #else
 246         /* Legacy ABI only. */
 247  USER(  ldr     scno, [saved_pc, #-4]   )       @ get SWI instruction
 248 #endif
 249
 250         /* saved_psr and saved_pc are now dead */
 251
 252         uaccess_disable tbl
 253
 254         adr     tbl, sys_call_table             @ load syscall table pointer
 255
 256 #if defined(CONFIG_OABI_COMPAT)
 257         /*
 258          * If the swi argument is zero, this is an EABI call and we do nothing.
 259          *
 260          * If this is an old ABI call, get the syscall number into scno and
 261          * get the old ABI syscall table address.
 262          */
 263         bics    r10, r10, #0xff000000
 264         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 265         ldrne   tbl, =sys_oabi_call_table
 266 #elif !defined(CONFIG_AEABI)
 267         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 268         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 269 #endif
 270         get_thread_info tsk
 271         /*
 272          * Reload the registers that may have been corrupted on entry to
 273          * the syscall assembly (by tracing or context tracking.)
 274          */
 275  TRACE( ldmia   sp, {r0 - r3}           )
 276
 277 local_restart:
 278         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 279         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 280
 281         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 282         bne     __sys_trace
 283
 284         invoke_syscall tbl, scno, r10, __ret_fast_syscall
 285
 286         add     r1, sp, #S_OFF
 287 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 288         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 289         bcs     arm_syscall
 290         mov     why, #0                         @ no longer a real syscall
 291         b       sys_ni_syscall                  @ not private func
 292
 293 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 294         /*
 295          * We failed to handle a fault trying to access the page
 296          * containing the swi instruction, but we're not really in a
 297          * position to return -EFAULT. Instead, return back to the
 298          * instruction and re-enter the user fault handling path trying
 299          * to page it in. This will likely result in sending SEGV to the
 300          * current task.
 301          */
 302 9001:
 303         sub     lr, saved_pc, #4
 304         str     lr, [sp, #S_PC]
 305         get_thread_info tsk
 306         b       ret_fast_syscall
 307 #endif
 308 ENDPROC(vector_swi)
 309
 310         /*
 311          * This is the really slow path.  We're going to be doing
 312          * context switches, and waiting for our parent to respond.
 313          */
 314 __sys_trace:
 315         mov     r1, scno
 316         add     r0, sp, #S_OFF
 317         bl      syscall_trace_enter
 318         mov     scno, r0
 319         invoke_syscall tbl, scno, r10, __sys_trace_return, reload=1
 320         cmp     scno, #-1                       @ skip the syscall?
 321         bne     2b
 322         add     sp, sp, #S_OFF                  @ restore stack
 323
 324 __sys_trace_return_nosave:
 325         enable_irq_notrace
 326         mov     r0, sp
 327         bl      syscall_trace_exit
 328         b       ret_slow_syscall
 329
 330 __sys_trace_return:
 331         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 332         mov     r0, sp
 333         bl      syscall_trace_exit
 334         b       ret_slow_syscall
 335
 336         .align  5
 337 #ifdef CONFIG_ALIGNMENT_TRAP
 338         .type   __cr_alignment, #object
 339 __cr_alignment:
 340         .word   cr_alignment
 341 #endif
 342         .ltorg
 343
 344         .macro  syscall_table_start, sym
 345         .equ    __sys_nr, 0
 346         .type   \sym, #object
 347 ENTRY(\sym)
 348         .endm
 349
 350         .macro  syscall, nr, func
 351         .ifgt   __sys_nr - \nr
 352         .error  "Duplicated/unorded system call entry"
 353         .endif
 354         .rept   \nr - __sys_nr
 355         .long   sys_ni_syscall
 356         .endr
 357         .long   \func
 358         .equ    __sys_nr, \nr + 1
 359         .endm
 360
 361         .macro  syscall_table_end, sym
 362         .ifgt   __sys_nr - __NR_syscalls
 363         .error  "System call table too big"
 364         .endif
 365         .rept   __NR_syscalls - __sys_nr
 366         .long   sys_ni_syscall
 367         .endr
 368         .size   \sym, . - \sym
 369         .endm
 370
 371 #define NATIVE(nr, func) syscall nr, func
 372
 373 /*
 374  * This is the syscall table declaration for native ABI syscalls.
 375  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 376  */
 377         syscall_table_start sys_call_table
 378 #define COMPAT(nr, native, compat) syscall nr, native
 379 #ifdef CONFIG_AEABI
 380 #include <calls-eabi.S>
 381 #else
 382 #include <calls-oabi.S>
 383 #endif
 384 #undef COMPAT
 385         syscall_table_end sys_call_table
 386
 387 /*============================================================================
 388  * Special system call wrappers
 389  */
 390 @ r0 = syscall number
 391 @ r8 = syscall table
 392 sys_syscall:
 393                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 394                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 395                 cmpne   scno, #NR_syscalls      @ check range
 396 #ifdef CONFIG_CPU_SPECTRE
 397                 movhs   scno, #0
 398                 csdb
 399 #endif
 400                 stmloia sp, {r5, r6}            @ shuffle args
 401                 movlo   r0, r1
 402                 movlo   r1, r2
 403                 movlo   r2, r3
 404                 movlo   r3, r4
 405                 ldrlo   pc, [tbl, scno, lsl #2]
 406                 b       sys_ni_syscall
 407 ENDPROC(sys_syscall)
 408
 409 sys_sigreturn_wrapper:
 410                 add     r0, sp, #S_OFF
 411                 mov     why, #0         @ prevent syscall restart handling
 412                 b       sys_sigreturn
 413 ENDPROC(sys_sigreturn_wrapper)
 414
 415 sys_rt_sigreturn_wrapper:
 416                 add     r0, sp, #S_OFF
 417                 mov     why, #0         @ prevent syscall restart handling
 418                 b       sys_rt_sigreturn
 419 ENDPROC(sys_rt_sigreturn_wrapper)
 420
 421 sys_statfs64_wrapper:
 422                 teq     r1, #88
 423                 moveq   r1, #84
 424                 b       sys_statfs64
 425 ENDPROC(sys_statfs64_wrapper)
 426
 427 sys_fstatfs64_wrapper:
 428                 teq     r1, #88
 429                 moveq   r1, #84
 430                 b       sys_fstatfs64
 431 ENDPROC(sys_fstatfs64_wrapper)
 432
 433 /*
 434  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 435  * offset, we return EINVAL.
 436  */
 437 sys_mmap2:
 438                 str     r5, [sp, #4]
 439                 b       sys_mmap_pgoff
 440 ENDPROC(sys_mmap2)
 441
 442 #ifdef CONFIG_OABI_COMPAT
 443
 444 /*
 445  * These are syscalls with argument register differences
 446  */
 447
 448 sys_oabi_pread64:
 449                 stmia   sp, {r3, r4}
 450                 b       sys_pread64
 451 ENDPROC(sys_oabi_pread64)
 452
 453 sys_oabi_pwrite64:
 454                 stmia   sp, {r3, r4}
 455                 b       sys_pwrite64
 456 ENDPROC(sys_oabi_pwrite64)
 457
 458 sys_oabi_truncate64:
 459                 mov     r3, r2
 460                 mov     r2, r1
 461                 b       sys_truncate64
 462 ENDPROC(sys_oabi_truncate64)
 463
 464 sys_oabi_ftruncate64:
 465                 mov     r3, r2
 466                 mov     r2, r1
 467                 b       sys_ftruncate64
 468 ENDPROC(sys_oabi_ftruncate64)
 469
 470 sys_oabi_readahead:
 471                 str     r3, [sp]
 472                 mov     r3, r2
 473                 mov     r2, r1
 474                 b       sys_readahead
 475 ENDPROC(sys_oabi_readahead)
 476
 477 /*
 478  * Let's declare a second syscall table for old ABI binaries
 479  * using the compatibility syscall entries.
 480  */
 481         syscall_table_start sys_oabi_call_table
 482 #define COMPAT(nr, native, compat) syscall nr, compat
 483 #include <calls-oabi.S>
 484         syscall_table_end sys_oabi_call_table
 485
 486 #endif
 487