arch/mips/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #include <asm/asm-offsets.h>
   3 #include <asm/thread_info.h>
   4
   5 #define PAGE_SIZE _PAGE_SIZE
   6
   7 /*
   8  * Put .bss..swapper_pg_dir as the first thing in .bss. This will
   9  * ensure that it has .bss alignment (64K).
  10  */
  11 #define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
  12
  13 #include <asm-generic/vmlinux.lds.h>
  14
  15 #undef mips
  16 #define mips mips
  17 OUTPUT_ARCH(mips)
  18 ENTRY(kernel_entry)
  19 PHDRS {
  20         text PT_LOAD FLAGS(7);  /* RWX */
  21 #ifndef CONFIG_CAVIUM_OCTEON_SOC
  22         note PT_NOTE FLAGS(4);  /* R__ */
  23 #endif /* CAVIUM_OCTEON_SOC */
  24 }
  25
  26 #ifdef CONFIG_32BIT
  27         #ifdef CONFIG_CPU_LITTLE_ENDIAN
  28                 jiffies  = jiffies_64;
  29         #else
  30                 jiffies  = jiffies_64 + 4;
  31         #endif
  32 #else
  33         jiffies  = jiffies_64;
  34 #endif
  35
  36 SECTIONS
  37 {
  38 #ifdef CONFIG_BOOT_ELF64
  39         /* Read-only sections, merged into text segment: */
  40         /* . = 0xc000000000000000; */
  41
  42         /* This is the value for an Origin kernel, taken from an IRIX kernel.  */
  43         /* . = 0xc00000000001c000; */
  44
  45         /* Set the vaddr for the text segment to a value
  46          *   >= 0xa800 0000 0001 9000 if no symmon is going to configured
  47          *   >= 0xa800 0000 0030 0000 otherwise
  48          */
  49
  50         /* . = 0xa800000000300000; */
  51         . = 0xffffffff80300000;
  52 #endif
  53         . = LINKER_LOAD_ADDRESS;
  54         /* read-only */
  55         _text = .;      /* Text and read-only data */
  56         .text : {
  57                 TEXT_TEXT
  58                 SCHED_TEXT
  59                 CPUIDLE_TEXT
  60                 LOCK_TEXT
  61                 KPROBES_TEXT
  62                 IRQENTRY_TEXT
  63                 SOFTIRQENTRY_TEXT
  64                 *(.text.*)
  65                 *(.fixup)
  66                 *(.gnu.warning)
  67         } :text = 0
  68         _etext = .;     /* End of text section */
  69
  70         EXCEPTION_TABLE(16)
  71
  72         /* Exception table for data bus errors */
  73         __dbe_table : {
  74                 __start___dbe_table = .;
  75                 *(__dbe_table)
  76                 __stop___dbe_table = .;
  77         }
  78
  79 #ifdef CONFIG_CAVIUM_OCTEON_SOC
  80 #define NOTES_HEADER
  81 #else /* CONFIG_CAVIUM_OCTEON_SOC */
  82 #define NOTES_HEADER :note
  83 #endif /* CONFIG_CAVIUM_OCTEON_SOC */
  84         NOTES :text NOTES_HEADER
  85         .dummy : { *(.dummy) } :text
  86
  87         _sdata = .;                     /* Start of data section */
  88         RODATA
  89
  90         /* writeable */
  91         .data : {       /* Data */
  92                 . = . + DATAOFFSET;             /* for CONFIG_MAPPED_KERNEL */
  93
  94                 INIT_TASK_DATA(THREAD_SIZE)
  95                 NOSAVE_DATA
  96                 PAGE_ALIGNED_DATA(PAGE_SIZE)
  97                 CACHELINE_ALIGNED_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
  98                 READ_MOSTLY_DATA(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
  99                 DATA_DATA
 100                 CONSTRUCTORS
 101         }
 102         BUG_TABLE
 103         _gp = . + 0x8000;
 104         .lit8 : {
 105                 *(.lit8)
 106         }
 107         .lit4 : {
 108                 *(.lit4)
 109         }
 110         /* We want the small data sections together, so single-instruction offsets
 111            can access them all, and initialized data all before uninitialized, so
 112            we can shorten the on-disk segment size.  */
 113         .sdata : {
 114                 *(.sdata)
 115         }
 116         _edata =  .;                    /* End of data section */
 117
 118         /* will be freed after init */
 119         . = ALIGN(PAGE_SIZE);           /* Init code and data */
 120         __init_begin = .;
 121         INIT_TEXT_SECTION(PAGE_SIZE)
 122         INIT_DATA_SECTION(16)
 123
 124         . = ALIGN(4);
 125         .mips.machines.init : AT(ADDR(.mips.machines.init) - LOAD_OFFSET) {
 126                 __mips_machines_start = .;
 127                 *(.mips.machines.init)
 128                 __mips_machines_end = .;
 129         }
 130
 131         /* .exit.text is discarded at runtime, not link time, to deal with
 132          * references from .rodata
 133          */
 134         .exit.text : {
 135                 EXIT_TEXT
 136         }
 137         .exit.data : {
 138                 EXIT_DATA
 139         }
 140 #ifdef CONFIG_SMP
 141         PERCPU_SECTION(1 << CONFIG_MIPS_L1_CACHE_SHIFT)
 142 #endif
 143
 144 #ifdef CONFIG_MIPS_ELF_APPENDED_DTB
 145         .appended_dtb : AT(ADDR(.appended_dtb) - LOAD_OFFSET) {
 146                 *(.appended_dtb)
 147                 KEEP(*(.appended_dtb))
 148         }
 149 #endif
 150
 151 #ifdef CONFIG_RELOCATABLE
 152         . = ALIGN(4);
 153
 154         .data.reloc : {
 155                 _relocation_start = .;
 156                 /*
 157                  * Space for relocation table
 158                  * This needs to be filled so that the
 159                  * relocs tool can overwrite the content.
 160                  * An invalid value is left at the start of the
 161                  * section to abort relocation if the table
 162                  * has not been filled in.
 163                  */
 164                 LONG(0xFFFFFFFF);
 165                 FILL(0);
 166                 . += CONFIG_RELOCATION_TABLE_SIZE - 4;
 167                 _relocation_end = .;
 168         }
 169 #endif
 170
 171 #ifdef CONFIG_MIPS_RAW_APPENDED_DTB
 172         __appended_dtb = .;
 173         /* leave space for appended DTB */
 174         . += 0x100000;
 175 #endif
 176         /*
 177          * Align to 64K in attempt to eliminate holes before the
 178          * .bss..swapper_pg_dir section at the start of .bss.  This
 179          * also satisfies PAGE_SIZE alignment as the largest page size
 180          * allowed is 64K.
 181          */
 182         . = ALIGN(0x10000);
 183         __init_end = .;
 184         /* freed after init ends here */
 185
 186         /*
 187          * Force .bss to 64K alignment so that .bss..swapper_pg_dir
 188          * gets that alignment.  .sbss should be empty, so there will be
 189          * no holes after __init_end. */
 190         BSS_SECTION(0, 0x10000, 8)
 191
 192         _end = . ;
 193
 194         /* These mark the ABI of the kernel for debuggers.  */
 195         .mdebug.abi32 : {
 196                 KEEP(*(.mdebug.abi32))
 197         }
 198         .mdebug.abi64 : {
 199                 KEEP(*(.mdebug.abi64))
 200         }
 201
 202         /* This is the MIPS specific mdebug section.  */
 203         .mdebug : {
 204                 *(.mdebug)
 205         }
 206
 207         STABS_DEBUG
 208         DWARF_DEBUG
 209
 210         /* These must appear regardless of  .  */
 211         .gptab.sdata : {
 212                 *(.gptab.data)
 213                 *(.gptab.sdata)
 214         }
 215         .gptab.sbss : {
 216                 *(.gptab.bss)
 217                 *(.gptab.sbss)
 218         }
 219
 220         /* Sections to be discarded */
 221         DISCARDS
 222         /DISCARD/ : {
 223                 /* ABI crap starts here */
 224                 *(.MIPS.abiflags)
 225                 *(.MIPS.options)
 226                 *(.options)
 227                 *(.pdr)
 228                 *(.reginfo)
 229                 *(.eh_frame)
 230         }
 231 }