arch/powerpc/kernel/vmlinux.lds.S

   1 /* SPDX-License-Identifier: GPL-2.0 */
   2 #ifdef CONFIG_PPC64
   3 #define PROVIDE32(x)    PROVIDE(__unused__##x)
   4 #else
   5 #define PROVIDE32(x)    PROVIDE(x)
   6 #endif
   7 #include <asm/page.h>
   8 #include <asm-generic/vmlinux.lds.h>
   9 #include <asm/cache.h>
  10 #include <asm/thread_info.h>
  11
  12 #if defined(CONFIG_STRICT_KERNEL_RWX) && !defined(CONFIG_PPC32)
  13 #define STRICT_ALIGN_SIZE       (1 << 24)
  14 #else
  15 #define STRICT_ALIGN_SIZE       PAGE_SIZE
  16 #endif
  17
  18 ENTRY(_stext)
  19
  20 PHDRS {
  21         kernel PT_LOAD FLAGS(7); /* RWX */
  22         notes PT_NOTE FLAGS(0);
  23         dummy PT_NOTE FLAGS(0);
  24
  25         /* binutils < 2.18 has a bug that makes it misbehave when taking an
  26            ELF file with all segments at load address 0 as input.  This
  27            happens when running "strip" on vmlinux, because of the AT() magic
  28            in this linker script.  People using GCC >= 4.2 won't run into
  29            this problem, because the "build-id" support will put some data
  30            into the "notes" segment (at a non-zero load address).
  31
  32            To work around this, we force some data into both the "dummy"
  33            segment and the kernel segment, so the dummy segment will get a
  34            non-zero load address.  It's not enough to always create the
  35            "notes" segment, since if nothing gets assigned to it, its load
  36            address will be zero.  */
  37 }
  38
  39 #ifdef CONFIG_PPC64
  40 OUTPUT_ARCH(powerpc:common64)
  41 jiffies = jiffies_64;
  42 #else
  43 OUTPUT_ARCH(powerpc:common)
  44 jiffies = jiffies_64 + 4;
  45 #endif
  46 SECTIONS
  47 {
  48         . = KERNELBASE;
  49
  50 /*
  51  * Text, read only data and other permanent read-only sections
  52  */
  53
  54         _text = .;
  55         _stext = .;
  56
  57         /*
  58          * Head text.
  59          * This needs to be in its own output section to avoid ld placing
  60          * branch trampoline stubs randomly throughout the fixed sections,
  61          * which it will do (even if the branch comes from another section)
  62          * in order to optimize stub generation.
  63          */
  64         .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
  65 #ifdef CONFIG_PPC64
  66                 KEEP(*(.head.text.first_256B));
  67 #ifdef CONFIG_PPC_BOOK3E
  68 #else
  69                 KEEP(*(.head.text.real_vectors));
  70                 *(.head.text.real_trampolines);
  71                 KEEP(*(.head.text.virt_vectors));
  72                 *(.head.text.virt_trampolines);
  73 # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  74                 KEEP(*(.head.data.fwnmi_page));
  75 # endif
  76 #endif
  77 #else /* !CONFIG_PPC64 */
  78                 HEAD_TEXT
  79 #endif
  80         } :kernel
  81
  82         __head_end = .;
  83
  84 #ifdef CONFIG_PPC64
  85         /*
  86          * BLOCK(0) overrides the default output section alignment because
  87          * this needs to start right after .head.text in order for fixed
  88          * section placement to work.
  89          */
  90         .text BLOCK(0) : AT(ADDR(.text) - LOAD_OFFSET) {
  91 #ifdef CONFIG_LD_HEAD_STUB_CATCH
  92                 *(.linker_stub_catch);
  93                 . = . ;
  94 #endif
  95
  96 #else
  97         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  98                 ALIGN_FUNCTION();
  99 #endif
 100                 /* careful! __ftr_alt_* sections need to be close to .text */
 101                 *(.text.hot .text .text.fixup .text.unlikely .fixup __ftr_alt_* .ref.text);
 102                 SCHED_TEXT
 103                 CPUIDLE_TEXT
 104                 LOCK_TEXT
 105                 KPROBES_TEXT
 106                 IRQENTRY_TEXT
 107                 SOFTIRQENTRY_TEXT
 108                 /*
 109                  * -Os builds call FP save/restore functions. The powerpc64
 110                  * linker generates those on demand in the .sfpr section.
 111                  * .sfpr gets placed at the beginning of a group of input
 112                  * sections, which can break start-of-text offset if it is
 113                  * included with the main text sections, so put it by itself.
 114                  */
 115                 *(.sfpr);
 116                 MEM_KEEP(init.text)
 117                 MEM_KEEP(exit.text)
 118
 119 #ifdef CONFIG_PPC32
 120                 *(.got1)
 121                 __got2_start = .;
 122                 *(.got2)
 123                 __got2_end = .;
 124 #endif /* CONFIG_PPC32 */
 125
 126         } :kernel
 127
 128         . = ALIGN(PAGE_SIZE);
 129         _etext = .;
 130         PROVIDE32 (etext = .);
 131
 132         /* Read-only data */
 133         RO_DATA(PAGE_SIZE)
 134
 135 #ifdef CONFIG_PPC64
 136         . = ALIGN(8);
 137         __stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
 138                 __start___stf_entry_barrier_fixup = .;
 139                 *(__stf_entry_barrier_fixup)
 140                 __stop___stf_entry_barrier_fixup = .;
 141         }
 142
 143         . = ALIGN(8);
 144         __uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) {
 145                 __start___uaccess_flush_fixup = .;
 146                 *(__uaccess_flush_fixup)
 147                 __stop___uaccess_flush_fixup = .;
 148         }
 149
 150         . = ALIGN(8);
 151         __entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
 152                 __start___entry_flush_fixup = .;
 153                 *(__entry_flush_fixup)
 154                 __stop___entry_flush_fixup = .;
 155         }
 156
 157         . = ALIGN(8);
 158         __stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
 159                 __start___stf_exit_barrier_fixup = .;
 160                 *(__stf_exit_barrier_fixup)
 161                 __stop___stf_exit_barrier_fixup = .;
 162         }
 163
 164         . = ALIGN(8);
 165         __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
 166                 __start___rfi_flush_fixup = .;
 167                 *(__rfi_flush_fixup)
 168                 __stop___rfi_flush_fixup = .;
 169         }
 170 #endif /* CONFIG_PPC64 */
 171
 172 #ifdef CONFIG_PPC_BARRIER_NOSPEC
 173         . = ALIGN(8);
 174         __spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
 175                 __start___barrier_nospec_fixup = .;
 176                 *(__barrier_nospec_fixup)
 177                 __stop___barrier_nospec_fixup = .;
 178         }
 179 #endif /* CONFIG_PPC_BARRIER_NOSPEC */
 180
 181 #ifdef CONFIG_PPC_FSL_BOOK3E
 182         . = ALIGN(8);
 183         __spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
 184                 __start__btb_flush_fixup = .;
 185                 *(__btb_flush_fixup)
 186                 __stop__btb_flush_fixup = .;
 187         }
 188 #endif
 189         EXCEPTION_TABLE(0)
 190
 191         NOTES :kernel :notes
 192
 193         /* The dummy segment contents for the bug workaround mentioned above
 194            near PHDRS.  */
 195         .dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
 196                 LONG(0)
 197                 LONG(0)
 198                 LONG(0)
 199         } :kernel :dummy
 200
 201 /*
 202  * Init sections discarded at runtime
 203  */
 204         . = ALIGN(STRICT_ALIGN_SIZE);
 205         __init_begin = .;
 206         INIT_TEXT_SECTION(PAGE_SIZE) :kernel
 207
 208         /* .exit.text is discarded at runtime, not link time,
 209          * to deal with references from __bug_table
 210          */
 211         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 212                 EXIT_TEXT
 213         }
 214
 215         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 216                 INIT_DATA
 217                 __vtop_table_begin = .;
 218                 *(.vtop_fixup);
 219                 __vtop_table_end = .;
 220                 __ptov_table_begin = .;
 221                 *(.ptov_fixup);
 222                 __ptov_table_end = .;
 223         }
 224
 225         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 226                 INIT_SETUP(16)
 227         }
 228
 229         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 230                 INIT_CALLS
 231         }
 232
 233         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 234                 CON_INITCALL
 235         }
 236
 237         SECURITY_INIT
 238
 239         . = ALIGN(8);
 240         __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
 241                 __start___ftr_fixup = .;
 242                 *(__ftr_fixup)
 243                 __stop___ftr_fixup = .;
 244         }
 245         . = ALIGN(8);
 246         __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
 247                 __start___mmu_ftr_fixup = .;
 248                 *(__mmu_ftr_fixup)
 249                 __stop___mmu_ftr_fixup = .;
 250         }
 251         . = ALIGN(8);
 252         __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
 253                 __start___lwsync_fixup = .;
 254                 *(__lwsync_fixup)
 255                 __stop___lwsync_fixup = .;
 256         }
 257 #ifdef CONFIG_PPC64
 258         . = ALIGN(8);
 259         __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
 260                 __start___fw_ftr_fixup = .;
 261                 *(__fw_ftr_fixup)
 262                 __stop___fw_ftr_fixup = .;
 263         }
 264 #endif
 265         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 266                 INIT_RAM_FS
 267         }
 268
 269         PERCPU_SECTION(L1_CACHE_BYTES)
 270
 271         . = ALIGN(8);
 272         .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
 273                 __machine_desc_start = . ;
 274                 *(.machine.desc)
 275                 __machine_desc_end = . ;
 276         }
 277 #ifdef CONFIG_RELOCATABLE
 278         . = ALIGN(8);
 279         .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
 280         {
 281 #ifdef CONFIG_PPC32
 282                 __dynamic_symtab = .;
 283 #endif
 284                 *(.dynsym)
 285         }
 286         .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
 287         .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
 288         {
 289                 __dynamic_start = .;
 290                 *(.dynamic)
 291         }
 292         .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
 293         .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
 294         .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
 295         {
 296                 __rela_dyn_start = .;
 297                 *(.rela*)
 298         }
 299 #endif
 300         /* .exit.data is discarded at runtime, not link time,
 301          * to deal with references from .exit.text
 302          */
 303         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 304                 EXIT_DATA
 305         }
 306
 307         /* freed after init ends here */
 308         . = ALIGN(PAGE_SIZE);
 309         __init_end = .;
 310
 311 /*
 312  * And now the various read/write data
 313  */
 314
 315         . = ALIGN(PAGE_SIZE);
 316         _sdata = .;
 317
 318 #ifdef CONFIG_PPC32
 319         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 320                 DATA_DATA
 321                 *(.sdata)
 322                 *(.sdata2)
 323                 *(.got.plt) *(.got)
 324                 *(.plt)
 325         }
 326 #else
 327         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 328                 DATA_DATA
 329                 *(.data.rel*)
 330                 *(.toc1)
 331                 *(.branch_lt)
 332         }
 333
 334 #ifdef CONFIG_DEBUG_INFO_BTF
 335         .BTF : AT(ADDR(.BTF) - LOAD_OFFSET) {
 336                 *(.BTF)
 337         }
 338 #endif
 339
 340         .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
 341                 *(.opd)
 342         }
 343
 344         . = ALIGN(256);
 345         .got : AT(ADDR(.got) - LOAD_OFFSET) {
 346                 __toc_start = .;
 347 #ifndef CONFIG_RELOCATABLE
 348                 __prom_init_toc_start = .;
 349                 arch/powerpc/kernel/prom_init.o*(.toc .got)
 350                 __prom_init_toc_end = .;
 351 #endif
 352                 *(.got)
 353                 *(.toc)
 354         }
 355 #endif
 356
 357         /* The initial task and kernel stack */
 358         INIT_TASK_DATA_SECTION(THREAD_SIZE)
 359
 360         .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
 361                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 362         }
 363
 364         .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
 365                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 366         }
 367
 368         .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
 369                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 370         }
 371
 372         . = ALIGN(PAGE_SIZE);
 373         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 374                 NOSAVE_DATA
 375         }
 376
 377         BUG_TABLE
 378
 379         . = ALIGN(PAGE_SIZE);
 380         _edata  =  .;
 381         PROVIDE32 (edata = .);
 382
 383 /*
 384  * And finally the bss
 385  */
 386
 387         BSS_SECTION(0, 0, 0)
 388
 389         . = ALIGN(PAGE_SIZE);
 390         _end = . ;
 391         PROVIDE32 (end = .);
 392
 393         STABS_DEBUG
 394
 395         DWARF_DEBUG
 396
 397         DISCARDS
 398         /DISCARD/ : {
 399                 *(*.EMB.apuinfo)
 400                 *(.glink .iplt .plt .rela* .comment)
 401                 *(.gnu.version*)
 402                 *(.gnu.attributes)
 403                 *(.eh_frame)
 404         }
 405 }