arch/arm64/kernel/hyp-stub.S

   1 /*
   2  * Hypervisor stub
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Author:      Marc Zyngier <marc.zyngier@arm.com>
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18  */
  19
  20 #include <linux/init.h>
  21 #include <linux/linkage.h>
  22 #include <linux/irqchip/arm-gic-v3.h>
  23
  24 #include <asm/assembler.h>
  25 #include <asm/kvm_arm.h>
  26 #include <asm/kvm_asm.h>
  27 #include <asm/ptrace.h>
  28 #include <asm/virt.h>
  29
  30         .text
  31         .pushsection    .hyp.text, "ax"
  32
  33         .align 11
  34
  35 ENTRY(__hyp_stub_vectors)
  36         ventry  el2_sync_invalid                // Synchronous EL2t
  37         ventry  el2_irq_invalid                 // IRQ EL2t
  38         ventry  el2_fiq_invalid                 // FIQ EL2t
  39         ventry  el2_error_invalid               // Error EL2t
  40
  41         ventry  el2_sync_invalid                // Synchronous EL2h
  42         ventry  el2_irq_invalid                 // IRQ EL2h
  43         ventry  el2_fiq_invalid                 // FIQ EL2h
  44         ventry  el2_error_invalid               // Error EL2h
  45
  46         ventry  el1_sync                        // Synchronous 64-bit EL1
  47         ventry  el1_irq_invalid                 // IRQ 64-bit EL1
  48         ventry  el1_fiq_invalid                 // FIQ 64-bit EL1
  49         ventry  el1_error_invalid               // Error 64-bit EL1
  50
  51         ventry  el1_sync_invalid                // Synchronous 32-bit EL1
  52         ventry  el1_irq_invalid                 // IRQ 32-bit EL1
  53         ventry  el1_fiq_invalid                 // FIQ 32-bit EL1
  54         ventry  el1_error_invalid               // Error 32-bit EL1
  55 ENDPROC(__hyp_stub_vectors)
  56
  57         .align 11
  58
  59 el1_sync:
  60         cmp     x0, #HVC_SET_VECTORS
  61         b.ne    2f
  62         msr     vbar_el2, x1
  63         b       9f
  64
  65 2:      cmp     x0, #HVC_SOFT_RESTART
  66         b.ne    3f
  67         mov     x0, x2
  68         mov     x2, x4
  69         mov     x4, x1
  70         mov     x1, x3
  71         br      x4                              // no return
  72
  73 3:      cmp     x0, #HVC_RESET_VECTORS
  74         beq     9f                              // Nothing to reset!
  75
  76         /* Someone called kvm_call_hyp() against the hyp-stub... */
  77         ldr     x0, =HVC_STUB_ERR
  78         eret
  79
  80 9:      mov     x0, xzr
  81         eret
  82 ENDPROC(el1_sync)
  83
  84 .macro invalid_vector   label
  85 \label:
  86         b \label
  87 ENDPROC(\label)
  88 .endm
  89
  90         invalid_vector  el2_sync_invalid
  91         invalid_vector  el2_irq_invalid
  92         invalid_vector  el2_fiq_invalid
  93         invalid_vector  el2_error_invalid
  94         invalid_vector  el1_sync_invalid
  95         invalid_vector  el1_irq_invalid
  96         invalid_vector  el1_fiq_invalid
  97         invalid_vector  el1_error_invalid
  98
  99 /*
 100  * __hyp_set_vectors: Call this after boot to set the initial hypervisor
 101  * vectors as part of hypervisor installation.  On an SMP system, this should
 102  * be called on each CPU.
 103  *
 104  * x0 must be the physical address of the new vector table, and must be
 105  * 2KB aligned.
 106  *
 107  * Before calling this, you must check that the stub hypervisor is installed
 108  * everywhere, by waiting for any secondary CPUs to be brought up and then
 109  * checking that is_hyp_mode_available() is true.
 110  *
 111  * If not, there is a pre-existing hypervisor, some CPUs failed to boot, or
 112  * something else went wrong... in such cases, trying to install a new
 113  * hypervisor is unlikely to work as desired.
 114  *
 115  * When you call into your shiny new hypervisor, sp_el2 will contain junk,
 116  * so you will need to set that to something sensible at the new hypervisor's
 117  * initialisation entry point.
 118  */
 119
 120 ENTRY(__hyp_set_vectors)
 121         mov     x1, x0
 122         mov     x0, #HVC_SET_VECTORS
 123         hvc     #0
 124         ret
 125 ENDPROC(__hyp_set_vectors)
 126
 127 ENTRY(__hyp_reset_vectors)
 128         mov     x0, #HVC_RESET_VECTORS
 129         hvc     #0
 130         ret
 131 ENDPROC(__hyp_reset_vectors)