arch/arm64/kernel/entry-ftrace.S

   1 /*
   2  * arch/arm64/kernel/entry-ftrace.S
   3  *
   4  * Copyright (C) 2013 Linaro Limited
   5  * Author: AKASHI Takahiro <takahiro.akashi@linaro.org>
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  */
  11
  12 #include <linux/linkage.h>
  13 #include <asm/assembler.h>
  14 #include <asm/ftrace.h>
  15 #include <asm/insn.h>
  16
  17 /*
  18  * Gcc with -pg will put the following code in the beginning of each function:
  19  *      mov x0, x30
  20  *      bl _mcount
  21  *      [function's body ...]
  22  * "bl _mcount" may be replaced to "bl ftrace_caller" or NOP if dynamic
  23  * ftrace is enabled.
  24  *
  25  * Please note that x0 as an argument will not be used here because we can
  26  * get lr(x30) of instrumented function at any time by winding up call stack
  27  * as long as the kernel is compiled without -fomit-frame-pointer.
  28  * (or CONFIG_FRAME_POINTER, this is forced on arm64)
  29  *
  30  * stack layout after mcount_enter in _mcount():
  31  *
  32  * current sp/fp =>  0:+-----+
  33  * in _mcount()        | x29 | -> instrumented function's fp
  34  *                     +-----+
  35  *                     | x30 | -> _mcount()'s lr (= instrumented function's pc)
  36  * old sp       => +16:+-----+
  37  * when instrumented   |     |
  38  * function calls      | ... |
  39  * _mcount()           |     |
  40  *                     |     |
  41  * instrumented => +xx:+-----+
  42  * function's fp       | x29 | -> parent's fp
  43  *                     +-----+
  44  *                     | x30 | -> instrumented function's lr (= parent's pc)
  45  *                     +-----+
  46  *                     | ... |
  47  */
  48
  49         .macro mcount_enter
  50         stp     x29, x30, [sp, #-16]!
  51         mov     x29, sp
  52         .endm
  53
  54         .macro mcount_exit
  55         ldp     x29, x30, [sp], #16
  56         ret
  57         .endm
  58
  59         .macro mcount_adjust_addr rd, rn
  60         sub     \rd, \rn, #AARCH64_INSN_SIZE
  61         .endm
  62
  63         /* for instrumented function's parent */
  64         .macro mcount_get_parent_fp reg
  65         ldr     \reg, [x29]
  66         ldr     \reg, [\reg]
  67         .endm
  68
  69         /* for instrumented function */
  70         .macro mcount_get_pc0 reg
  71         mcount_adjust_addr      \reg, x30
  72         .endm
  73
  74         .macro mcount_get_pc reg
  75         ldr     \reg, [x29, #8]
  76         mcount_adjust_addr      \reg, \reg
  77         .endm
  78
  79         .macro mcount_get_lr reg
  80         ldr     \reg, [x29]
  81         ldr     \reg, [\reg, #8]
  82         .endm
  83
  84         .macro mcount_get_lr_addr reg
  85         ldr     \reg, [x29]
  86         add     \reg, \reg, #8
  87         .endm
  88
  89 #ifndef CONFIG_DYNAMIC_FTRACE
  90 /*
  91  * void _mcount(unsigned long return_address)
  92  * @return_address: return address to instrumented function
  93  *
  94  * This function makes calls, if enabled, to:
  95  *     - tracer function to probe instrumented function's entry,
  96  *     - ftrace_graph_caller to set up an exit hook
  97  */
  98 ENTRY(_mcount)
  99         mcount_enter
 100
 101         ldr_l   x2, ftrace_trace_function
 102         adr     x0, ftrace_stub
 103         cmp     x0, x2                  // if (ftrace_trace_function
 104         b.eq    skip_ftrace_call        //     != ftrace_stub) {
 105
 106         mcount_get_pc   x0              //       function's pc
 107         mcount_get_lr   x1              //       function's lr (= parent's pc)
 108         blr     x2                      //   (*ftrace_trace_function)(pc, lr);
 109
 110 #ifndef CONFIG_FUNCTION_GRAPH_TRACER
 111 skip_ftrace_call:                       //   return;
 112         mcount_exit                     // }
 113 #else
 114         mcount_exit                     //   return;
 115                                         // }
 116 skip_ftrace_call:
 117         ldr_l   x2, ftrace_graph_return
 118         cmp     x0, x2                  //   if ((ftrace_graph_return
 119         b.ne    ftrace_graph_caller     //        != ftrace_stub)
 120
 121         ldr_l   x2, ftrace_graph_entry  //     || (ftrace_graph_entry
 122         adr_l   x0, ftrace_graph_entry_stub //     != ftrace_graph_entry_stub))
 123         cmp     x0, x2
 124         b.ne    ftrace_graph_caller     //     ftrace_graph_caller();
 125
 126         mcount_exit
 127 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
 128 ENDPROC(_mcount)
 129
 130 #else /* CONFIG_DYNAMIC_FTRACE */
 131 /*
 132  * _mcount() is used to build the kernel with -pg option, but all the branch
 133  * instructions to _mcount() are replaced to NOP initially at kernel start up,
 134  * and later on, NOP to branch to ftrace_caller() when enabled or branch to
 135  * NOP when disabled per-function base.
 136  */
 137 ENTRY(_mcount)
 138         ret
 139 ENDPROC(_mcount)
 140
 141 /*
 142  * void ftrace_caller(unsigned long return_address)
 143  * @return_address: return address to instrumented function
 144  *
 145  * This function is a counterpart of _mcount() in 'static' ftrace, and
 146  * makes calls to:
 147  *     - tracer function to probe instrumented function's entry,
 148  *     - ftrace_graph_caller to set up an exit hook
 149  */
 150 ENTRY(ftrace_caller)
 151         mcount_enter
 152
 153         mcount_get_pc0  x0              //     function's pc
 154         mcount_get_lr   x1              //     function's lr
 155
 156         .global ftrace_call
 157 ftrace_call:                            // tracer(pc, lr);
 158         nop                             // This will be replaced with "bl xxx"
 159                                         // where xxx can be any kind of tracer.
 160
 161 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 162         .global ftrace_graph_call
 163 ftrace_graph_call:                      // ftrace_graph_caller();
 164         nop                             // If enabled, this will be replaced
 165                                         // "b ftrace_graph_caller"
 166 #endif
 167
 168         mcount_exit
 169 ENDPROC(ftrace_caller)
 170 #endif /* CONFIG_DYNAMIC_FTRACE */
 171
 172 ENTRY(ftrace_stub)
 173         ret
 174 ENDPROC(ftrace_stub)
 175
 176 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 177         /* save return value regs*/
 178         .macro save_return_regs
 179         sub sp, sp, #64
 180         stp x0, x1, [sp]
 181         stp x2, x3, [sp, #16]
 182         stp x4, x5, [sp, #32]
 183         stp x6, x7, [sp, #48]
 184         .endm
 185
 186         /* restore return value regs*/
 187         .macro restore_return_regs
 188         ldp x0, x1, [sp]
 189         ldp x2, x3, [sp, #16]
 190         ldp x4, x5, [sp, #32]
 191         ldp x6, x7, [sp, #48]
 192         add sp, sp, #64
 193         .endm
 194
 195 /*
 196  * void ftrace_graph_caller(void)
 197  *
 198  * Called from _mcount() or ftrace_caller() when function_graph tracer is
 199  * selected.
 200  * This function w/ prepare_ftrace_return() fakes link register's value on
 201  * the call stack in order to intercept instrumented function's return path
 202  * and run return_to_handler() later on its exit.
 203  */
 204 ENTRY(ftrace_graph_caller)
 205         mcount_get_lr_addr        x0    //     pointer to function's saved lr
 206         mcount_get_pc             x1    //     function's pc
 207         mcount_get_parent_fp      x2    //     parent's fp
 208         bl      prepare_ftrace_return   // prepare_ftrace_return(&lr, pc, fp)
 209
 210         mcount_exit
 211 ENDPROC(ftrace_graph_caller)
 212
 213 /*
 214  * void return_to_handler(void)
 215  *
 216  * Run ftrace_return_to_handler() before going back to parent.
 217  * @fp is checked against the value passed by ftrace_graph_caller()
 218  * only when HAVE_FUNCTION_GRAPH_FP_TEST is enabled.
 219  */
 220 ENTRY(return_to_handler)
 221         save_return_regs
 222         mov     x0, x29                 //     parent's fp
 223         bl      ftrace_return_to_handler// addr = ftrace_return_to_hander(fp);
 224         mov     x30, x0                 // restore the original return address
 225         restore_return_regs
 226         ret
 227 END(return_to_handler)
 228 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */