arch/powerpc/kernel/head_fsl_booke.S

   1 /*
   2  * Kernel execution entry point code.
   3  *
   4  *    Copyright (c) 1995-1996 Gary Thomas <gdt@linuxppc.org>
   5  *      Initial PowerPC version.
   6  *    Copyright (c) 1996 Cort Dougan <cort@cs.nmt.edu>
   7  *      Rewritten for PReP
   8  *    Copyright (c) 1996 Paul Mackerras <paulus@cs.anu.edu.au>
   9  *      Low-level exception handers, MMU support, and rewrite.
  10  *    Copyright (c) 1997 Dan Malek <dmalek@jlc.net>
  11  *      PowerPC 8xx modifications.
  12  *    Copyright (c) 1998-1999 TiVo, Inc.
  13  *      PowerPC 403GCX modifications.
  14  *    Copyright (c) 1999 Grant Erickson <grant@lcse.umn.edu>
  15  *      PowerPC 403GCX/405GP modifications.
  16  *    Copyright 2000 MontaVista Software Inc.
  17  *      PPC405 modifications
  18  *      PowerPC 403GCX/405GP modifications.
  19  *      Author: MontaVista Software, Inc.
  20  *              frank_rowand@mvista.com or source@mvista.com
  21  *              debbie_chu@mvista.com
  22  *    Copyright 2002-2004 MontaVista Software, Inc.
  23  *      PowerPC 44x support, Matt Porter <mporter@kernel.crashing.org>
  24  *    Copyright 2004 Freescale Semiconductor, Inc
  25  *      PowerPC e500 modifications, Kumar Gala <galak@kernel.crashing.org>
  26  *
  27  * This program is free software; you can redistribute  it and/or modify it
  28  * under  the terms of  the GNU General  Public License as published by the
  29  * Free Software Foundation;  either version 2 of the  License, or (at your
  30  * option) any later version.
  31  */
  32
  33 #include <linux/init.h>
  34 #include <linux/threads.h>
  35 #include <asm/processor.h>
  36 #include <asm/page.h>
  37 #include <asm/mmu.h>
  38 #include <asm/pgtable.h>
  39 #include <asm/cputable.h>
  40 #include <asm/thread_info.h>
  41 #include <asm/ppc_asm.h>
  42 #include <asm/asm-offsets.h>
  43 #include <asm/cache.h>
  44 #include <asm/ptrace.h>
  45 #include "head_booke.h"
  46
  47 /* As with the other PowerPC ports, it is expected that when code
  48  * execution begins here, the following registers contain valid, yet
  49  * optional, information:
  50  *
  51  *   r3 - Board info structure pointer (DRAM, frequency, MAC address, etc.)
  52  *   r4 - Starting address of the init RAM disk
  53  *   r5 - Ending address of the init RAM disk
  54  *   r6 - Start of kernel command line string (e.g. "mem=128")
  55  *   r7 - End of kernel command line string
  56  *
  57  */
  58         __HEAD
  59 _ENTRY(_stext);
  60 _ENTRY(_start);
  61         /*
  62          * Reserve a word at a fixed location to store the address
  63          * of abatron_pteptrs
  64          */
  65         nop
  66
  67         /* Translate device tree address to physical, save in r30/r31 */
  68         bl      get_phys_addr
  69         mr      r30,r3
  70         mr      r31,r4
  71
  72         li      r25,0                   /* phys kernel start (low) */
  73         li      r24,0                   /* CPU number */
  74         li      r23,0                   /* phys kernel start (high) */
  75
  76 #ifdef CONFIG_RELOCATABLE
  77         LOAD_REG_ADDR_PIC(r3, _stext)   /* Get our current runtime base */
  78
  79         /* Translate _stext address to physical, save in r23/r25 */
  80         bl      get_phys_addr
  81         mr      r23,r3
  82         mr      r25,r4
  83
  84         bl      0f
  85 0:      mflr    r8
  86         addis   r3,r8,(is_second_reloc - 0b)@ha
  87         lwz     r19,(is_second_reloc - 0b)@l(r3)
  88
  89         /* Check if this is the second relocation. */
  90         cmpwi   r19,1
  91         bne     1f
  92
  93         /*
  94          * For the second relocation, we already get the real memstart_addr
  95          * from device tree. So we will map PAGE_OFFSET to memstart_addr,
  96          * then the virtual address of start kernel should be:
  97          *          PAGE_OFFSET + (kernstart_addr - memstart_addr)
  98          * Since the offset between kernstart_addr and memstart_addr should
  99          * never be beyond 1G, so we can just use the lower 32bit of them
 100          * for the calculation.
 101          */
 102         lis     r3,PAGE_OFFSET@h
 103
 104         addis   r4,r8,(kernstart_addr - 0b)@ha
 105         addi    r4,r4,(kernstart_addr - 0b)@l
 106         lwz     r5,4(r4)
 107
 108         addis   r6,r8,(memstart_addr - 0b)@ha
 109         addi    r6,r6,(memstart_addr - 0b)@l
 110         lwz     r7,4(r6)
 111
 112         subf    r5,r7,r5
 113         add     r3,r3,r5
 114         b       2f
 115
 116 1:
 117         /*
 118          * We have the runtime (virutal) address of our base.
 119          * We calculate our shift of offset from a 64M page.
 120          * We could map the 64M page we belong to at PAGE_OFFSET and
 121          * get going from there.
 122          */
 123         lis     r4,KERNELBASE@h
 124         ori     r4,r4,KERNELBASE@l
 125         rlwinm  r6,r25,0,0x3ffffff              /* r6 = PHYS_START % 64M */
 126         rlwinm  r5,r4,0,0x3ffffff               /* r5 = KERNELBASE % 64M */
 127         subf    r3,r5,r6                        /* r3 = r6 - r5 */
 128         add     r3,r4,r3                        /* Required Virtual Address */
 129
 130 2:      bl      relocate
 131
 132         /*
 133          * For the second relocation, we already set the right tlb entries
 134          * for the kernel space, so skip the code in fsl_booke_entry_mapping.S
 135         */
 136         cmpwi   r19,1
 137         beq     set_ivor
 138 #endif
 139
 140 /* We try to not make any assumptions about how the boot loader
 141  * setup or used the TLBs.  We invalidate all mappings from the
 142  * boot loader and load a single entry in TLB1[0] to map the
 143  * first 64M of kernel memory.  Any boot info passed from the
 144  * bootloader needs to live in this first 64M.
 145  *
 146  * Requirement on bootloader:
 147  *  - The page we're executing in needs to reside in TLB1 and
 148  *    have IPROT=1.  If not an invalidate broadcast could
 149  *    evict the entry we're currently executing in.
 150  *
 151  *  r3 = Index of TLB1 were executing in
 152  *  r4 = Current MSR[IS]
 153  *  r5 = Index of TLB1 temp mapping
 154  *
 155  * Later in mapin_ram we will correctly map lowmem, and resize TLB1[0]
 156  * if needed
 157  */
 158
 159 _ENTRY(__early_start)
 160
 161 #define ENTRY_MAPPING_BOOT_SETUP
 162 #include "fsl_booke_entry_mapping.S"
 163 #undef ENTRY_MAPPING_BOOT_SETUP
 164
 165 set_ivor:
 166         /* Establish the interrupt vector offsets */
 167         SET_IVOR(0,  CriticalInput);
 168         SET_IVOR(1,  MachineCheck);
 169         SET_IVOR(2,  DataStorage);
 170         SET_IVOR(3,  InstructionStorage);
 171         SET_IVOR(4,  ExternalInput);
 172         SET_IVOR(5,  Alignment);
 173         SET_IVOR(6,  Program);
 174         SET_IVOR(7,  FloatingPointUnavailable);
 175         SET_IVOR(8,  SystemCall);
 176         SET_IVOR(9,  AuxillaryProcessorUnavailable);
 177         SET_IVOR(10, Decrementer);
 178         SET_IVOR(11, FixedIntervalTimer);
 179         SET_IVOR(12, WatchdogTimer);
 180         SET_IVOR(13, DataTLBError);
 181         SET_IVOR(14, InstructionTLBError);
 182         SET_IVOR(15, DebugCrit);
 183
 184         /* Establish the interrupt vector base */
 185         lis     r4,interrupt_base@h     /* IVPR only uses the high 16-bits */
 186         mtspr   SPRN_IVPR,r4
 187
 188         /* Setup the defaults for TLB entries */
 189         li      r2,(MAS4_TSIZED(BOOK3E_PAGESZ_4K))@l
 190 #ifdef CONFIG_E200
 191         oris    r2,r2,MAS4_TLBSELD(1)@h
 192 #endif
 193         mtspr   SPRN_MAS4, r2
 194
 195 #if 0
 196         /* Enable DOZE */
 197         mfspr   r2,SPRN_HID0
 198         oris    r2,r2,HID0_DOZE@h
 199         mtspr   SPRN_HID0, r2
 200 #endif
 201
 202 #if !defined(CONFIG_BDI_SWITCH)
 203         /*
 204          * The Abatron BDI JTAG debugger does not tolerate others
 205          * mucking with the debug registers.
 206          */
 207         lis     r2,DBCR0_IDM@h
 208         mtspr   SPRN_DBCR0,r2
 209         isync
 210         /* clear any residual debug events */
 211         li      r2,-1
 212         mtspr   SPRN_DBSR,r2
 213 #endif
 214
 215 #ifdef CONFIG_SMP
 216         /* Check to see if we're the second processor, and jump
 217          * to the secondary_start code if so
 218          */
 219         LOAD_REG_ADDR_PIC(r24, boot_cpuid)
 220         lwz     r24, 0(r24)
 221         cmpwi   r24, -1
 222         mfspr   r24,SPRN_PIR
 223         bne     __secondary_start
 224 #endif
 225
 226         /*
 227          * This is where the main kernel code starts.
 228          */
 229
 230         /* ptr to current */
 231         lis     r2,init_task@h
 232         ori     r2,r2,init_task@l
 233
 234         /* ptr to current thread */
 235         addi    r4,r2,THREAD    /* init task's THREAD */
 236         mtspr   SPRN_SPRG_THREAD,r4
 237
 238         /* stack */
 239         lis     r1,init_thread_union@h
 240         ori     r1,r1,init_thread_union@l
 241         li      r0,0
 242         stwu    r0,THREAD_SIZE-STACK_FRAME_OVERHEAD(r1)
 243
 244         CURRENT_THREAD_INFO(r22, r1)
 245         stw     r24, TI_CPU(r22)
 246
 247         bl      early_init
 248
 249 #ifdef CONFIG_RELOCATABLE
 250         mr      r3,r30
 251         mr      r4,r31
 252 #ifdef CONFIG_PHYS_64BIT
 253         mr      r5,r23
 254         mr      r6,r25
 255 #else
 256         mr      r5,r25
 257 #endif
 258         bl      relocate_init
 259 #endif
 260
 261 #ifdef CONFIG_DYNAMIC_MEMSTART
 262         lis     r3,kernstart_addr@ha
 263         la      r3,kernstart_addr@l(r3)
 264 #ifdef CONFIG_PHYS_64BIT
 265         stw     r23,0(r3)
 266         stw     r25,4(r3)
 267 #else
 268         stw     r25,0(r3)
 269 #endif
 270 #endif
 271
 272 /*
 273  * Decide what sort of machine this is and initialize the MMU.
 274  */
 275         mr      r3,r30
 276         mr      r4,r31
 277         bl      machine_init
 278         bl      MMU_init
 279
 280         /* Setup PTE pointers for the Abatron bdiGDB */
 281         lis     r6, swapper_pg_dir@h
 282         ori     r6, r6, swapper_pg_dir@l
 283         lis     r5, abatron_pteptrs@h
 284         ori     r5, r5, abatron_pteptrs@l
 285         lis     r4, KERNELBASE@h
 286         ori     r4, r4, KERNELBASE@l
 287         stw     r5, 0(r4)       /* Save abatron_pteptrs at a fixed location */
 288         stw     r6, 0(r5)
 289
 290         /* Let's move on */
 291         lis     r4,start_kernel@h
 292         ori     r4,r4,start_kernel@l
 293         lis     r3,MSR_KERNEL@h
 294         ori     r3,r3,MSR_KERNEL@l
 295         mtspr   SPRN_SRR0,r4
 296         mtspr   SPRN_SRR1,r3
 297         rfi                     /* change context and jump to start_kernel */
 298
 299 /* Macros to hide the PTE size differences
 300  *
 301  * FIND_PTE -- walks the page tables given EA & pgdir pointer
 302  *   r10 -- EA of fault
 303  *   r11 -- PGDIR pointer
 304  *   r12 -- free
 305  *   label 2: is the bailout case
 306  *
 307  * if we find the pte (fall through):
 308  *   r11 is low pte word
 309  *   r12 is pointer to the pte
 310  *   r10 is the pshift from the PGD, if we're a hugepage
 311  */
 312 #ifdef CONFIG_PTE_64BIT
 313 #ifdef CONFIG_HUGETLB_PAGE
 314 #define FIND_PTE        \
 315         rlwinm  r12, r10, 13, 19, 29;   /* Compute pgdir/pmd offset */  \
 316         lwzx    r11, r12, r11;          /* Get pgd/pmd entry */         \
 317         rlwinm. r12, r11, 0, 0, 20;     /* Extract pt base address */   \
 318         blt     1000f;                  /* Normal non-huge page */      \
 319         beq     2f;                     /* Bail if no table */          \
 320         oris    r11, r11, PD_HUGE@h;    /* Put back address bit */      \
 321         andi.   r10, r11, HUGEPD_SHIFT_MASK@l; /* extract size field */ \
 322         xor     r12, r10, r11;          /* drop size bits from pointer */ \
 323         b       1001f;                                                  \
 324 1000:   rlwimi  r12, r10, 23, 20, 28;   /* Compute pte address */       \
 325         li      r10, 0;                 /* clear r10 */                 \
 326 1001:   lwz     r11, 4(r12);            /* Get pte entry */
 327 #else
 328 #define FIND_PTE        \
 329         rlwinm  r12, r10, 13, 19, 29;   /* Compute pgdir/pmd offset */  \
 330         lwzx    r11, r12, r11;          /* Get pgd/pmd entry */         \
 331         rlwinm. r12, r11, 0, 0, 20;     /* Extract pt base address */   \
 332         beq     2f;                     /* Bail if no table */          \
 333         rlwimi  r12, r10, 23, 20, 28;   /* Compute pte address */       \
 334         lwz     r11, 4(r12);            /* Get pte entry */
 335 #endif /* HUGEPAGE */
 336 #else /* !PTE_64BIT */
 337 #define FIND_PTE        \
 338         rlwimi  r11, r10, 12, 20, 29;   /* Create L1 (pgdir/pmd) address */     \
 339         lwz     r11, 0(r11);            /* Get L1 entry */                      \
 340         rlwinm. r12, r11, 0, 0, 19;     /* Extract L2 (pte) base address */     \
 341         beq     2f;                     /* Bail if no table */                  \
 342         rlwimi  r12, r10, 22, 20, 29;   /* Compute PTE address */               \
 343         lwz     r11, 0(r12);            /* Get Linux PTE */
 344 #endif
 345
 346 /*
 347  * Interrupt vector entry code
 348  *
 349  * The Book E MMUs are always on so we don't need to handle
 350  * interrupts in real mode as with previous PPC processors. In
 351  * this case we handle interrupts in the kernel virtual address
 352  * space.
 353  *
 354  * Interrupt vectors are dynamically placed relative to the
 355  * interrupt prefix as determined by the address of interrupt_base.
 356  * The interrupt vectors offsets are programmed using the labels
 357  * for each interrupt vector entry.
 358  *
 359  * Interrupt vectors must be aligned on a 16 byte boundary.
 360  * We align on a 32 byte cache line boundary for good measure.
 361  */
 362
 363 interrupt_base:
 364         /* Critical Input Interrupt */
 365         CRITICAL_EXCEPTION(0x0100, CRITICAL, CriticalInput, unknown_exception)
 366
 367         /* Machine Check Interrupt */
 368 #ifdef CONFIG_E200
 369         /* no RFMCI, MCSRRs on E200 */
 370         CRITICAL_EXCEPTION(0x0200, MACHINE_CHECK, MachineCheck, \
 371                            machine_check_exception)
 372 #else
 373         MCHECK_EXCEPTION(0x0200, MachineCheck, machine_check_exception)
 374 #endif
 375
 376         /* Data Storage Interrupt */
 377         START_EXCEPTION(DataStorage)
 378         NORMAL_EXCEPTION_PROLOG(DATA_STORAGE)
 379         mfspr   r5,SPRN_ESR             /* Grab the ESR, save it, pass arg3 */
 380         stw     r5,_ESR(r11)
 381         mfspr   r4,SPRN_DEAR            /* Grab the DEAR, save it, pass arg2 */
 382         andis.  r10,r5,(ESR_ILK|ESR_DLK)@h
 383         bne     1f
 384         EXC_XFER_LITE(0x0300, handle_page_fault)
 385 1:
 386         addi    r3,r1,STACK_FRAME_OVERHEAD
 387         EXC_XFER_EE_LITE(0x0300, CacheLockingException)
 388
 389         /* Instruction Storage Interrupt */
 390         INSTRUCTION_STORAGE_EXCEPTION
 391
 392         /* External Input Interrupt */
 393         EXCEPTION(0x0500, EXTERNAL, ExternalInput, do_IRQ, EXC_XFER_LITE)
 394
 395         /* Alignment Interrupt */
 396         ALIGNMENT_EXCEPTION
 397
 398         /* Program Interrupt */
 399         PROGRAM_EXCEPTION
 400
 401         /* Floating Point Unavailable Interrupt */
 402 #ifdef CONFIG_PPC_FPU
 403         FP_UNAVAILABLE_EXCEPTION
 404 #else
 405 #ifdef CONFIG_E200
 406         /* E200 treats 'normal' floating point instructions as FP Unavail exception */
 407         EXCEPTION(0x0800, FP_UNAVAIL, FloatingPointUnavailable, \
 408                   program_check_exception, EXC_XFER_EE)
 409 #else
 410         EXCEPTION(0x0800, FP_UNAVAIL, FloatingPointUnavailable, \
 411                   unknown_exception, EXC_XFER_EE)
 412 #endif
 413 #endif
 414
 415         /* System Call Interrupt */
 416         START_EXCEPTION(SystemCall)
 417         NORMAL_EXCEPTION_PROLOG(SYSCALL)
 418         EXC_XFER_EE_LITE(0x0c00, DoSyscall)
 419
 420         /* Auxiliary Processor Unavailable Interrupt */
 421         EXCEPTION(0x2900, AP_UNAVAIL, AuxillaryProcessorUnavailable, \
 422                   unknown_exception, EXC_XFER_EE)
 423
 424         /* Decrementer Interrupt */
 425         DECREMENTER_EXCEPTION
 426
 427         /* Fixed Internal Timer Interrupt */
 428         /* TODO: Add FIT support */
 429         EXCEPTION(0x3100, FIT, FixedIntervalTimer, \
 430                   unknown_exception, EXC_XFER_EE)
 431
 432         /* Watchdog Timer Interrupt */
 433 #ifdef CONFIG_BOOKE_WDT
 434         CRITICAL_EXCEPTION(0x3200, WATCHDOG, WatchdogTimer, WatchdogException)
 435 #else
 436         CRITICAL_EXCEPTION(0x3200, WATCHDOG, WatchdogTimer, unknown_exception)
 437 #endif
 438
 439         /* Data TLB Error Interrupt */
 440         START_EXCEPTION(DataTLBError)
 441         mtspr   SPRN_SPRG_WSCRATCH0, r10 /* Save some working registers */
 442         mfspr   r10, SPRN_SPRG_THREAD
 443         stw     r11, THREAD_NORMSAVE(0)(r10)
 444 #ifdef CONFIG_KVM_BOOKE_HV
 445 BEGIN_FTR_SECTION
 446         mfspr   r11, SPRN_SRR1
 447 END_FTR_SECTION_IFSET(CPU_FTR_EMB_HV)
 448 #endif
 449         stw     r12, THREAD_NORMSAVE(1)(r10)
 450         stw     r13, THREAD_NORMSAVE(2)(r10)
 451         mfcr    r13
 452         stw     r13, THREAD_NORMSAVE(3)(r10)
 453         DO_KVM  BOOKE_INTERRUPT_DTLB_MISS SPRN_SRR1
 454 START_BTB_FLUSH_SECTION
 455         mfspr r11, SPRN_SRR1
 456         andi. r10,r11,MSR_PR
 457         beq 1f
 458         BTB_FLUSH(r10)
 459 1:
 460 END_BTB_FLUSH_SECTION
 461         mfspr   r10, SPRN_DEAR          /* Get faulting address */
 462
 463         /* If we are faulting a kernel address, we have to use the
 464          * kernel page tables.
 465          */
 466         lis     r11, PAGE_OFFSET@h
 467         cmplw   5, r10, r11
 468         blt     5, 3f
 469         lis     r11, swapper_pg_dir@h
 470         ori     r11, r11, swapper_pg_dir@l
 471
 472         mfspr   r12,SPRN_MAS1           /* Set TID to 0 */
 473         rlwinm  r12,r12,0,16,1
 474         mtspr   SPRN_MAS1,r12
 475
 476         b       4f
 477
 478         /* Get the PGD for the current thread */
 479 3:
 480         mfspr   r11,SPRN_SPRG_THREAD
 481         lwz     r11,PGDIR(r11)
 482
 483 4:
 484         /* Mask of required permission bits. Note that while we
 485          * do copy ESR:ST to _PAGE_RW position as trying to write
 486          * to an RO page is pretty common, we don't do it with
 487          * _PAGE_DIRTY. We could do it, but it's a fairly rare
 488          * event so I'd rather take the overhead when it happens
 489          * rather than adding an instruction here. We should measure
 490          * whether the whole thing is worth it in the first place
 491          * as we could avoid loading SPRN_ESR completely in the first
 492          * place...
 493          *
 494          * TODO: Is it worth doing that mfspr & rlwimi in the first
 495          *       place or can we save a couple of instructions here ?
 496          */
 497         mfspr   r12,SPRN_ESR
 498 #ifdef CONFIG_PTE_64BIT
 499         li      r13,_PAGE_PRESENT
 500         oris    r13,r13,_PAGE_ACCESSED@h
 501 #else
 502         li      r13,_PAGE_PRESENT|_PAGE_ACCESSED
 503 #endif
 504         rlwimi  r13,r12,11,29,29
 505
 506         FIND_PTE
 507         andc.   r13,r13,r11             /* Check permission */
 508
 509 #ifdef CONFIG_PTE_64BIT
 510 #ifdef CONFIG_SMP
 511         subf    r13,r11,r12             /* create false data dep */
 512         lwzx    r13,r11,r13             /* Get upper pte bits */
 513 #else
 514         lwz     r13,0(r12)              /* Get upper pte bits */
 515 #endif
 516 #endif
 517
 518         bne     2f                      /* Bail if permission/valid mismach */
 519
 520         /* Jump to common tlb load */
 521         b       finish_tlb_load
 522 2:
 523         /* The bailout.  Restore registers to pre-exception conditions
 524          * and call the heavyweights to help us out.
 525          */
 526         mfspr   r10, SPRN_SPRG_THREAD
 527         lwz     r11, THREAD_NORMSAVE(3)(r10)
 528         mtcr    r11
 529         lwz     r13, THREAD_NORMSAVE(2)(r10)
 530         lwz     r12, THREAD_NORMSAVE(1)(r10)
 531         lwz     r11, THREAD_NORMSAVE(0)(r10)
 532         mfspr   r10, SPRN_SPRG_RSCRATCH0
 533         b       DataStorage
 534
 535         /* Instruction TLB Error Interrupt */
 536         /*
 537          * Nearly the same as above, except we get our
 538          * information from different registers and bailout
 539          * to a different point.
 540          */
 541         START_EXCEPTION(InstructionTLBError)
 542         mtspr   SPRN_SPRG_WSCRATCH0, r10 /* Save some working registers */
 543         mfspr   r10, SPRN_SPRG_THREAD
 544         stw     r11, THREAD_NORMSAVE(0)(r10)
 545 #ifdef CONFIG_KVM_BOOKE_HV
 546 BEGIN_FTR_SECTION
 547         mfspr   r11, SPRN_SRR1
 548 END_FTR_SECTION_IFSET(CPU_FTR_EMB_HV)
 549 #endif
 550         stw     r12, THREAD_NORMSAVE(1)(r10)
 551         stw     r13, THREAD_NORMSAVE(2)(r10)
 552         mfcr    r13
 553         stw     r13, THREAD_NORMSAVE(3)(r10)
 554         DO_KVM  BOOKE_INTERRUPT_ITLB_MISS SPRN_SRR1
 555 START_BTB_FLUSH_SECTION
 556         mfspr r11, SPRN_SRR1
 557         andi. r10,r11,MSR_PR
 558         beq 1f
 559         BTB_FLUSH(r10)
 560 1:
 561 END_BTB_FLUSH_SECTION
 562
 563         mfspr   r10, SPRN_SRR0          /* Get faulting address */
 564
 565         /* If we are faulting a kernel address, we have to use the
 566          * kernel page tables.
 567          */
 568         lis     r11, PAGE_OFFSET@h
 569         cmplw   5, r10, r11
 570         blt     5, 3f
 571         lis     r11, swapper_pg_dir@h
 572         ori     r11, r11, swapper_pg_dir@l
 573
 574         mfspr   r12,SPRN_MAS1           /* Set TID to 0 */
 575         rlwinm  r12,r12,0,16,1
 576         mtspr   SPRN_MAS1,r12
 577
 578         /* Make up the required permissions for kernel code */
 579 #ifdef CONFIG_PTE_64BIT
 580         li      r13,_PAGE_PRESENT | _PAGE_BAP_SX
 581         oris    r13,r13,_PAGE_ACCESSED@h
 582 #else
 583         li      r13,_PAGE_PRESENT | _PAGE_ACCESSED | _PAGE_EXEC
 584 #endif
 585         b       4f
 586
 587         /* Get the PGD for the current thread */
 588 3:
 589         mfspr   r11,SPRN_SPRG_THREAD
 590         lwz     r11,PGDIR(r11)
 591
 592         /* Make up the required permissions for user code */
 593 #ifdef CONFIG_PTE_64BIT
 594         li      r13,_PAGE_PRESENT | _PAGE_BAP_UX
 595         oris    r13,r13,_PAGE_ACCESSED@h
 596 #else
 597         li      r13,_PAGE_PRESENT | _PAGE_ACCESSED | _PAGE_EXEC
 598 #endif
 599
 600 4:
 601         FIND_PTE
 602         andc.   r13,r13,r11             /* Check permission */
 603
 604 #ifdef CONFIG_PTE_64BIT
 605 #ifdef CONFIG_SMP
 606         subf    r13,r11,r12             /* create false data dep */
 607         lwzx    r13,r11,r13             /* Get upper pte bits */
 608 #else
 609         lwz     r13,0(r12)              /* Get upper pte bits */
 610 #endif
 611 #endif
 612
 613         bne     2f                      /* Bail if permission mismach */
 614
 615         /* Jump to common TLB load point */
 616         b       finish_tlb_load
 617
 618 2:
 619         /* The bailout.  Restore registers to pre-exception conditions
 620          * and call the heavyweights to help us out.
 621          */
 622         mfspr   r10, SPRN_SPRG_THREAD
 623         lwz     r11, THREAD_NORMSAVE(3)(r10)
 624         mtcr    r11
 625         lwz     r13, THREAD_NORMSAVE(2)(r10)
 626         lwz     r12, THREAD_NORMSAVE(1)(r10)
 627         lwz     r11, THREAD_NORMSAVE(0)(r10)
 628         mfspr   r10, SPRN_SPRG_RSCRATCH0
 629         b       InstructionStorage
 630
 631 /* Define SPE handlers for e200 and e500v2 */
 632 #ifdef CONFIG_SPE
 633         /* SPE Unavailable */
 634         START_EXCEPTION(SPEUnavailable)
 635         NORMAL_EXCEPTION_PROLOG(SPE_UNAVAIL)
 636         beq     1f
 637         bl      load_up_spe
 638         b       fast_exception_return
 639 1:      addi    r3,r1,STACK_FRAME_OVERHEAD
 640         EXC_XFER_EE_LITE(0x2010, KernelSPE)
 641 #elif defined(CONFIG_SPE_POSSIBLE)
 642         EXCEPTION(0x2020, SPE_UNAVAIL, SPEUnavailable, \
 643                   unknown_exception, EXC_XFER_EE)
 644 #endif /* CONFIG_SPE_POSSIBLE */
 645
 646         /* SPE Floating Point Data */
 647 #ifdef CONFIG_SPE
 648         EXCEPTION(0x2030, SPE_FP_DATA, SPEFloatingPointData,
 649                   SPEFloatingPointException, EXC_XFER_EE)
 650
 651         /* SPE Floating Point Round */
 652         EXCEPTION(0x2050, SPE_FP_ROUND, SPEFloatingPointRound, \
 653                   SPEFloatingPointRoundException, EXC_XFER_EE)
 654 #elif defined(CONFIG_SPE_POSSIBLE)
 655         EXCEPTION(0x2040, SPE_FP_DATA, SPEFloatingPointData,
 656                   unknown_exception, EXC_XFER_EE)
 657         EXCEPTION(0x2050, SPE_FP_ROUND, SPEFloatingPointRound, \
 658                   unknown_exception, EXC_XFER_EE)
 659 #endif /* CONFIG_SPE_POSSIBLE */
 660
 661
 662         /* Performance Monitor */
 663         EXCEPTION(0x2060, PERFORMANCE_MONITOR, PerformanceMonitor, \
 664                   performance_monitor_exception, EXC_XFER_STD)
 665
 666         EXCEPTION(0x2070, DOORBELL, Doorbell, doorbell_exception, EXC_XFER_STD)
 667
 668         CRITICAL_EXCEPTION(0x2080, DOORBELL_CRITICAL, \
 669                            CriticalDoorbell, unknown_exception)
 670
 671         /* Debug Interrupt */
 672         DEBUG_DEBUG_EXCEPTION
 673         DEBUG_CRIT_EXCEPTION
 674
 675         GUEST_DOORBELL_EXCEPTION
 676
 677         CRITICAL_EXCEPTION(0, GUEST_DBELL_CRIT, CriticalGuestDoorbell, \
 678                            unknown_exception)
 679
 680         /* Hypercall */
 681         EXCEPTION(0, HV_SYSCALL, Hypercall, unknown_exception, EXC_XFER_EE)
 682
 683         /* Embedded Hypervisor Privilege */
 684         EXCEPTION(0, HV_PRIV, Ehvpriv, unknown_exception, EXC_XFER_EE)
 685
 686 interrupt_end:
 687
 688 /*
 689  * Local functions
 690  */
 691
 692 /*
 693  * Both the instruction and data TLB miss get to this
 694  * point to load the TLB.
 695  *      r10 - tsize encoding (if HUGETLB_PAGE) or available to use
 696  *      r11 - TLB (info from Linux PTE)
 697  *      r12 - available to use
 698  *      r13 - upper bits of PTE (if PTE_64BIT) or available to use
 699  *      CR5 - results of addr >= PAGE_OFFSET
 700  *      MAS0, MAS1 - loaded with proper value when we get here
 701  *      MAS2, MAS3 - will need additional info from Linux PTE
 702  *      Upon exit, we reload everything and RFI.
 703  */
 704 finish_tlb_load:
 705 #ifdef CONFIG_HUGETLB_PAGE
 706         cmpwi   6, r10, 0                       /* check for huge page */
 707         beq     6, finish_tlb_load_cont         /* !huge */
 708
 709         /* Alas, we need more scratch registers for hugepages */
 710         mfspr   r12, SPRN_SPRG_THREAD
 711         stw     r14, THREAD_NORMSAVE(4)(r12)
 712         stw     r15, THREAD_NORMSAVE(5)(r12)
 713         stw     r16, THREAD_NORMSAVE(6)(r12)
 714         stw     r17, THREAD_NORMSAVE(7)(r12)
 715
 716         /* Get the next_tlbcam_idx percpu var */
 717 #ifdef CONFIG_SMP
 718         lwz     r12, THREAD_INFO-THREAD(r12)
 719         lwz     r15, TI_CPU(r12)
 720         lis     r14, __per_cpu_offset@h
 721         ori     r14, r14, __per_cpu_offset@l
 722         rlwinm  r15, r15, 2, 0, 29
 723         lwzx    r16, r14, r15
 724 #else
 725         li      r16, 0
 726 #endif
 727         lis     r17, next_tlbcam_idx@h
 728         ori     r17, r17, next_tlbcam_idx@l
 729         add     r17, r17, r16                   /* r17 = *next_tlbcam_idx */
 730         lwz     r15, 0(r17)                     /* r15 = next_tlbcam_idx */
 731
 732         lis     r14, MAS0_TLBSEL(1)@h           /* select TLB1 (TLBCAM) */
 733         rlwimi  r14, r15, 16, 4, 15             /* next_tlbcam_idx entry */
 734         mtspr   SPRN_MAS0, r14
 735
 736         /* Extract TLB1CFG(NENTRY) */
 737         mfspr   r16, SPRN_TLB1CFG
 738         andi.   r16, r16, 0xfff
 739
 740         /* Update next_tlbcam_idx, wrapping when necessary */
 741         addi    r15, r15, 1
 742         cmpw    r15, r16
 743         blt     100f
 744         lis     r14, tlbcam_index@h
 745         ori     r14, r14, tlbcam_index@l
 746         lwz     r15, 0(r14)
 747 100:    stw     r15, 0(r17)
 748
 749         /*
 750          * Calc MAS1_TSIZE from r10 (which has pshift encoded)
 751          * tlb_enc = (pshift - 10).
 752          */
 753         subi    r15, r10, 10
 754         mfspr   r16, SPRN_MAS1
 755         rlwimi  r16, r15, 7, 20, 24
 756         mtspr   SPRN_MAS1, r16
 757
 758         /* copy the pshift for use later */
 759         mr      r14, r10
 760
 761         /* fall through */
 762
 763 #endif /* CONFIG_HUGETLB_PAGE */
 764
 765         /*
 766          * We set execute, because we don't have the granularity to
 767          * properly set this at the page level (Linux problem).
 768          * Many of these bits are software only.  Bits we don't set
 769          * here we (properly should) assume have the appropriate value.
 770          */
 771 finish_tlb_load_cont:
 772 #ifdef CONFIG_PTE_64BIT
 773         rlwinm  r12, r11, 32-2, 26, 31  /* Move in perm bits */
 774         andi.   r10, r11, _PAGE_DIRTY
 775         bne     1f
 776         li      r10, MAS3_SW | MAS3_UW
 777         andc    r12, r12, r10
 778 1:      rlwimi  r12, r13, 20, 0, 11     /* grab RPN[32:43] */
 779         rlwimi  r12, r11, 20, 12, 19    /* grab RPN[44:51] */
 780 2:      mtspr   SPRN_MAS3, r12
 781 BEGIN_MMU_FTR_SECTION
 782         srwi    r10, r13, 12            /* grab RPN[12:31] */
 783         mtspr   SPRN_MAS7, r10
 784 END_MMU_FTR_SECTION_IFSET(MMU_FTR_BIG_PHYS)
 785 #else
 786         li      r10, (_PAGE_EXEC | _PAGE_PRESENT)
 787         mr      r13, r11
 788         rlwimi  r10, r11, 31, 29, 29    /* extract _PAGE_DIRTY into SW */
 789         and     r12, r11, r10
 790         andi.   r10, r11, _PAGE_USER    /* Test for _PAGE_USER */
 791         slwi    r10, r12, 1
 792         or      r10, r10, r12
 793         iseleq  r12, r12, r10
 794         rlwimi  r13, r12, 0, 20, 31     /* Get RPN from PTE, merge w/ perms */
 795         mtspr   SPRN_MAS3, r13
 796 #endif
 797
 798         mfspr   r12, SPRN_MAS2
 799 #ifdef CONFIG_PTE_64BIT
 800         rlwimi  r12, r11, 32-19, 27, 31 /* extract WIMGE from pte */
 801 #else
 802         rlwimi  r12, r11, 26, 27, 31    /* extract WIMGE from pte */
 803 #endif
 804 #ifdef CONFIG_HUGETLB_PAGE
 805         beq     6, 3f                   /* don't mask if page isn't huge */
 806         li      r13, 1
 807         slw     r13, r13, r14
 808         subi    r13, r13, 1
 809         rlwinm  r13, r13, 0, 0, 19      /* bottom bits used for WIMGE/etc */
 810         andc    r12, r12, r13           /* mask off ea bits within the page */
 811 #endif
 812 3:      mtspr   SPRN_MAS2, r12
 813
 814 #ifdef CONFIG_E200
 815         /* Round robin TLB1 entries assignment */
 816         mfspr   r12, SPRN_MAS0
 817
 818         /* Extract TLB1CFG(NENTRY) */
 819         mfspr   r11, SPRN_TLB1CFG
 820         andi.   r11, r11, 0xfff
 821
 822         /* Extract MAS0(NV) */
 823         andi.   r13, r12, 0xfff
 824         addi    r13, r13, 1
 825         cmpw    0, r13, r11
 826         addi    r12, r12, 1
 827
 828         /* check if we need to wrap */
 829         blt     7f
 830
 831         /* wrap back to first free tlbcam entry */
 832         lis     r13, tlbcam_index@ha
 833         lwz     r13, tlbcam_index@l(r13)
 834         rlwimi  r12, r13, 0, 20, 31
 835 7:
 836         mtspr   SPRN_MAS0,r12
 837 #endif /* CONFIG_E200 */
 838
 839 tlb_write_entry:
 840         tlbwe
 841
 842         /* Done...restore registers and get out of here.  */
 843         mfspr   r10, SPRN_SPRG_THREAD
 844 #ifdef CONFIG_HUGETLB_PAGE
 845         beq     6, 8f /* skip restore for 4k page faults */
 846         lwz     r14, THREAD_NORMSAVE(4)(r10)
 847         lwz     r15, THREAD_NORMSAVE(5)(r10)
 848         lwz     r16, THREAD_NORMSAVE(6)(r10)
 849         lwz     r17, THREAD_NORMSAVE(7)(r10)
 850 #endif
 851 8:      lwz     r11, THREAD_NORMSAVE(3)(r10)
 852         mtcr    r11
 853         lwz     r13, THREAD_NORMSAVE(2)(r10)
 854         lwz     r12, THREAD_NORMSAVE(1)(r10)
 855         lwz     r11, THREAD_NORMSAVE(0)(r10)
 856         mfspr   r10, SPRN_SPRG_RSCRATCH0
 857         rfi                                     /* Force context change */
 858
 859 #ifdef CONFIG_SPE
 860 /* Note that the SPE support is closely modeled after the AltiVec
 861  * support.  Changes to one are likely to be applicable to the
 862  * other!  */
 863 _GLOBAL(load_up_spe)
 864 /*
 865  * Disable SPE for the task which had SPE previously,
 866  * and save its SPE registers in its thread_struct.
 867  * Enables SPE for use in the kernel on return.
 868  * On SMP we know the SPE units are free, since we give it up every
 869  * switch.  -- Kumar
 870  */
 871         mfmsr   r5
 872         oris    r5,r5,MSR_SPE@h
 873         mtmsr   r5                      /* enable use of SPE now */
 874         isync
 875 /*
 876  * For SMP, we don't do lazy SPE switching because it just gets too
 877  * horrendously complex, especially when a task switches from one CPU
 878  * to another.  Instead we call giveup_spe in switch_to.
 879  */
 880 #ifndef CONFIG_SMP
 881         lis     r3,last_task_used_spe@ha
 882         lwz     r4,last_task_used_spe@l(r3)
 883         cmpi    0,r4,0
 884         beq     1f
 885         addi    r4,r4,THREAD    /* want THREAD of last_task_used_spe */
 886         SAVE_32EVRS(0,r10,r4,THREAD_EVR0)
 887         evxor   evr10, evr10, evr10     /* clear out evr10 */
 888         evmwumiaa evr10, evr10, evr10   /* evr10 <- ACC = 0 * 0 + ACC */
 889         li      r5,THREAD_ACC
 890         evstddx evr10, r4, r5           /* save off accumulator */
 891         lwz     r5,PT_REGS(r4)
 892         lwz     r4,_MSR-STACK_FRAME_OVERHEAD(r5)
 893         lis     r10,MSR_SPE@h
 894         andc    r4,r4,r10       /* disable SPE for previous task */
 895         stw     r4,_MSR-STACK_FRAME_OVERHEAD(r5)
 896 1:
 897 #endif /* !CONFIG_SMP */
 898         /* enable use of SPE after return */
 899         oris    r9,r9,MSR_SPE@h
 900         mfspr   r5,SPRN_SPRG_THREAD     /* current task's THREAD (phys) */
 901         li      r4,1
 902         li      r10,THREAD_ACC
 903         stw     r4,THREAD_USED_SPE(r5)
 904         evlddx  evr4,r10,r5
 905         evmra   evr4,evr4
 906         REST_32EVRS(0,r10,r5,THREAD_EVR0)
 907 #ifndef CONFIG_SMP
 908         subi    r4,r5,THREAD
 909         stw     r4,last_task_used_spe@l(r3)
 910 #endif /* !CONFIG_SMP */
 911         blr
 912
 913 /*
 914  * SPE unavailable trap from kernel - print a message, but let
 915  * the task use SPE in the kernel until it returns to user mode.
 916  */
 917 KernelSPE:
 918         lwz     r3,_MSR(r1)
 919         oris    r3,r3,MSR_SPE@h
 920         stw     r3,_MSR(r1)     /* enable use of SPE after return */
 921 #ifdef CONFIG_PRINTK
 922         lis     r3,87f@h
 923         ori     r3,r3,87f@l
 924         mr      r4,r2           /* current */
 925         lwz     r5,_NIP(r1)
 926         bl      printk
 927 #endif
 928         b       ret_from_except
 929 #ifdef CONFIG_PRINTK
 930 87:     .string "SPE used in kernel  (task=%p, pc=%x)  \n"
 931 #endif
 932         .align  4,0
 933
 934 #endif /* CONFIG_SPE */
 935
 936 /*
 937  * Translate the effec addr in r3 to phys addr. The phys addr will be put
 938  * into r3(higher 32bit) and r4(lower 32bit)
 939  */
 940 get_phys_addr:
 941         mfmsr   r8
 942         mfspr   r9,SPRN_PID
 943         rlwinm  r9,r9,16,0x3fff0000     /* turn PID into MAS6[SPID] */
 944         rlwimi  r9,r8,28,0x00000001     /* turn MSR[DS] into MAS6[SAS] */
 945         mtspr   SPRN_MAS6,r9
 946
 947         tlbsx   0,r3                    /* must succeed */
 948
 949         mfspr   r8,SPRN_MAS1
 950         mfspr   r12,SPRN_MAS3
 951         rlwinm  r9,r8,25,0x1f           /* r9 = log2(page size) */
 952         li      r10,1024
 953         slw     r10,r10,r9              /* r10 = page size */
 954         addi    r10,r10,-1
 955         and     r11,r3,r10              /* r11 = page offset */
 956         andc    r4,r12,r10              /* r4 = page base */
 957         or      r4,r4,r11               /* r4 = devtree phys addr */
 958 #ifdef CONFIG_PHYS_64BIT
 959         mfspr   r3,SPRN_MAS7
 960 #endif
 961         blr
 962
 963 /*
 964  * Global functions
 965  */
 966
 967 #ifdef CONFIG_E200
 968 /* Adjust or setup IVORs for e200 */
 969 _GLOBAL(__setup_e200_ivors)
 970         li      r3,DebugDebug@l
 971         mtspr   SPRN_IVOR15,r3
 972         li      r3,SPEUnavailable@l
 973         mtspr   SPRN_IVOR32,r3
 974         li      r3,SPEFloatingPointData@l
 975         mtspr   SPRN_IVOR33,r3
 976         li      r3,SPEFloatingPointRound@l
 977         mtspr   SPRN_IVOR34,r3
 978         sync
 979         blr
 980 #endif
 981
 982 #ifdef CONFIG_E500
 983 #ifndef CONFIG_PPC_E500MC
 984 /* Adjust or setup IVORs for e500v1/v2 */
 985 _GLOBAL(__setup_e500_ivors)
 986         li      r3,DebugCrit@l
 987         mtspr   SPRN_IVOR15,r3
 988         li      r3,SPEUnavailable@l
 989         mtspr   SPRN_IVOR32,r3
 990         li      r3,SPEFloatingPointData@l
 991         mtspr   SPRN_IVOR33,r3
 992         li      r3,SPEFloatingPointRound@l
 993         mtspr   SPRN_IVOR34,r3
 994         li      r3,PerformanceMonitor@l
 995         mtspr   SPRN_IVOR35,r3
 996         sync
 997         blr
 998 #else
 999 /* Adjust or setup IVORs for e500mc */
