arch/powerpc/kernel/tm.S

   1 /*
   2  * Transactional memory support routines to reclaim and recheckpoint
   3  * transactional process state.
   4  *
   5  * Copyright 2012 Matt Evans & Michael Neuling, IBM Corporation.
   6  */
   7
   8 #include <asm/asm-offsets.h>
   9 #include <asm/ppc_asm.h>
  10 #include <asm/ppc-opcode.h>
  11 #include <asm/ptrace.h>
  12 #include <asm/reg.h>
  13 #include <asm/bug.h>
  14
  15 #ifdef CONFIG_VSX
  16 /* See fpu.S, this is borrowed from there */
  17 #define __SAVE_32FPRS_VSRS(n,c,base)            \
  18 BEGIN_FTR_SECTION                               \
  19         b       2f;                             \
  20 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  21         SAVE_32FPRS(n,base);                    \
  22         b       3f;                             \
  23 2:      SAVE_32VSRS(n,c,base);                  \
  24 3:
  25 #define __REST_32FPRS_VSRS(n,c,base)            \
  26 BEGIN_FTR_SECTION                               \
  27         b       2f;                             \
  28 END_FTR_SECTION_IFSET(CPU_FTR_VSX);             \
  29         REST_32FPRS(n,base);                    \
  30         b       3f;                             \
  31 2:      REST_32VSRS(n,c,base);                  \
  32 3:
  33 #else
  34 #define __SAVE_32FPRS_VSRS(n,c,base)    SAVE_32FPRS(n, base)
  35 #define __REST_32FPRS_VSRS(n,c,base)    REST_32FPRS(n, base)
  36 #endif
  37 #define SAVE_32FPRS_VSRS(n,c,base) \
  38         __SAVE_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  39 #define REST_32FPRS_VSRS(n,c,base) \
  40         __REST_32FPRS_VSRS(n,__REG_##c,__REG_##base)
  41
  42 /* Stack frame offsets for local variables. */
  43 #define TM_FRAME_L0     TM_FRAME_SIZE-16
  44 #define TM_FRAME_L1     TM_FRAME_SIZE-8
  45
  46
  47 /* In order to access the TM SPRs, TM must be enabled.  So, do so: */
  48 _GLOBAL(tm_enable)
  49         mfmsr   r4
  50         li      r3, MSR_TM >> 32
  51         sldi    r3, r3, 32
  52         and.    r0, r4, r3
  53         bne     1f
  54         or      r4, r4, r3
  55         mtmsrd  r4
  56 1:      blr
  57
  58 _GLOBAL(tm_save_sprs)
  59         mfspr   r0, SPRN_TFHAR
  60         std     r0, THREAD_TM_TFHAR(r3)
  61         mfspr   r0, SPRN_TEXASR
  62         std     r0, THREAD_TM_TEXASR(r3)
  63         mfspr   r0, SPRN_TFIAR
  64         std     r0, THREAD_TM_TFIAR(r3)
  65         blr
  66
  67 _GLOBAL(tm_restore_sprs)
  68         ld      r0, THREAD_TM_TFHAR(r3)
  69         mtspr   SPRN_TFHAR, r0
  70         ld      r0, THREAD_TM_TEXASR(r3)
  71         mtspr   SPRN_TEXASR, r0
  72         ld      r0, THREAD_TM_TFIAR(r3)
  73         mtspr   SPRN_TFIAR, r0
  74         blr
  75
  76         /* Passed an 8-bit failure cause as first argument. */
  77 _GLOBAL(tm_abort)
  78         TABORT(R3)
  79         blr
  80
  81 /* void tm_reclaim(struct thread_struct *thread,
  82  *                 unsigned long orig_msr,
  83  *                 uint8_t cause)
  84  *
  85  *      - Performs a full reclaim.  This destroys outstanding
  86  *        transactions and updates thread->regs.tm_ckpt_* with the
  87  *        original checkpointed state.  Note that thread->regs is
  88  *        unchanged.
  89  *      - FP regs are written back to thread->transact_fpr before
  90  *        reclaiming.  These are the transactional (current) versions.
  91  *
  92  * Purpose is to both abort transactions of, and preserve the state of,
  93  * a transactions at a context switch. We preserve/restore both sets of process
  94  * state to restore them when the thread's scheduled again.  We continue in
  95  * userland as though nothing happened, but when the transaction is resumed
  96  * they will abort back to the checkpointed state we save out here.
  97  *
  98  * Call with IRQs off, stacks get all out of sync for some periods in here!
  99  */
 100 _GLOBAL(tm_reclaim)
 101         mfcr    r6
 102         mflr    r0
 103         stw     r6, 8(r1)
 104         std     r0, 16(r1)
 105         std     r2, STK_GOT(r1)
 106         stdu    r1, -TM_FRAME_SIZE(r1)
 107
 108         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD]. */
 109
 110         std     r3, STK_PARAM(R3)(r1)
 111         SAVE_NVGPRS(r1)
 112
 113         /* We need to setup MSR for VSX register save instructions. */
 114         mfmsr   r14
 115         mr      r15, r14
 116         ori     r15, r15, MSR_FP
 117         li      r16, 0
 118         ori     r16, r16, MSR_EE /* IRQs hard off */
 119         andc    r15, r15, r16
 120         oris    r15, r15, MSR_VEC@h
 121 #ifdef CONFIG_VSX
 122         BEGIN_FTR_SECTION
 123         oris    r15,r15, MSR_VSX@h
 124         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 125 #endif
 126         mtmsrd  r15
 127         std     r14, TM_FRAME_L0(r1)
 128
 129         /* Stash the stack pointer away for use after reclaim */
 130         std     r1, PACAR1(r13)
 131
 132         /* ******************** FPR/VR/VSRs ************
 133          * Before reclaiming, capture the current/transactional FPR/VR
 134         * versions /if used/.
 135          *
 136          * (If VSX used, FP and VMX are implied.  Or, we don't need to look
 137          * at MSR.VSX as copying FP regs if .FP, vector regs if .VMX covers it.)
 138          *
 139          * We're passed the thread's MSR as parameter 2.
 140          *
 141          * We enabled VEC/FP/VSX in the msr above, so we can execute these
 142          * instructions!
 143          */
 144         andis.          r0, r4, MSR_VEC@h
 145         beq     dont_backup_vec
 146
 147         addi    r7, r3, THREAD_TRANSACT_VRSTATE
 148         SAVE_32VRS(0, r6, r7)   /* r6 scratch, r7 transact vr state */
 149         mfvscr  v0
 150         li      r6, VRSTATE_VSCR
 151         stvx    v0, r7, r6
 152 dont_backup_vec:
 153         mfspr   r0, SPRN_VRSAVE
 154         std     r0, THREAD_TRANSACT_VRSAVE(r3)
 155
 156         andi.   r0, r4, MSR_FP
 157         beq     dont_backup_fp
 158
 159         addi    r7, r3, THREAD_TRANSACT_FPSTATE
 160         SAVE_32FPRS_VSRS(0, R6, R7)     /* r6 scratch, r7 transact fp state */
 161
 162         mffs    fr0
 163         stfd    fr0,FPSTATE_FPSCR(r7)
 164
 165 dont_backup_fp:
 166         /* Do sanity check on MSR to make sure we are suspended */
 167         li      r7, (MSR_TS_S)@higher
 168         srdi    r6, r14, 32
 169         and     r6, r6, r7
 170 1:      tdeqi   r6, 0
 171         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 172
 173         /* Clear MSR RI since we are about to change r1, EE is already off. */
 174         li      r4, 0
 175         mtmsrd  r4, 1
 176
 177         /*
 178          * BE CAREFUL HERE:
 179          * At this point we can't take an SLB miss since we have MSR_RI
 180          * off. Load only to/from the stack/paca which are in SLB bolted regions
 181          * until we turn MSR RI back on.
 182          *
 183          * The moment we treclaim, ALL of our GPRs will switch
 184          * to user register state.  (FPRs, CCR etc. also!)
 185          * Use an sprg and a tm_scratch in the PACA to shuffle.
 186          */
 187         TRECLAIM(R5)                            /* Cause in r5 */
 188
 189         /* ******************** GPRs ******************** */
 190         /* Stash the checkpointed r13 away in the scratch SPR and get the real
 191          *  paca
 192          */
 193         SET_SCRATCH0(r13)
 194         GET_PACA(r13)
 195
 196         /* Stash the checkpointed r1 away in paca tm_scratch and get the real
 197          * stack pointer back
 198          */
 199         std     r1, PACATMSCRATCH(r13)
 200         ld      r1, PACAR1(r13)
 201
 202         std     r11, GPR11(r1)                  /* Temporary stash */
 203
 204         /*
 205          * Move the saved user r1 to the kernel stack in case PACATMSCRATCH is
 206          * clobbered by an exception once we turn on MSR_RI below.
 207          */
 208         ld      r11, PACATMSCRATCH(r13)
 209         std     r11, GPR1(r1)
 210
 211         /*
 212          * Store r13 away so we can free up the scratch SPR for the SLB fault
 213          * handler (needed once we start accessing the thread_struct).
 214          */
 215         GET_SCRATCH0(r11)
 216         std     r11, GPR13(r1)
 217
 218         /* Reset MSR RI so we can take SLB faults again */
 219         li      r11, MSR_RI
 220         mtmsrd  r11, 1
 221
 222         /* Store the PPR in r11 and reset to decent value */
 223         mfspr   r11, SPRN_PPR
 224         HMT_MEDIUM
 225
 226         /* Now get some more GPRS free */
 227         std     r7, GPR7(r1)                    /* Temporary stash */
 228         std     r12, GPR12(r1)                  /* ''   ''    ''   */
 229         ld      r12, STK_PARAM(R3)(r1)          /* Param 0, thread_struct * */
 230
 231         std     r11, THREAD_TM_PPR(r12)         /* Store PPR and free r11 */
 232
 233         addi    r7, r12, PT_CKPT_REGS           /* Thread's ckpt_regs */
 234
 235         /* Make r7 look like an exception frame so that we
 236          * can use the neat GPRx(n) macros.  r7 is NOT a pt_regs ptr!
 237          */
 238         subi    r7, r7, STACK_FRAME_OVERHEAD
 239
 240         /* Sync the userland GPRs 2-12, 14-31 to thread->regs: */
 241         SAVE_GPR(0, r7)                         /* user r0 */
 242         SAVE_GPR(2, r7)                 /* user r2 */
 243         SAVE_4GPRS(3, r7)                       /* user r3-r6 */
 244         SAVE_GPR(8, r7)                         /* user r8 */
 245         SAVE_GPR(9, r7)                         /* user r9 */
 246         SAVE_GPR(10, r7)                        /* user r10 */
 247         ld      r3, GPR1(r1)                    /* user r1 */
 248         ld      r4, GPR7(r1)                    /* user r7 */
 249         ld      r5, GPR11(r1)                   /* user r11 */
 250         ld      r6, GPR12(r1)                   /* user r12 */
 251         ld      r8, GPR13(r1)                   /* user r13 */
 252         std     r3, GPR1(r7)
 253         std     r4, GPR7(r7)
 254         std     r5, GPR11(r7)
 255         std     r6, GPR12(r7)
 256         std     r8, GPR13(r7)
 257
 258         SAVE_NVGPRS(r7)                         /* user r14-r31 */
 259
 260         /* ******************** NIP ******************** */
 261         mfspr   r3, SPRN_TFHAR
 262         std     r3, _NIP(r7)                    /* Returns to failhandler */
 263         /* The checkpointed NIP is ignored when rescheduling/rechkpting,
 264          * but is used in signal return to 'wind back' to the abort handler.
 265          */
 266
 267         /* ******************** CR,LR,CCR,MSR ********** */
 268         mfctr   r3
 269         mflr    r4
 270         mfcr    r5
 271         mfxer   r6
 272
 273         std     r3, _CTR(r7)
 274         std     r4, _LINK(r7)
 275         std     r5, _CCR(r7)
 276         std     r6, _XER(r7)
 277
 278
 279         /* ******************** TAR, DSCR ********** */
 280         mfspr   r3, SPRN_TAR
 281         mfspr   r4, SPRN_DSCR
 282
 283         std     r3, THREAD_TM_TAR(r12)
 284         std     r4, THREAD_TM_DSCR(r12)
 285
 286         /* MSR and flags:  We don't change CRs, and we don't need to alter
 287          * MSR.
 288          */
 289
 290         /* TM regs, incl TEXASR -- these live in thread_struct.  Note they've
 291          * been updated by the treclaim, to explain to userland the failure
 292          * cause (aborted).
 293          */
 294         mfspr   r0, SPRN_TEXASR
 295         mfspr   r3, SPRN_TFHAR
 296         mfspr   r4, SPRN_TFIAR
 297         std     r0, THREAD_TM_TEXASR(r12)
 298         std     r3, THREAD_TM_TFHAR(r12)
 299         std     r4, THREAD_TM_TFIAR(r12)
 300
 301         /* AMR is checkpointed too, but is unsupported by Linux. */
 302
 303         /* Restore original MSR/IRQ state & clear TM mode */
 304         ld      r14, TM_FRAME_L0(r1)            /* Orig MSR */
 305         li      r15, 0
 306         rldimi  r14, r15, MSR_TS_LG, (63-MSR_TS_LG)-1
 307         mtmsrd  r14
 308
 309         REST_NVGPRS(r1)
 310
 311         addi    r1, r1, TM_FRAME_SIZE
 312         lwz     r4, 8(r1)
 313         ld      r0, 16(r1)
 314         mtcr    r4
 315         mtlr    r0
 316         ld      r2, STK_GOT(r1)
 317
 318         /* Load CPU's default DSCR */
 319         ld      r0, PACA_DSCR_DEFAULT(r13)
 320         mtspr   SPRN_DSCR, r0
 321
 322         blr
 323
 324
 325         /* void tm_recheckpoint(struct thread_struct *thread,
 326          *                      unsigned long orig_msr)
 327          *      - Restore the checkpointed register state saved by tm_reclaim
 328          *        when we switch_to a process.
 329          *
 330          *      Call with IRQs off, stacks get all out of sync for
 331          *      some periods in here!
 332          */
 333 _GLOBAL(__tm_recheckpoint)
 334         mfcr    r5
 335         mflr    r0
 336         stw     r5, 8(r1)
 337         std     r0, 16(r1)
 338         std     r2, STK_GOT(r1)
 339         stdu    r1, -TM_FRAME_SIZE(r1)
 340
 341         /* We've a struct pt_regs at [r1+STACK_FRAME_OVERHEAD].
 342          * This is used for backing up the NVGPRs:
 343          */
 344         SAVE_NVGPRS(r1)
 345
 346         /* Load complete register state from ts_ckpt* registers */
 347
 348         addi    r7, r3, PT_CKPT_REGS            /* Thread's ckpt_regs */
 349
 350         /* Make r7 look like an exception frame so that we
 351          * can use the neat GPRx(n) macros.  r7 is now NOT a pt_regs ptr!
 352          */
 353         subi    r7, r7, STACK_FRAME_OVERHEAD
 354
 355         mfmsr   r6
 356         /* R4 = original MSR to indicate whether thread used FP/Vector etc. */
 357
 358         /* Enable FP/vec in MSR if necessary! */
 359         lis     r5, MSR_VEC@h
 360         ori     r5, r5, MSR_FP
 361         and.    r5, r4, r5
 362         beq     restore_gprs                    /* if neither, skip both */
 363
 364 #ifdef CONFIG_VSX
 365         BEGIN_FTR_SECTION
 366         oris    r5, r5, MSR_VSX@h
 367         END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 368 #endif
 369         or      r5, r6, r5                      /* Set MSR.FP+.VSX/.VEC */
 370         mtmsr   r5
 371
 372 #ifdef CONFIG_ALTIVEC
 373         /* FP and VEC registers:  These are recheckpointed from thread.fpr[]
 374          * and thread.vr[] respectively.  The thread.transact_fpr[] version
 375          * is more modern, and will be loaded subsequently by any FPUnavailable
 376          * trap.
 377          */
 378         andis.  r0, r4, MSR_VEC@h
 379         beq     dont_restore_vec
 380
 381         addi    r8, r3, THREAD_VRSTATE
 382         li      r5, VRSTATE_VSCR
 383         lvx     v0, r8, r5
 384         mtvscr  v0
 385         REST_32VRS(0, r5, r8)                   /* r5 scratch, r8 ptr */
 386 dont_restore_vec:
 387         ld      r5, THREAD_VRSAVE(r3)
 388         mtspr   SPRN_VRSAVE, r5
 389 #endif
 390
 391         andi.   r0, r4, MSR_FP
 392         beq     dont_restore_fp
 393
 394         addi    r8, r3, THREAD_FPSTATE
 395         lfd     fr0, FPSTATE_FPSCR(r8)
 396         MTFSF_L(fr0)
 397         REST_32FPRS_VSRS(0, R4, R8)
 398
 399 dont_restore_fp:
 400         mtmsr   r6                              /* FP/Vec off again! */
 401
 402 restore_gprs:
 403
 404         /* ******************** CR,LR,CCR,MSR ********** */
 405         ld      r4, _CTR(r7)
 406         ld      r5, _LINK(r7)
 407         ld      r8, _XER(r7)
 408
 409         mtctr   r4
 410         mtlr    r5
 411         mtxer   r8
 412
 413         /* ******************** TAR ******************** */
 414         ld      r4, THREAD_TM_TAR(r3)
 415         mtspr   SPRN_TAR,       r4
 416
 417         /* Load up the PPR and DSCR in GPRs only at this stage */
 418         ld      r5, THREAD_TM_DSCR(r3)
 419         ld      r6, THREAD_TM_PPR(r3)
 420
 421         REST_GPR(0, r7)                         /* GPR0 */
 422         REST_2GPRS(2, r7)                       /* GPR2-3 */
 423         REST_GPR(4, r7)                         /* GPR4 */
 424         REST_4GPRS(8, r7)                       /* GPR8-11 */
 425         REST_2GPRS(12, r7)                      /* GPR12-13 */
 426
 427         REST_NVGPRS(r7)                         /* GPR14-31 */
 428
 429         /* Load up PPR and DSCR here so we don't run with user values for long
 430          */
 431         mtspr   SPRN_DSCR, r5
 432         mtspr   SPRN_PPR, r6
 433
 434         /* Do final sanity check on TEXASR to make sure FS is set.  Do this
 435          * here before we load up the userspace r1 so any bugs we hit will get
 436          * a call chain */
 437         mfspr   r5, SPRN_TEXASR
 438         srdi    r5, r5, 16
 439         li      r6, (TEXASR_FS)@h
 440         and     r6, r6, r5
 441 1:      tdeqi   r6, 0
 442         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 443
 444         /* Do final sanity check on MSR to make sure we are not transactional
 445          * or suspended
 446          */
 447         mfmsr   r6
 448         li      r5, (MSR_TS_MASK)@higher
 449         srdi    r6, r6, 32
 450         and     r6, r6, r5
 451 1:      tdnei   r6, 0
 452         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,0
 453
 454         /* Restore CR */
 455         ld      r6, _CCR(r7)
 456         mtcr    r6
 457
 458         REST_GPR(6, r7)
 459
 460         /*
 461          * Store r1 and r5 on the stack so that we can access them
 462          * after we clear MSR RI.
 463          */
 464
 465         REST_GPR(5, r7)
 466         std     r5, -8(r1)
 467         ld      r5, GPR1(r7)
 468         std     r5, -16(r1)
 469
 470         REST_GPR(7, r7)
 471
 472         /* Clear MSR RI since we are about to change r1. EE is already off */
 473         li      r5, 0
 474         mtmsrd  r5, 1
 475
 476         /*
 477          * BE CAREFUL HERE:
 478          * At this point we can't take an SLB miss since we have MSR_RI
 479          * off. Load only to/from the stack/paca which are in SLB bolted regions
 480          * until we turn MSR RI back on.
 481          */
 482
 483         SET_SCRATCH0(r1)
 484         ld      r5, -8(r1)
 485         ld      r1, -16(r1)
 486
 487         /* Commit register state as checkpointed state: */
 488         TRECHKPT
 489
 490         HMT_MEDIUM
 491
 492         /* Our transactional state has now changed.
 493          *
 494          * Now just get out of here.  Transactional (current) state will be
 495          * updated once restore is called on the return path in the _switch-ed
 496          * -to process.
 497          */
 498
 499         GET_PACA(r13)
 500         GET_SCRATCH0(r1)
 501
 502         /* R1 is restored, so we are recoverable again.  EE is still off */
 503         li      r4, MSR_RI
 504         mtmsrd  r4, 1
 505
 506         REST_NVGPRS(r1)
 507
 508         addi    r1, r1, TM_FRAME_SIZE
 509         lwz     r4, 8(r1)
 510         ld      r0, 16(r1)
 511         mtcr    r4
 512         mtlr    r0
 513         ld      r2, STK_GOT(r1)
 514
 515         /* Load CPU's default DSCR */
 516         ld      r0, PACA_DSCR_DEFAULT(r13)
 517         mtspr   SPRN_DSCR, r0
 518
 519         blr
 520
 521         /* ****************************************************************** */