arch/arm64/kernel/head.S

   1 /*
   2  * Low-level CPU initialisation
   3  * Based on arch/arm/kernel/head.S
   4  *
   5  * Copyright (C) 1994-2002 Russell King
   6  * Copyright (C) 2003-2012 ARM Ltd.
   7  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   8  *              Will Deacon <will.deacon@arm.com>
   9  *
  10  * This program is free software; you can redistribute it and/or modify
  11  * it under the terms of the GNU General Public License version 2 as
  12  * published by the Free Software Foundation.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21  */
  22
  23 #include <linux/linkage.h>
  24 #include <linux/init.h>
  25 #include <linux/irqchip/arm-gic-v3.h>
  26
  27 #include <asm/assembler.h>
  28 #include <asm/ptrace.h>
  29 #include <asm/asm-offsets.h>
  30 #include <asm/cache.h>
  31 #include <asm/cputype.h>
  32 #include <asm/kernel-pgtable.h>
  33 #include <asm/kvm_arm.h>
  34 #include <asm/memory.h>
  35 #include <asm/pgtable-hwdef.h>
  36 #include <asm/pgtable.h>
  37 #include <asm/page.h>
  38 #include <asm/sysreg.h>
  39 #include <asm/thread_info.h>
  40 #include <asm/virt.h>
  41
  42 #define __PHYS_OFFSET   (KERNEL_START - TEXT_OFFSET)
  43
  44 #if (TEXT_OFFSET & 0xfff) != 0
  45 #error TEXT_OFFSET must be at least 4KB aligned
  46 #elif (PAGE_OFFSET & 0x1fffff) != 0
  47 #error PAGE_OFFSET must be at least 2MB aligned
  48 #elif TEXT_OFFSET > 0x1fffff
  49 #error TEXT_OFFSET must be less than 2MB
  50 #endif
  51
  52 #define KERNEL_START    _text
  53 #define KERNEL_END      _end
  54
  55 /*
  56  * Kernel startup entry point.
  57  * ---------------------------
  58  *
  59  * The requirements are:
  60  *   MMU = off, D-cache = off, I-cache = on or off,
  61  *   x0 = physical address to the FDT blob.
  62  *
  63  * This code is mostly position independent so you call this at
  64  * __pa(PAGE_OFFSET + TEXT_OFFSET).
  65  *
  66  * Note that the callee-saved registers are used for storing variables
  67  * that are useful before the MMU is enabled. The allocations are described
  68  * in the entry routines.
  69  */
  70         __HEAD
  71
  72         /*
  73          * DO NOT MODIFY. Image header expected by Linux boot-loaders.
  74          */
  75 #ifdef CONFIG_EFI
  76 efi_head:
  77         /*
  78          * This add instruction has no meaningful effect except that
  79          * its opcode forms the magic "MZ" signature required by UEFI.
  80          */
  81         add     x13, x18, #0x16
  82         b       stext
  83 #else
  84         b       stext                           // branch to kernel start, magic
  85         .long   0                               // reserved
  86 #endif
  87         .quad   _kernel_offset_le               // Image load offset from start of RAM, little-endian
  88         .quad   _kernel_size_le                 // Effective size of kernel image, little-endian
  89         .quad   _kernel_flags_le                // Informative flags, little-endian
  90         .quad   0                               // reserved
  91         .quad   0                               // reserved
  92         .quad   0                               // reserved
  93         .byte   0x41                            // Magic number, "ARM\x64"
  94         .byte   0x52
  95         .byte   0x4d
  96         .byte   0x64
  97 #ifdef CONFIG_EFI
  98         .long   pe_header - efi_head            // Offset to the PE header.
  99 #else
 100         .word   0                               // reserved
 101 #endif
 102
 103 #ifdef CONFIG_EFI
 104         .globl  __efistub_stext_offset
 105         .set    __efistub_stext_offset, stext - efi_head
 106         .align 3
 107 pe_header:
 108         .ascii  "PE"
 109         .short  0
 110 coff_header:
 111         .short  0xaa64                          // AArch64
 112         .short  2                               // nr_sections
 113         .long   0                               // TimeDateStamp
 114         .long   0                               // PointerToSymbolTable
 115         .long   1                               // NumberOfSymbols
 116         .short  section_table - optional_header // SizeOfOptionalHeader
 117         .short  0x206                           // Characteristics.
 118                                                 // IMAGE_FILE_DEBUG_STRIPPED |
 119                                                 // IMAGE_FILE_EXECUTABLE_IMAGE |
 120                                                 // IMAGE_FILE_LINE_NUMS_STRIPPED
 121 optional_header:
 122         .short  0x20b                           // PE32+ format
 123         .byte   0x02                            // MajorLinkerVersion
 124         .byte   0x14                            // MinorLinkerVersion
 125         .long   _end - stext                    // SizeOfCode
 126         .long   0                               // SizeOfInitializedData
 127         .long   0                               // SizeOfUninitializedData
 128         .long   __efistub_entry - efi_head      // AddressOfEntryPoint
 129         .long   __efistub_stext_offset          // BaseOfCode
 130
 131 extra_header_fields:
 132         .quad   0                               // ImageBase
 133         .long   0x1000                          // SectionAlignment
 134         .long   PECOFF_FILE_ALIGNMENT           // FileAlignment
 135         .short  0                               // MajorOperatingSystemVersion
 136         .short  0                               // MinorOperatingSystemVersion
 137         .short  0                               // MajorImageVersion
 138         .short  0                               // MinorImageVersion
 139         .short  0                               // MajorSubsystemVersion
 140         .short  0                               // MinorSubsystemVersion
 141         .long   0                               // Win32VersionValue
 142
 143         .long   _end - efi_head                 // SizeOfImage
 144
 145         // Everything before the kernel image is considered part of the header
 146         .long   __efistub_stext_offset          // SizeOfHeaders
 147         .long   0                               // CheckSum
 148         .short  0xa                             // Subsystem (EFI application)
 149         .short  0                               // DllCharacteristics
 150         .quad   0                               // SizeOfStackReserve
 151         .quad   0                               // SizeOfStackCommit
 152         .quad   0                               // SizeOfHeapReserve
 153         .quad   0                               // SizeOfHeapCommit
 154         .long   0                               // LoaderFlags
 155         .long   0x6                             // NumberOfRvaAndSizes
 156
 157         .quad   0                               // ExportTable
 158         .quad   0                               // ImportTable
 159         .quad   0                               // ResourceTable
 160         .quad   0                               // ExceptionTable
 161         .quad   0                               // CertificationTable
 162         .quad   0                               // BaseRelocationTable
 163
 164         // Section table
 165 section_table:
 166
 167         /*
 168          * The EFI application loader requires a relocation section
 169          * because EFI applications must be relocatable.  This is a
 170          * dummy section as far as we are concerned.
 171          */
 172         .ascii  ".reloc"
 173         .byte   0
 174         .byte   0                       // end of 0 padding of section name
 175         .long   0
 176         .long   0
 177         .long   0                       // SizeOfRawData
 178         .long   0                       // PointerToRawData
 179         .long   0                       // PointerToRelocations
 180         .long   0                       // PointerToLineNumbers
 181         .short  0                       // NumberOfRelocations
 182         .short  0                       // NumberOfLineNumbers
 183         .long   0x42100040              // Characteristics (section flags)
 184
 185
 186         .ascii  ".text"
 187         .byte   0
 188         .byte   0
 189         .byte   0                       // end of 0 padding of section name
 190         .long   _end - stext            // VirtualSize
 191         .long   __efistub_stext_offset  // VirtualAddress
 192         .long   _edata - stext          // SizeOfRawData
 193         .long   __efistub_stext_offset  // PointerToRawData
 194
 195         .long   0               // PointerToRelocations (0 for executables)
 196         .long   0               // PointerToLineNumbers (0 for executables)
 197         .short  0               // NumberOfRelocations  (0 for executables)
 198         .short  0               // NumberOfLineNumbers  (0 for executables)
 199         .long   0xe0500020      // Characteristics (section flags)
 200
 201         /*
 202          * EFI will load stext onwards at the 4k section alignment
 203          * described in the PE/COFF header. To ensure that instruction
 204          * sequences using an adrp and a :lo12: immediate will function
 205          * correctly at this alignment, we must ensure that stext is
 206          * placed at a 4k boundary in the Image to begin with.
 207          */
 208         .align 12
 209 #endif
 210
 211 ENTRY(stext)
 212         bl      preserve_boot_args
 213         bl      el2_setup                       // Drop to EL1, w20=cpu_boot_mode
 214         adrp    x24, __PHYS_OFFSET
 215         bl      set_cpu_boot_mode_flag
 216         bl      __create_page_tables            // x25=TTBR0, x26=TTBR1
 217         /*
 218          * The following calls CPU setup code, see arch/arm64/mm/proc.S for
 219          * details.
 220          * On return, the CPU will be ready for the MMU to be turned on and
 221          * the TCR will have been set.
 222          */
 223         ldr     x27, =__mmap_switched           // address to jump to after
 224                                                 // MMU has been enabled
 225         adr_l   lr, __enable_mmu                // return (PIC) address
 226         b       __cpu_setup                     // initialise processor
 227 ENDPROC(stext)
 228
 229 /*
 230  * Preserve the arguments passed by the bootloader in x0 .. x3
 231  */
 232 preserve_boot_args:
 233         mov     x21, x0                         // x21=FDT
 234
 235         adr_l   x0, boot_args                   // record the contents of
 236         stp     x21, x1, [x0]                   // x0 .. x3 at kernel entry
 237         stp     x2, x3, [x0, #16]
 238
 239         dmb     sy                              // needed before dc ivac with
 240                                                 // MMU off
 241
 242         add     x1, x0, #0x20                   // 4 x 8 bytes
 243         b       __inval_cache_range             // tail call
 244 ENDPROC(preserve_boot_args)
 245
 246 /*
 247  * Macro to create a table entry to the next page.
 248  *
 249  *      tbl:    page table address
 250  *      virt:   virtual address
 251  *      shift:  #imm page table shift
 252  *      ptrs:   #imm pointers per table page
 253  *
 254  * Preserves:   virt
 255  * Corrupts:    tmp1, tmp2
 256  * Returns:     tbl -> next level table page address
 257  */
 258         .macro  create_table_entry, tbl, virt, shift, ptrs, tmp1, tmp2
 259         lsr     \tmp1, \virt, #\shift
 260         and     \tmp1, \tmp1, #\ptrs - 1        // table index
 261         add     \tmp2, \tbl, #PAGE_SIZE
 262         orr     \tmp2, \tmp2, #PMD_TYPE_TABLE   // address of next table and entry type
 263         str     \tmp2, [\tbl, \tmp1, lsl #3]
 264         add     \tbl, \tbl, #PAGE_SIZE          // next level table page
 265         .endm
 266
 267 /*
 268  * Macro to populate the PGD (and possibily PUD) for the corresponding
 269  * block entry in the next level (tbl) for the given virtual address.
 270  *
 271  * Preserves:   tbl, next, virt
 272  * Corrupts:    tmp1, tmp2
 273  */
 274         .macro  create_pgd_entry, tbl, virt, tmp1, tmp2
 275         create_table_entry \tbl, \virt, PGDIR_SHIFT, PTRS_PER_PGD, \tmp1, \tmp2
 276 #if SWAPPER_PGTABLE_LEVELS > 3
 277         create_table_entry \tbl, \virt, PUD_SHIFT, PTRS_PER_PUD, \tmp1, \tmp2
 278 #endif
 279 #if SWAPPER_PGTABLE_LEVELS > 2
 280         create_table_entry \tbl, \virt, SWAPPER_TABLE_SHIFT, PTRS_PER_PTE, \tmp1, \tmp2
 281 #endif
 282         .endm
 283
 284 /*
 285  * Macro to populate block entries in the page table for the start..end
 286  * virtual range (inclusive).
 287  *
 288  * Preserves:   tbl, flags
 289  * Corrupts:    phys, start, end, pstate
 290  */
 291         .macro  create_block_map, tbl, flags, phys, start, end
 292         lsr     \phys, \phys, #SWAPPER_BLOCK_SHIFT
 293         lsr     \start, \start, #SWAPPER_BLOCK_SHIFT
 294         and     \start, \start, #PTRS_PER_PTE - 1       // table index
 295         orr     \phys, \flags, \phys, lsl #SWAPPER_BLOCK_SHIFT  // table entry
 296         lsr     \end, \end, #SWAPPER_BLOCK_SHIFT
 297         and     \end, \end, #PTRS_PER_PTE - 1           // table end index
 298 9999:   str     \phys, [\tbl, \start, lsl #3]           // store the entry
 299         add     \start, \start, #1                      // next entry
 300         add     \phys, \phys, #SWAPPER_BLOCK_SIZE               // next block
 301         cmp     \start, \end
 302         b.ls    9999b
 303         .endm
 304
 305 /*
 306  * Setup the initial page tables. We only setup the barest amount which is
 307  * required to get the kernel running. The following sections are required:
 308  *   - identity mapping to enable the MMU (low address, TTBR0)
 309  *   - first few MB of the kernel linear mapping to jump to once the MMU has
 310  *     been enabled
 311  */
 312 __create_page_tables:
 313         adrp    x25, idmap_pg_dir
 314         adrp    x26, swapper_pg_dir
 315         mov     x27, lr
 316
 317         /*
 318          * Invalidate the idmap and swapper page tables to avoid potential
 319          * dirty cache lines being evicted.
 320          */
 321         mov     x0, x25
 322         add     x1, x26, #SWAPPER_DIR_SIZE
 323         bl      __inval_cache_range
 324
 325         /*
 326          * Clear the idmap and swapper page tables.
 327          */
 328         mov     x0, x25
 329         add     x6, x26, #SWAPPER_DIR_SIZE
 330 1:      stp     xzr, xzr, [x0], #16
 331         stp     xzr, xzr, [x0], #16
 332         stp     xzr, xzr, [x0], #16
 333         stp     xzr, xzr, [x0], #16
 334         cmp     x0, x6
 335         b.lo    1b
 336
 337         ldr     x7, =SWAPPER_MM_MMUFLAGS
 338
 339         /*
 340          * Create the identity mapping.
 341          */
 342         mov     x0, x25                         // idmap_pg_dir
 343         adrp    x3, __idmap_text_start          // __pa(__idmap_text_start)
 344
 345 #ifndef CONFIG_ARM64_VA_BITS_48
 346 #define EXTRA_SHIFT     (PGDIR_SHIFT + PAGE_SHIFT - 3)
 347 #define EXTRA_PTRS      (1 << (48 - EXTRA_SHIFT))
 348
 349         /*
 350          * If VA_BITS < 48, it may be too small to allow for an ID mapping to be
 351          * created that covers system RAM if that is located sufficiently high
 352          * in the physical address space. So for the ID map, use an extended
 353          * virtual range in that case, by configuring an additional translation
 354          * level.
 355          * First, we have to verify our assumption that the current value of
 356          * VA_BITS was chosen such that all translation levels are fully
 357          * utilised, and that lowering T0SZ will always result in an additional
 358          * translation level to be configured.
 359          */
 360 #if VA_BITS != EXTRA_SHIFT
 361 #error "Mismatch between VA_BITS and page size/number of translation levels"
 362 #endif
 363
 364         /*
 365          * Calculate the maximum allowed value for TCR_EL1.T0SZ so that the
 366          * entire ID map region can be mapped. As T0SZ == (64 - #bits used),
 367          * this number conveniently equals the number of leading zeroes in
 368          * the physical address of __idmap_text_end.
 369          */
 370         adrp    x5, __idmap_text_end
 371         clz     x5, x5
 372         cmp     x5, TCR_T0SZ(VA_BITS)   // default T0SZ small enough?
 373         b.ge    1f                      // .. then skip additional level
 374
 375         adr_l   x6, idmap_t0sz
 376         str     x5, [x6]
 377         dmb     sy
 378         dc      ivac, x6                // Invalidate potentially stale cache line
 379
 380         create_table_entry x0, x3, EXTRA_SHIFT, EXTRA_PTRS, x5, x6
 381 1:
 382 #endif
 383
 384         create_pgd_entry x0, x3, x5, x6
 385         mov     x5, x3                          // __pa(__idmap_text_start)
 386         adr_l   x6, __idmap_text_end            // __pa(__idmap_text_end)
 387         create_block_map x0, x7, x3, x5, x6
 388
 389         /*
 390          * Map the kernel image (starting with PHYS_OFFSET).
 391          */
 392         mov     x0, x26                         // swapper_pg_dir
 393         mov     x5, #PAGE_OFFSET
 394         create_pgd_entry x0, x5, x3, x6
 395         ldr     x6, =KERNEL_END                 // __va(KERNEL_END)
 396         mov     x3, x24                         // phys offset
 397         create_block_map x0, x7, x3, x5, x6
 398
 399         /*
 400          * Since the page tables have been populated with non-cacheable
 401          * accesses (MMU disabled), invalidate the idmap and swapper page
 402          * tables again to remove any speculatively loaded cache lines.
 403          */
 404         mov     x0, x25
 405         add     x1, x26, #SWAPPER_DIR_SIZE
 406         dmb     sy
 407         bl      __inval_cache_range
 408
 409         mov     lr, x27
 410         ret
 411 ENDPROC(__create_page_tables)
 412         .ltorg
 413
 414 /*
 415  * The following fragment of code is executed with the MMU enabled.
 416  */
 417         .set    initial_sp, init_thread_union + THREAD_START_SP
 418 __mmap_switched:
 419         adr_l   x6, __bss_start
 420         adr_l   x7, __bss_stop
 421
 422 1:      cmp     x6, x7
 423         b.hs    2f
 424         str     xzr, [x6], #8                   // Clear BSS
 425         b       1b
 426 2:
 427         adrp    x4, initial_sp
 428         add     sp, x4, :lo12:initial_sp
 429         str_l   x21, __fdt_pointer, x5          // Save FDT pointer
 430         str_l   x24, memstart_addr, x6          // Save PHYS_OFFSET
 431         mov     x29, #0
 432 #ifdef CONFIG_KASAN
 433         bl      kasan_early_init
 434 #endif
 435         b       start_kernel
 436 ENDPROC(__mmap_switched)
 437
 438 /*
 439  * end early head section, begin head code that is also used for
 440  * hotplug and needs to have the same protections as the text region
 441  */
 442         .section ".text","ax"
 443 /*
 444  * If we're fortunate enough to boot at EL2, ensure that the world is
 445  * sane before dropping to EL1.
 446  *
 447  * Returns either BOOT_CPU_MODE_EL1 or BOOT_CPU_MODE_EL2 in x20 if
 448  * booted in EL1 or EL2 respectively.
 449  */
 450 ENTRY(el2_setup)
 451         msr     SPsel, #1                       // We want to use SP_EL{1,2}
 452         mrs     x0, CurrentEL
 453         cmp     x0, #CurrentEL_EL2
 454         b.ne    1f
 455         mrs     x0, sctlr_el2
 456 CPU_BE( orr     x0, x0, #(1 << 25)      )       // Set the EE bit for EL2
 457 CPU_LE( bic     x0, x0, #(1 << 25)      )       // Clear the EE bit for EL2
 458         msr     sctlr_el2, x0
 459         b       2f
 460 1:      mrs     x0, sctlr_el1
 461 CPU_BE( orr     x0, x0, #(3 << 24)      )       // Set the EE and E0E bits for EL1
 462 CPU_LE( bic     x0, x0, #(3 << 24)      )       // Clear the EE and E0E bits for EL1
 463         msr     sctlr_el1, x0
 464         mov     w20, #BOOT_CPU_MODE_EL1         // This cpu booted in EL1
 465         isb
 466         ret
 467
 468         /* Hyp configuration. */
 469 2:      mov_q   x0, HCR_HOST_NVHE_FLAGS
 470         msr     hcr_el2, x0
 471
 472         /* Generic timers. */
 473         mrs     x0, cnthctl_el2
 474         orr     x0, x0, #3                      // Enable EL1 physical timers
 475         msr     cnthctl_el2, x0
 476         msr     cntvoff_el2, xzr                // Clear virtual offset
 477
 478 #ifdef CONFIG_ARM_GIC_V3
 479         /* GICv3 system register access */
 480         mrs     x0, id_aa64pfr0_el1
 481         ubfx    x0, x0, #24, #4
 482         cbz     x0, 3f
 483
 484         mrs_s   x0, ICC_SRE_EL2
 485         orr     x0, x0, #ICC_SRE_EL2_SRE        // Set ICC_SRE_EL2.SRE==1
 486         orr     x0, x0, #ICC_SRE_EL2_ENABLE     // Set ICC_SRE_EL2.Enable==1
 487         msr_s   ICC_SRE_EL2, x0
 488         isb                                     // Make sure SRE is now set
 489         mrs_s   x0, ICC_SRE_EL2                 // Read SRE back,
 490         tbz     x0, #0, 3f                      // and check that it sticks
 491         msr_s   ICH_HCR_EL2, xzr                // Reset ICC_HCR_EL2 to defaults
 492
 493 3:
 494 #endif
 495
 496         /* Populate ID registers. */
 497         mrs     x0, midr_el1
 498         mrs     x1, mpidr_el1
 499         msr     vpidr_el2, x0
 500         msr     vmpidr_el2, x1
 501
 502         /* sctlr_el1 */
 503         mov     x0, #0x0800                     // Set/clear RES{1,0} bits
 504 CPU_BE( movk    x0, #0x33d0, lsl #16    )       // Set EE and E0E on BE systems
 505 CPU_LE( movk    x0, #0x30d0, lsl #16    )       // Clear EE and E0E on LE systems
 506         msr     sctlr_el1, x0
 507
 508         /* Coprocessor traps. */
 509         mov     x0, #0x33ff
 510         msr     cptr_el2, x0                    // Disable copro. traps to EL2
 511
 512 #ifdef CONFIG_COMPAT
 513         msr     hstr_el2, xzr                   // Disable CP15 traps to EL2
 514 #endif
 515
 516         /* EL2 debug */
 517         mrs     x0, id_aa64dfr0_el1             // Check ID_AA64DFR0_EL1 PMUVer
 518         sbfx    x0, x0, #8, #4
 519         cmp     x0, #1
 520         b.lt    4f                              // Skip if no PMU present
 521         mrs     x0, pmcr_el0                    // Disable debug access traps
 522         ubfx    x0, x0, #11, #5                 // to EL2 and allow access to
 523 4:
 524         csel    x0, xzr, x0, lt                 // all PMU counters from EL1
 525         msr     mdcr_el2, x0                    // (if they exist)
 526
 527         /* Stage-2 translation */
 528         msr     vttbr_el2, xzr
 529
 530         /* Hypervisor stub */
 531         adrp    x0, __hyp_stub_vectors
 532         add     x0, x0, #:lo12:__hyp_stub_vectors
 533         msr     vbar_el2, x0
 534
 535         /* spsr */
 536         mov     x0, #(PSR_F_BIT | PSR_I_BIT | PSR_A_BIT | PSR_D_BIT |\
 537                       PSR_MODE_EL1h)
 538         msr     spsr_el2, x0
 539         msr     elr_el2, lr
 540         mov     w20, #BOOT_CPU_MODE_EL2         // This CPU booted in EL2
 541         eret
 542 ENDPROC(el2_setup)
 543
 544 /*
 545  * Sets the __boot_cpu_mode flag depending on the CPU boot mode passed
 546  * in x20. See arch/arm64/include/asm/virt.h for more info.
 547  */
 548 ENTRY(set_cpu_boot_mode_flag)
 549         adr_l   x1, __boot_cpu_mode
 550         cmp     w20, #BOOT_CPU_MODE_EL2
 551         b.ne    1f
 552         add     x1, x1, #4
 553 1:      str     w20, [x1]                       // This CPU has booted in EL1
 554         dmb     sy
 555         dc      ivac, x1                        // Invalidate potentially stale cache line
 556         ret
 557 ENDPROC(set_cpu_boot_mode_flag)
 558
 559 /*
 560  * We need to find out the CPU boot mode long after boot, so we need to
 561  * store it in a writable variable.
 562  *
 563  * This is not in .bss, because we set it sufficiently early that the boot-time
 564  * zeroing of .bss would clobber it.
 565  */
 566         .pushsection    .data..cacheline_aligned
 567         .align  L1_CACHE_SHIFT
 568 ENTRY(__boot_cpu_mode)
 569         .long   BOOT_CPU_MODE_EL2
 570         .long   BOOT_CPU_MODE_EL1
 571         .popsection
 572
 573         /*
 574          * This provides a "holding pen" for platforms to hold all secondary
 575          * cores are held until we're ready for them to initialise.
 576          */
 577 ENTRY(secondary_holding_pen)
 578         bl      el2_setup                       // Drop to EL1, w20=cpu_boot_mode
 579         bl      set_cpu_boot_mode_flag
 580         mrs     x0, mpidr_el1
 581         ldr     x1, =MPIDR_HWID_BITMASK
 582         and     x0, x0, x1
 583         adr_l   x3, secondary_holding_pen_release
 584 pen:    ldr     x4, [x3]
 585         cmp     x4, x0
 586         b.eq    secondary_startup
 587         wfe
 588         b       pen
 589 ENDPROC(secondary_holding_pen)
 590
 591         /*
 592          * Secondary entry point that jumps straight into the kernel. Only to
 593          * be used where CPUs are brought online dynamically by the kernel.
 594          */
 595 ENTRY(secondary_entry)
 596         bl      el2_setup                       // Drop to EL1
 597         bl      set_cpu_boot_mode_flag
 598         b       secondary_startup
 599 ENDPROC(secondary_entry)
 600
 601 ENTRY(secondary_startup)
 602         /*
 603          * Common entry point for secondary CPUs.
 604          */
 605         adrp    x25, idmap_pg_dir
 606         adrp    x26, swapper_pg_dir
 607         bl      __cpu_setup                     // initialise processor
 608
 609         ldr     x21, =secondary_data
 610         ldr     x27, =__secondary_switched      // address to jump to after enabling the MMU
 611         b       __enable_mmu
 612 ENDPROC(secondary_startup)
 613
 614 ENTRY(__secondary_switched)
 615         ldr     x0, [x21]                       // get secondary_data.stack
 616         mov     sp, x0
 617         mov     x29, #0
 618         b       secondary_start_kernel
 619 ENDPROC(__secondary_switched)
 620
 621 /*
 622  * Enable the MMU.
 623  *
 624  *  x0  = SCTLR_EL1 value for turning on the MMU.
 625  *  x27 = *virtual* address to jump to upon completion
 626  *
 627  * Other registers depend on the function called upon completion.
 628  *
 629  * Checks if the selected granule size is supported by the CPU.
 630  * If it isn't, park the CPU
 631  */
 632         .section        ".idmap.text", "ax"
 633 __enable_mmu:
 634         mrs     x1, ID_AA64MMFR0_EL1
 635         ubfx    x2, x1, #ID_AA64MMFR0_TGRAN_SHIFT, 4
 636         cmp     x2, #ID_AA64MMFR0_TGRAN_SUPPORTED
 637         b.ne    __no_granule_support
 638         ldr     x5, =vectors
 639         msr     vbar_el1, x5
 640         msr     ttbr0_el1, x25                  // load TTBR0
 641         msr     ttbr1_el1, x26                  // load TTBR1
 642         isb
 643         msr     sctlr_el1, x0
 644         isb
 645         /*
 646          * Invalidate the local I-cache so that any instructions fetched
 647          * speculatively from the PoC are discarded, since they may have
 648          * been dynamically patched at the PoU.
 649          */
 650         ic      iallu
 651         dsb     nsh
 652         isb
 653         br      x27
 654 ENDPROC(__enable_mmu)
 655
 656 __no_granule_support:
 657         wfe
 658         b __no_granule_support
 659 ENDPROC(__no_granule_support)