1000 _GLOBAL(__setup_e500mc_ivors)
1001         li      r3,DebugDebug@l
1002         mtspr   SPRN_IVOR15,r3
1003         li      r3,PerformanceMonitor@l
1004         mtspr   SPRN_IVOR35,r3
1005         li      r3,Doorbell@l
1006         mtspr   SPRN_IVOR36,r3
1007         li      r3,CriticalDoorbell@l
1008         mtspr   SPRN_IVOR37,r3
1009         sync
1010         blr
1011
1012 /* setup ehv ivors for */
1013 _GLOBAL(__setup_ehv_ivors)
1014         li      r3,GuestDoorbell@l
1015         mtspr   SPRN_IVOR38,r3
1016         li      r3,CriticalGuestDoorbell@l
1017         mtspr   SPRN_IVOR39,r3
1018         li      r3,Hypercall@l
1019         mtspr   SPRN_IVOR40,r3
1020         li      r3,Ehvpriv@l
1021         mtspr   SPRN_IVOR41,r3
1022         sync
1023         blr
1024 #endif /* CONFIG_PPC_E500MC */
1025 #endif /* CONFIG_E500 */
1026
1027 #ifdef CONFIG_SPE
1028 /*
1029  * extern void giveup_spe(struct task_struct *prev)
1030  *
1031  */
1032 _GLOBAL(giveup_spe)
1033         mfmsr   r5
1034         oris    r5,r5,MSR_SPE@h
1035         mtmsr   r5                      /* enable use of SPE now */
1036         isync
1037         cmpi    0,r3,0
1038         beqlr-                          /* if no previous owner, done */
1039         addi    r3,r3,THREAD            /* want THREAD of task */
1040         lwz     r5,PT_REGS(r3)
1041         cmpi    0,r5,0
1042         SAVE_32EVRS(0, r4, r3, THREAD_EVR0)
1043         evxor   evr6, evr6, evr6        /* clear out evr6 */
1044         evmwumiaa evr6, evr6, evr6      /* evr6 <- ACC = 0 * 0 + ACC */
1045         li      r4,THREAD_ACC
1046         evstddx evr6, r4, r3            /* save off accumulator */
1047         beq     1f
1048         lwz     r4,_MSR-STACK_FRAME_OVERHEAD(r5)
1049         lis     r3,MSR_SPE@h
1050         andc    r4,r4,r3                /* disable SPE for previous task */
1051         stw     r4,_MSR-STACK_FRAME_OVERHEAD(r5)
1052 1:
1053 #ifndef CONFIG_SMP
1054         li      r5,0
1055         lis     r4,last_task_used_spe@ha
1056         stw     r5,last_task_used_spe@l(r4)
1057 #endif /* !CONFIG_SMP */
1058         blr
1059 #endif /* CONFIG_SPE */
1060
1061 /*
1062  * extern void abort(void)
1063  *
1064  * At present, this routine just applies a system reset.
1065  */
1066 _GLOBAL(abort)
1067         li      r13,0
1068         mtspr   SPRN_DBCR0,r13          /* disable all debug events */
1069         isync
1070         mfmsr   r13
1071         ori     r13,r13,MSR_DE@l        /* Enable Debug Events */
1072         mtmsr   r13
1073         isync
1074         mfspr   r13,SPRN_DBCR0
1075         lis     r13,(DBCR0_IDM|DBCR0_RST_CHIP)@h
1076         mtspr   SPRN_DBCR0,r13
1077         isync
1078
1079 _GLOBAL(set_context)
1080
1081 #ifdef CONFIG_BDI_SWITCH
1082         /* Context switch the PTE pointer for the Abatron BDI2000.
1083          * The PGDIR is the second parameter.
1084          */
1085         lis     r5, abatron_pteptrs@h
1086         ori     r5, r5, abatron_pteptrs@l
1087         stw     r4, 0x4(r5)
1088 #endif
1089         mtspr   SPRN_PID,r3
1090         isync                   /* Force context change */
1091         blr
1092
1093 _GLOBAL(flush_dcache_L1)
1094         mfspr   r3,SPRN_L1CFG0
1095
1096         rlwinm  r5,r3,9,3       /* Extract cache block size */
1097         twlgti  r5,1            /* Only 32 and 64 byte cache blocks
1098                                  * are currently defined.
1099                                  */
1100         li      r4,32
1101         subfic  r6,r5,2         /* r6 = log2(1KiB / cache block size) -
1102                                  *      log2(number of ways)
1103                                  */
1104         slw     r5,r4,r5        /* r5 = cache block size */
1105
1106         rlwinm  r7,r3,0,0xff    /* Extract number of KiB in the cache */
1107         mulli   r7,r7,13        /* An 8-way cache will require 13
1108                                  * loads per set.
1109                                  */
1110         slw     r7,r7,r6
1111
1112         /* save off HID0 and set DCFA */
1113         mfspr   r8,SPRN_HID0
1114         ori     r9,r8,HID0_DCFA@l
1115         mtspr   SPRN_HID0,r9
1116         isync
1117
1118         lis     r4,KERNELBASE@h
1119         mtctr   r7
1120
1121 1:      lwz     r3,0(r4)        /* Load... */
1122         add     r4,r4,r5
1123         bdnz    1b
1124
1125         msync
1126         lis     r4,KERNELBASE@h
1127         mtctr   r7
1128
1129 1:      dcbf    0,r4            /* ...and flush. */
1130         add     r4,r4,r5
1131         bdnz    1b
1132
1133         /* restore HID0 */
1134         mtspr   SPRN_HID0,r8
1135         isync
1136
1137         blr
1138
1139 /* Flush L1 d-cache, invalidate and disable d-cache and i-cache */
1140 _GLOBAL(__flush_disable_L1)
1141         mflr    r10
1142         bl      flush_dcache_L1 /* Flush L1 d-cache */
1143         mtlr    r10
1144
1145         mfspr   r4, SPRN_L1CSR0 /* Invalidate and disable d-cache */
1146         li      r5, 2
1147         rlwimi  r4, r5, 0, 3
1148
1149         msync
1150         isync
1151         mtspr   SPRN_L1CSR0, r4
1152         isync
1153
1154 1:      mfspr   r4, SPRN_L1CSR0 /* Wait for the invalidate to finish */
1155         andi.   r4, r4, 2
1156         bne     1b
1157
1158         mfspr   r4, SPRN_L1CSR1 /* Invalidate and disable i-cache */
1159         li      r5, 2
1160         rlwimi  r4, r5, 0, 3
1161
1162         mtspr   SPRN_L1CSR1, r4
1163         isync
1164
1165         blr
1166
1167 #ifdef CONFIG_SMP
1168 /* When we get here, r24 needs to hold the CPU # */
1169         .globl __secondary_start
1170 __secondary_start:
1171         LOAD_REG_ADDR_PIC(r3, tlbcam_index)
1172         lwz     r3,0(r3)
1173         mtctr   r3
1174         li      r26,0           /* r26 safe? */
1175
1176         bl      switch_to_as1
1177         mr      r27,r3          /* tlb entry */
1178         /* Load each CAM entry */
1179 1:      mr      r3,r26
1180         bl      loadcam_entry
1181         addi    r26,r26,1
1182         bdnz    1b
1183         mr      r3,r27          /* tlb entry */
1184         LOAD_REG_ADDR_PIC(r4, memstart_addr)
1185         lwz     r4,0(r4)
1186         mr      r5,r25          /* phys kernel start */
1187         rlwinm  r5,r5,0,~0x3ffffff      /* aligned 64M */
1188         subf    r4,r5,r4        /* memstart_addr - phys kernel start */
1189         li      r5,0            /* no device tree */
1190         li      r6,0            /* not boot cpu */
1191         bl      restore_to_as0
1192
1193
1194         lis     r3,__secondary_hold_acknowledge@h
1195         ori     r3,r3,__secondary_hold_acknowledge@l
1196         stw     r24,0(r3)
1197
1198         li      r3,0
1199         mr      r4,r24          /* Why? */
1200         bl      call_setup_cpu
1201
1202         /* get current_thread_info and current */
1203         lis     r1,secondary_ti@ha
1204         lwz     r1,secondary_ti@l(r1)
1205         lwz     r2,TI_TASK(r1)
1206
1207         /* stack */
1208         addi    r1,r1,THREAD_SIZE-STACK_FRAME_OVERHEAD
1209         li      r0,0
1210         stw     r0,0(r1)
1211
1212         /* ptr to current thread */
1213         addi    r4,r2,THREAD    /* address of our thread_struct */
1214         mtspr   SPRN_SPRG_THREAD,r4
1215
1216         /* Setup the defaults for TLB entries */
1217         li      r4,(MAS4_TSIZED(BOOK3E_PAGESZ_4K))@l
1218         mtspr   SPRN_MAS4,r4
1219
1220         /* Jump to start_secondary */
1221         lis     r4,MSR_KERNEL@h
1222         ori     r4,r4,MSR_KERNEL@l
1223         lis     r3,start_secondary@h
1224         ori     r3,r3,start_secondary@l
1225         mtspr   SPRN_SRR0,r3
1226         mtspr   SPRN_SRR1,r4
1227         sync
1228         rfi
1229         sync
1230
1231         .globl __secondary_hold_acknowledge
1232 __secondary_hold_acknowledge:
1233         .long   -1
1234 #endif
1235
1236 /*
1237  * Create a tlb entry with the same effective and physical address as
1238  * the tlb entry used by the current running code. But set the TS to 1.
1239  * Then switch to the address space 1. It will return with the r3 set to
1240  * the ESEL of the new created tlb.
1241  */
1242 _GLOBAL(switch_to_as1)
1243         mflr    r5
1244
1245         /* Find a entry not used */
1246         mfspr   r3,SPRN_TLB1CFG
1247         andi.   r3,r3,0xfff
1248         mfspr   r4,SPRN_PID
1249         rlwinm  r4,r4,16,0x3fff0000     /* turn PID into MAS6[SPID] */
1250         mtspr   SPRN_MAS6,r4
1251 1:      lis     r4,0x1000               /* Set MAS0(TLBSEL) = 1 */
1252         addi    r3,r3,-1
1253         rlwimi  r4,r3,16,4,15           /* Setup MAS0 = TLBSEL | ESEL(r3) */
1254         mtspr   SPRN_MAS0,r4
1255         tlbre
1256         mfspr   r4,SPRN_MAS1
1257         andis.  r4,r4,MAS1_VALID@h
1258         bne     1b
1259
1260         /* Get the tlb entry used by the current running code */
1261         bl      0f
1262 0:      mflr    r4
1263         tlbsx   0,r4
1264
1265         mfspr   r4,SPRN_MAS1
1266         ori     r4,r4,MAS1_TS           /* Set the TS = 1 */
1267         mtspr   SPRN_MAS1,r4
1268
1269         mfspr   r4,SPRN_MAS0
1270         rlwinm  r4,r4,0,~MAS0_ESEL_MASK
1271         rlwimi  r4,r3,16,4,15           /* Setup MAS0 = TLBSEL | ESEL(r3) */
1272         mtspr   SPRN_MAS0,r4
1273         tlbwe
1274         isync
1275         sync
1276
1277         mfmsr   r4
1278         ori     r4,r4,MSR_IS | MSR_DS
1279         mtspr   SPRN_SRR0,r5
1280         mtspr   SPRN_SRR1,r4
1281         sync
1282         rfi
1283
1284 /*
1285  * Restore to the address space 0 and also invalidate the tlb entry created
1286  * by switch_to_as1.
1287  * r3 - the tlb entry which should be invalidated
1288  * r4 - __pa(PAGE_OFFSET in AS1) - __pa(PAGE_OFFSET in AS0)
1289  * r5 - device tree virtual address. If r4 is 0, r5 is ignored.
1290  * r6 - boot cpu
1291 */
1292 _GLOBAL(restore_to_as0)
1293         mflr    r0
1294
1295         bl      0f
1296 0:      mflr    r9
1297         addi    r9,r9,1f - 0b
1298
1299         /*
1300          * We may map the PAGE_OFFSET in AS0 to a different physical address,
1301          * so we need calculate the right jump and device tree address based
1302          * on the offset passed by r4.
1303          */
1304         add     r9,r9,r4
1305         add     r5,r5,r4
1306         add     r0,r0,r4
1307
1308 2:      mfmsr   r7
1309         li      r8,(MSR_IS | MSR_DS)
1310         andc    r7,r7,r8
1311
1312         mtspr   SPRN_SRR0,r9
1313         mtspr   SPRN_SRR1,r7
1314         sync
1315         rfi
1316
1317         /* Invalidate the temporary tlb entry for AS1 */
1318 1:      lis     r9,0x1000               /* Set MAS0(TLBSEL) = 1 */
1319         rlwimi  r9,r3,16,4,15           /* Setup MAS0 = TLBSEL | ESEL(r3) */
1320         mtspr   SPRN_MAS0,r9
1321         tlbre
1322         mfspr   r9,SPRN_MAS1
1323         rlwinm  r9,r9,0,2,31            /* Clear MAS1 Valid and IPPROT */
1324         mtspr   SPRN_MAS1,r9
1325         tlbwe
1326         isync
1327
1328         cmpwi   r4,0
1329         cmpwi   cr1,r6,0
1330         cror    eq,4*cr1+eq,eq
1331         bne     3f                      /* offset != 0 && is_boot_cpu */
1332         mtlr    r0
1333         blr
1334
1335         /*
1336          * The PAGE_OFFSET will map to a different physical address,
1337          * jump to _start to do another relocation again.
1338         */
1339 3:      mr      r3,r5
1340         bl      _start
1341
1342 /*
1343  * We put a few things here that have to be page-aligned. This stuff
1344  * goes at the beginning of the data segment, which is page-aligned.
1345  */
1346         .data
1347         .align  12
1348         .globl  sdata
1349 sdata:
1350         .globl  empty_zero_page
1351 empty_zero_page:
1352         .space  4096
1353         .globl  swapper_pg_dir
1354 swapper_pg_dir:
1355         .space  PGD_TABLE_SIZE
1356
1357 /*
1358  * Room for two PTE pointers, usually the kernel and current user pointers
1359  * to their respective root page table.
1360  */
1361 abatron_pteptrs:
1362         .space  8