arch/s390/kernel/entry.S

   1 /*
   2  *    S390 low-level entry points.
   3  *
   4  *    Copyright IBM Corp. 1999, 2012
   5  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   6  *               Hartmut Penner (hp@de.ibm.com),
   7  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   8  *               Heiko Carstens <heiko.carstens@de.ibm.com>
   9  */
  10
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/processor.h>
  14 #include <asm/cache.h>
  15 #include <asm/errno.h>
  16 #include <asm/ptrace.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/unistd.h>
  20 #include <asm/page.h>
  21 #include <asm/sigp.h>
  22 #include <asm/irq.h>
  23 #include <asm/vx-insn.h>
  24 #include <asm/setup.h>
  25 #include <asm/nmi.h>
  26 #include <asm/nospec-insn.h>
  27
  28 __PT_R0      =  __PT_GPRS
  29 __PT_R1      =  __PT_GPRS + 8
  30 __PT_R2      =  __PT_GPRS + 16
  31 __PT_R3      =  __PT_GPRS + 24
  32 __PT_R4      =  __PT_GPRS + 32
  33 __PT_R5      =  __PT_GPRS + 40
  34 __PT_R6      =  __PT_GPRS + 48
  35 __PT_R7      =  __PT_GPRS + 56
  36 __PT_R8      =  __PT_GPRS + 64
  37 __PT_R9      =  __PT_GPRS + 72
  38 __PT_R10     =  __PT_GPRS + 80
  39 __PT_R11     =  __PT_GPRS + 88
  40 __PT_R12     =  __PT_GPRS + 96
  41 __PT_R13     =  __PT_GPRS + 104
  42 __PT_R14     =  __PT_GPRS + 112
  43 __PT_R15     =  __PT_GPRS + 120
  44
  45 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  46 STACK_SIZE  = 1 << STACK_SHIFT
  47 STACK_INIT = STACK_SIZE - STACK_FRAME_OVERHEAD - __PT_SIZE
  48
  49 _TIF_WORK       = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  50                    _TIF_UPROBE)
  51 _TIF_TRACE      = (_TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT | _TIF_SECCOMP | \
  52                    _TIF_SYSCALL_TRACEPOINT)
  53 _CIF_WORK       = (_CIF_MCCK_PENDING | _CIF_ASCE | _CIF_FPU)
  54 _PIF_WORK       = (_PIF_PER_TRAP)
  55
  56 #define BASED(name) name-cleanup_critical(%r13)
  57
  58         .macro  TRACE_IRQS_ON
  59 #ifdef CONFIG_TRACE_IRQFLAGS
  60         basr    %r2,%r0
  61         brasl   %r14,trace_hardirqs_on_caller
  62 #endif
  63         .endm
  64
  65         .macro  TRACE_IRQS_OFF
  66 #ifdef CONFIG_TRACE_IRQFLAGS
  67         basr    %r2,%r0
  68         brasl   %r14,trace_hardirqs_off_caller
  69 #endif
  70         .endm
  71
  72         .macro  LOCKDEP_SYS_EXIT
  73 #ifdef CONFIG_LOCKDEP
  74         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
  75         jz      .+10
  76         brasl   %r14,lockdep_sys_exit
  77 #endif
  78         .endm
  79
  80         .macro  CHECK_STACK stacksize,savearea
  81 #ifdef CONFIG_CHECK_STACK
  82         tml     %r15,\stacksize - CONFIG_STACK_GUARD
  83         lghi    %r14,\savearea
  84         jz      stack_overflow
  85 #endif
  86         .endm
  87
  88         .macro  SWITCH_ASYNC savearea,timer
  89         tmhh    %r8,0x0001              # interrupting from user ?
  90         jnz     1f
  91         lgr     %r14,%r9
  92         slg     %r14,BASED(.Lcritical_start)
  93         clg     %r14,BASED(.Lcritical_length)
  94         jhe     0f
  95         lghi    %r11,\savearea          # inside critical section, do cleanup
  96         brasl   %r14,cleanup_critical
  97         tmhh    %r8,0x0001              # retest problem state after cleanup
  98         jnz     1f
  99 0:      lg      %r14,__LC_ASYNC_STACK   # are we already on the async stack?
 100         slgr    %r14,%r15
 101         srag    %r14,%r14,STACK_SHIFT
 102         jnz     2f
 103         CHECK_STACK 1<<STACK_SHIFT,\savearea
 104         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 105         j       3f
 106 1:      LAST_BREAK %r14
 107         UPDATE_VTIME %r14,%r15,\timer
 108         BPENTER __TI_flags(%r12),_TIF_ISOLATE_BP
 109 2:      lg      %r15,__LC_ASYNC_STACK   # load async stack
 110 3:      la      %r11,STACK_FRAME_OVERHEAD(%r15)
 111         .endm
 112
 113         .macro UPDATE_VTIME w1,w2,enter_timer
 114         lg      \w1,__LC_EXIT_TIMER
 115         lg      \w2,__LC_LAST_UPDATE_TIMER
 116         slg     \w1,\enter_timer
 117         slg     \w2,__LC_EXIT_TIMER
 118         alg     \w1,__LC_USER_TIMER
 119         alg     \w2,__LC_SYSTEM_TIMER
 120         stg     \w1,__LC_USER_TIMER
 121         stg     \w2,__LC_SYSTEM_TIMER
 122         mvc     __LC_LAST_UPDATE_TIMER(8),\enter_timer
 123         .endm
 124
 125         .macro  LAST_BREAK scratch
 126         srag    \scratch,%r10,23
 127         jz      .+10
 128         stg     %r10,__TI_last_break(%r12)
 129         .endm
 130
 131         .macro REENABLE_IRQS
 132         stg     %r8,__LC_RETURN_PSW
 133         ni      __LC_RETURN_PSW,0xbf
 134         ssm     __LC_RETURN_PSW
 135         .endm
 136
 137         .macro STCK savearea
 138 #ifdef CONFIG_HAVE_MARCH_Z9_109_FEATURES
 139         .insn   s,0xb27c0000,\savearea          # store clock fast
 140 #else
 141         .insn   s,0xb2050000,\savearea          # store clock
 142 #endif
 143         .endm
 144
 145         /*
 146          * The TSTMSK macro generates a test-under-mask instruction by
 147          * calculating the memory offset for the specified mask value.
 148          * Mask value can be any constant.  The macro shifts the mask
 149          * value to calculate the memory offset for the test-under-mask
 150          * instruction.
 151          */
 152         .macro TSTMSK addr, mask, size=8, bytepos=0
 153                 .if (\bytepos < \size) && (\mask >> 8)
 154                         .if (\mask & 0xff)
 155                                 .error "Mask exceeds byte boundary"
 156                         .endif
 157                         TSTMSK \addr, "(\mask >> 8)", \size, "(\bytepos + 1)"
 158                         .exitm
 159                 .endif
 160                 .ifeq \mask
 161                         .error "Mask must not be zero"
 162                 .endif
 163                 off = \size - \bytepos - 1
 164                 tm      off+\addr, \mask
 165         .endm
 166
 167         .macro BPOFF
 168         .pushsection .altinstr_replacement, "ax"
 169 660:    .long   0xb2e8c000
 170         .popsection
 171 661:    .long   0x47000000
 172         .pushsection .altinstructions, "a"
 173         .long 661b - .
 174         .long 660b - .
 175         .word 82
 176         .byte 4
 177         .byte 4
 178         .popsection
 179         .endm
 180
 181         .macro BPON
 182         .pushsection .altinstr_replacement, "ax"
 183 662:    .long   0xb2e8d000
 184         .popsection
 185 663:    .long   0x47000000
 186         .pushsection .altinstructions, "a"
 187         .long 663b - .
 188         .long 662b - .
 189         .word 82
 190         .byte 4
 191         .byte 4
 192         .popsection
 193         .endm
 194
 195         .macro BPENTER tif_ptr,tif_mask
 196         .pushsection .altinstr_replacement, "ax"
 197 662:    .word   0xc004, 0x0000, 0x0000  # 6 byte nop
 198         .word   0xc004, 0x0000, 0x0000  # 6 byte nop
 199         .popsection
 200 664:    TSTMSK  \tif_ptr,\tif_mask
 201         jz      . + 8
 202         .long   0xb2e8d000
 203         .pushsection .altinstructions, "a"
 204         .long 664b - .
 205         .long 662b - .
 206         .word 82
 207         .byte 12
 208         .byte 12
 209         .popsection
 210         .endm
 211
 212         .macro BPEXIT tif_ptr,tif_mask
 213         TSTMSK  \tif_ptr,\tif_mask
 214         .pushsection .altinstr_replacement, "ax"
 215 662:    jnz     . + 8
 216         .long   0xb2e8d000
 217         .popsection
 218 664:    jz      . + 8
 219         .long   0xb2e8c000
 220         .pushsection .altinstructions, "a"
 221         .long 664b - .
 222         .long 662b - .
 223         .word 82
 224         .byte 8
 225         .byte 8
 226         .popsection
 227         .endm
 228
 229         GEN_BR_THUNK %r9
 230         GEN_BR_THUNK %r14
 231         GEN_BR_THUNK %r14,%r11
 232
 233         .section .kprobes.text, "ax"
 234
 235 ENTRY(__bpon)
 236         .globl __bpon
 237         BPON
 238         BR_EX   %r14
 239
 240 /*
 241  * Scheduler resume function, called by switch_to
 242  *  gpr2 = (task_struct *) prev
 243  *  gpr3 = (task_struct *) next
 244  * Returns:
 245  *  gpr2 = prev
 246  */
 247 ENTRY(__switch_to)
 248         stmg    %r6,%r15,__SF_GPRS(%r15)        # store gprs of prev task
 249         lgr     %r1,%r2
 250         aghi    %r1,__TASK_thread               # thread_struct of prev task
 251         lg      %r4,__TASK_thread_info(%r2)     # get thread_info of prev
 252         lg      %r5,__TASK_thread_info(%r3)     # get thread_info of next
 253         stg     %r15,__THREAD_ksp(%r1)          # store kernel stack of prev
 254         lgr     %r1,%r3
 255         aghi    %r1,__TASK_thread               # thread_struct of next task
 256         lgr     %r15,%r5
 257         aghi    %r15,STACK_INIT                 # end of kernel stack of next
 258         stg     %r3,__LC_CURRENT                # store task struct of next
 259         stg     %r5,__LC_THREAD_INFO            # store thread info of next
 260         stg     %r15,__LC_KERNEL_STACK          # store end of kernel stack
 261         lg      %r15,__THREAD_ksp(%r1)          # load kernel stack of next
 262         lctl    %c4,%c4,__TASK_pid(%r3)         # load pid to control reg. 4
 263         mvc     __LC_CURRENT_PID(4,%r0),__TASK_pid(%r3) # store pid of next
 264         lmg     %r6,%r15,__SF_GPRS(%r15)        # load gprs of next task
 265         TSTMSK  __LC_MACHINE_FLAGS,MACHINE_FLAG_LPP
 266         jz      0f
 267         .insn   s,0xb2800000,__LC_LPP           # set program parameter
 268 0:      BR_EX   %r14
 269
 270 .L__critical_start:
 271
 272 #if IS_ENABLED(CONFIG_KVM)
 273 /*
 274  * sie64a calling convention:
 275  * %r2 pointer to sie control block
 276  * %r3 guest register save area
 277  */
 278 ENTRY(sie64a)
 279         stmg    %r6,%r14,__SF_GPRS(%r15)        # save kernel registers
 280         lg      %r12,__LC_CURRENT
 281         stg     %r2,__SF_EMPTY(%r15)            # save control block pointer
 282         stg     %r3,__SF_EMPTY+8(%r15)          # save guest register save area
 283         xc      __SF_EMPTY+16(8,%r15),__SF_EMPTY+16(%r15) # reason code = 0
 284         mvc     __SF_EMPTY+24(8,%r15),__TI_flags(%r12) # copy thread flags
 285         TSTMSK  __LC_CPU_FLAGS,_CIF_FPU         # load guest fp/vx registers ?
 286         jno     .Lsie_load_guest_gprs
 287         brasl   %r14,load_fpu_regs              # load guest fp/vx regs
 288 .Lsie_load_guest_gprs:
 289         lmg     %r0,%r13,0(%r3)                 # load guest gprs 0-13
 290         lg      %r14,__LC_GMAP                  # get gmap pointer
 291         ltgr    %r14,%r14
 292         jz      .Lsie_gmap
 293         lctlg   %c1,%c1,__GMAP_ASCE(%r14)       # load primary asce
 294 .Lsie_gmap:
 295         lg      %r14,__SF_EMPTY(%r15)           # get control block pointer
 296         oi      __SIE_PROG0C+3(%r14),1          # we are going into SIE now
 297         tm      __SIE_PROG20+3(%r14),3          # last exit...
 298         jnz     .Lsie_skip
 299         TSTMSK  __LC_CPU_FLAGS,_CIF_FPU
 300         jo      .Lsie_skip                      # exit if fp/vx regs changed
 301         BPEXIT  __SF_EMPTY+24(%r15),(_TIF_ISOLATE_BP|_TIF_ISOLATE_BP_GUEST)
 302         sie     0(%r14)
 303 .Lsie_exit:
 304         BPOFF
 305         BPENTER __SF_EMPTY+24(%r15),(_TIF_ISOLATE_BP|_TIF_ISOLATE_BP_GUEST)
 306 .Lsie_skip:
 307         ni      __SIE_PROG0C+3(%r14),0xfe       # no longer in SIE
 308         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 309 .Lsie_done:
 310 # some program checks are suppressing. C code (e.g. do_protection_exception)
 311 # will rewind the PSW by the ILC, which is often 4 bytes in case of SIE. There
 312 # are some corner cases (e.g. runtime instrumentation) where ILC is unpredictable.
 313 # Other instructions between sie64a and .Lsie_done should not cause program
 314 # interrupts. So lets use 3 nops as a landing pad for all possible rewinds.
 315 # See also .Lcleanup_sie
 316 .Lrewind_pad6:
 317         nopr    7
 318 .Lrewind_pad4:
 319         nopr    7
 320 .Lrewind_pad2:
 321         nopr    7
 322         .globl sie_exit
 323 sie_exit:
 324         lg      %r14,__SF_EMPTY+8(%r15)         # load guest register save area
 325         stmg    %r0,%r13,0(%r14)                # save guest gprs 0-13
 326         xgr     %r0,%r0                         # clear guest registers to
 327         xgr     %r1,%r1                         # prevent speculative use
 328         xgr     %r2,%r2
 329         xgr     %r3,%r3
 330         xgr     %r4,%r4
 331         xgr     %r5,%r5
 332         lmg     %r6,%r14,__SF_GPRS(%r15)        # restore kernel registers
 333         lg      %r2,__SF_EMPTY+16(%r15)         # return exit reason code
 334         BR_EX   %r14
 335 .Lsie_fault:
 336         lghi    %r14,-EFAULT
 337         stg     %r14,__SF_EMPTY+16(%r15)        # set exit reason code
 338         j       sie_exit
 339
 340         EX_TABLE(.Lrewind_pad6,.Lsie_fault)
 341         EX_TABLE(.Lrewind_pad4,.Lsie_fault)
 342         EX_TABLE(.Lrewind_pad2,.Lsie_fault)
 343         EX_TABLE(sie_exit,.Lsie_fault)
 344 #endif
 345
 346 /*
 347  * SVC interrupt handler routine. System calls are synchronous events and
 348  * are executed with interrupts enabled.
 349  */
 350
 351 ENTRY(system_call)
 352         stpt    __LC_SYNC_ENTER_TIMER
 353 .Lsysc_stmg:
 354         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 355         BPOFF
 356         lg      %r10,__LC_LAST_BREAK
 357         lg      %r12,__LC_THREAD_INFO
 358         lghi    %r14,_PIF_SYSCALL
 359 .Lsysc_per:
 360         lg      %r15,__LC_KERNEL_STACK
 361         la      %r11,STACK_FRAME_OVERHEAD(%r15) # pointer to pt_regs
 362         LAST_BREAK %r13
 363 .Lsysc_vtime:
 364         UPDATE_VTIME %r10,%r13,__LC_SYNC_ENTER_TIMER
 365         BPENTER __TI_flags(%r12),_TIF_ISOLATE_BP
 366         stmg    %r0,%r7,__PT_R0(%r11)
 367         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 368         mvc     __PT_PSW(16,%r11),__LC_SVC_OLD_PSW
 369         mvc     __PT_INT_CODE(4,%r11),__LC_SVC_ILC
 370         stg     %r14,__PT_FLAGS(%r11)
 371 .Lsysc_do_svc:
 372         # clear user controlled register to prevent speculative use
 373         xgr     %r0,%r0
 374         lg      %r10,__TI_sysc_table(%r12)      # address of system call table
 375         llgh    %r8,__PT_INT_CODE+2(%r11)
 376         slag    %r8,%r8,2                       # shift and test for svc 0
 377         jnz     .Lsysc_nr_ok
 378         # svc 0: system call number in %r1
 379         llgfr   %r1,%r1                         # clear high word in r1
 380         cghi    %r1,NR_syscalls
 381         jnl     .Lsysc_nr_ok
 382         sth     %r1,__PT_INT_CODE+2(%r11)
 383         slag    %r8,%r1,2
 384 .Lsysc_nr_ok:
 385         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 386         stg     %r2,__PT_ORIG_GPR2(%r11)
 387         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 388         lgf     %r9,0(%r8,%r10)                 # get system call add.
 389         TSTMSK  __TI_flags(%r12),_TIF_TRACE
 390         jnz     .Lsysc_tracesys
 391         BASR_EX %r14,%r9                        # call sys_xxxx
 392         stg     %r2,__PT_R2(%r11)               # store return value
 393
 394 .Lsysc_return:
 395         LOCKDEP_SYS_EXIT
 396 .Lsysc_tif:
 397         TSTMSK  __PT_FLAGS(%r11),_PIF_WORK
 398         jnz     .Lsysc_work
 399         TSTMSK  __TI_flags(%r12),_TIF_WORK
 400         jnz     .Lsysc_work                     # check for work
 401         TSTMSK  __LC_CPU_FLAGS,_CIF_WORK
 402         jnz     .Lsysc_work
 403         BPEXIT  __TI_flags(%r12),_TIF_ISOLATE_BP
 404 .Lsysc_restore:
 405         lg      %r14,__LC_VDSO_PER_CPU
 406         lmg     %r0,%r10,__PT_R0(%r11)
 407         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 408 .Lsysc_exit_timer:
 409         stpt    __LC_EXIT_TIMER
 410         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 411         lmg     %r11,%r15,__PT_R11(%r11)
 412         lpswe   __LC_RETURN_PSW
 413 .Lsysc_done:
 414
 415 #
 416 # One of the work bits is on. Find out which one.
 417 #
 418 .Lsysc_work:
 419         TSTMSK  __LC_CPU_FLAGS,_CIF_MCCK_PENDING
 420         jo      .Lsysc_mcck_pending
 421         TSTMSK  __TI_flags(%r12),_TIF_NEED_RESCHED
 422         jo      .Lsysc_reschedule
 423 #ifdef CONFIG_UPROBES
 424         TSTMSK  __TI_flags(%r12),_TIF_UPROBE
 425         jo      .Lsysc_uprobe_notify
 426 #endif
 427         TSTMSK  __PT_FLAGS(%r11),_PIF_PER_TRAP
 428         jo      .Lsysc_singlestep
 429         TSTMSK  __TI_flags(%r12),_TIF_SIGPENDING
 430         jo      .Lsysc_sigpending
 431         TSTMSK  __TI_flags(%r12),_TIF_NOTIFY_RESUME
 432         jo      .Lsysc_notify_resume
 433         TSTMSK  __LC_CPU_FLAGS,_CIF_FPU
 434         jo      .Lsysc_vxrs
 435         TSTMSK  __LC_CPU_FLAGS,_CIF_ASCE
 436         jo      .Lsysc_uaccess
 437         j       .Lsysc_return           # beware of critical section cleanup
 438
 439 #
 440 # _TIF_NEED_RESCHED is set, call schedule
 441 #
 442 .Lsysc_reschedule:
 443         larl    %r14,.Lsysc_return
 444         jg      schedule
 445
 446 #
 447 # _CIF_MCCK_PENDING is set, call handler
 448 #
 449 .Lsysc_mcck_pending:
 450         larl    %r14,.Lsysc_return
 451         jg      s390_handle_mcck        # TIF bit will be cleared by handler
 452
 453 #
 454 # _CIF_ASCE is set, load user space asce
 455 #
 456 .Lsysc_uaccess:
 457         ni      __LC_CPU_FLAGS+7,255-_CIF_ASCE
 458         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 459         j       .Lsysc_return
 460
 461 #
 462 # CIF_FPU is set, restore floating-point controls and floating-point registers.
 463 #
 464 .Lsysc_vxrs:
 465         larl    %r14,.Lsysc_return
 466         jg      load_fpu_regs
 467
 468 #
 469 # _TIF_SIGPENDING is set, call do_signal
 470 #
 471 .Lsysc_sigpending:
 472         lgr     %r2,%r11                # pass pointer to pt_regs
 473         brasl   %r14,do_signal
 474         TSTMSK  __PT_FLAGS(%r11),_PIF_SYSCALL
 475         jno     .Lsysc_return
 476         lmg     %r2,%r7,__PT_R2(%r11)   # load svc arguments
 477         lg      %r10,__TI_sysc_table(%r12)      # address of system call table
 478         lghi    %r8,0                   # svc 0 returns -ENOSYS
 479         llgh    %r1,__PT_INT_CODE+2(%r11)       # load new svc number
 480         cghi    %r1,NR_syscalls
 481         jnl     .Lsysc_nr_ok            # invalid svc number -> do svc 0
 482         slag    %r8,%r1,2
 483         j       .Lsysc_nr_ok            # restart svc
 484
 485 #
 486 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 487 #
 488 .Lsysc_notify_resume:
 489         lgr     %r2,%r11                # pass pointer to pt_regs
 490         larl    %r14,.Lsysc_return
 491         jg      do_notify_resume
 492
 493 #
 494 # _TIF_UPROBE is set, call uprobe_notify_resume
 495 #
 496 #ifdef CONFIG_UPROBES
 497 .Lsysc_uprobe_notify:
 498         lgr     %r2,%r11                # pass pointer to pt_regs
 499         larl    %r14,.Lsysc_return
 500         jg      uprobe_notify_resume
 501 #endif
 502
 503 #
 504 # _PIF_PER_TRAP is set, call do_per_trap
 505 #
 506 .Lsysc_singlestep:
 507         ni      __PT_FLAGS+7(%r11),255-_PIF_PER_TRAP
 508         lgr     %r2,%r11                # pass pointer to pt_regs
 509         larl    %r14,.Lsysc_return
 510         jg      do_per_trap
 511
 512 #
 513 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 514 # and after the system call
 515 #
 516 .Lsysc_tracesys:
 517         lgr     %r2,%r11                # pass pointer to pt_regs
 518         la      %r3,0
 519         llgh    %r0,__PT_INT_CODE+2(%r11)
 520         stg     %r0,__PT_R2(%r11)
 521         brasl   %r14,do_syscall_trace_enter
 522         lghi    %r0,NR_syscalls
 523         clgr    %r0,%r2
 524         jnh     .Lsysc_tracenogo
 525         sllg    %r8,%r2,2
 526         lgf     %r9,0(%r8,%r10)
 527 .Lsysc_tracego:
 528         lmg     %r3,%r7,__PT_R3(%r11)
 529         stg     %r7,STACK_FRAME_OVERHEAD(%r15)
 530         lg      %r2,__PT_ORIG_GPR2(%r11)
 531         BASR_EX %r14,%r9                # call sys_xxx
 532         stg     %r2,__PT_R2(%r11)       # store return value
 533 .Lsysc_tracenogo:
 534         TSTMSK  __TI_flags(%r12),_TIF_TRACE
 535         jz      .Lsysc_return
 536         lgr     %r2,%r11                # pass pointer to pt_regs
 537         larl    %r14,.Lsysc_return
 538         jg      do_syscall_trace_exit
 539
 540 #
 541 # a new process exits the kernel with ret_from_fork
 542 #
 543 ENTRY(ret_from_fork)
 544         la      %r11,STACK_FRAME_OVERHEAD(%r15)
 545         lg      %r12,__LC_THREAD_INFO
 546         brasl   %r14,schedule_tail
 547         TRACE_IRQS_ON
 548         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 549         tm      __PT_PSW+1(%r11),0x01   # forking a kernel thread ?
 550         jne     .Lsysc_tracenogo
 551         # it's a kernel thread
 552         lmg     %r9,%r10,__PT_R9(%r11)  # load gprs
 553 ENTRY(kernel_thread_starter)
 554         la      %r2,0(%r10)
 555         BASR_EX %r14,%r9
 556         j       .Lsysc_tracenogo
 557
 558 /*
 559  * Program check handler routine
 560  */
 561
 562 ENTRY(pgm_check_handler)
 563         stpt    __LC_SYNC_ENTER_TIMER
 564         BPOFF
 565         stmg    %r8,%r15,__LC_SAVE_AREA_SYNC
 566         lg      %r10,__LC_LAST_BREAK
 567         lg      %r12,__LC_THREAD_INFO
 568         larl    %r13,cleanup_critical
 569         lmg     %r8,%r9,__LC_PGM_OLD_PSW
 570         tmhh    %r8,0x0001              # test problem state bit
 571         jnz     2f                      # -> fault in user space
 572 #if IS_ENABLED(CONFIG_KVM)
 573         # cleanup critical section for sie64a
 574         lgr     %r14,%r9
 575         slg     %r14,BASED(.Lsie_critical_start)
 576         clg     %r14,BASED(.Lsie_critical_length)
 577         jhe     0f
 578         brasl   %r14,.Lcleanup_sie
 579 #endif
 580 0:      tmhh    %r8,0x4000              # PER bit set in old PSW ?
 581         jnz     1f                      # -> enabled, can't be a double fault
 582         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 583         jnz     .Lpgm_svcper            # -> single stepped svc
 584 1:      CHECK_STACK STACK_SIZE,__LC_SAVE_AREA_SYNC
 585         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 586         j       3f
 587 2:      LAST_BREAK %r14
 588         UPDATE_VTIME %r14,%r15,__LC_SYNC_ENTER_TIMER
 589         BPENTER __TI_flags(%r12),_TIF_ISOLATE_BP
 590         lg      %r15,__LC_KERNEL_STACK
 591         lg      %r14,__TI_task(%r12)
 592         aghi    %r14,__TASK_thread      # pointer to thread_struct
 593         lghi    %r13,__LC_PGM_TDB
 594         tm      __LC_PGM_ILC+2,0x02     # check for transaction abort
 595         jz      3f
 596         mvc     __THREAD_trap_tdb(256,%r14),0(%r13)
 597 3:      la      %r11,STACK_FRAME_OVERHEAD(%r15)
 598         stmg    %r0,%r7,__PT_R0(%r11)
 599         # clear user controlled registers to prevent speculative use
 600         xgr     %r0,%r0
 601         xgr     %r1,%r1
 602         xgr     %r2,%r2
 603         xgr     %r3,%r3
 604         xgr     %r4,%r4
 605         xgr     %r5,%r5
 606         xgr     %r6,%r6
 607         xgr     %r7,%r7
 608         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_SYNC
 609         stmg    %r8,%r9,__PT_PSW(%r11)
 610         mvc     __PT_INT_CODE(4,%r11),__LC_PGM_ILC
 611         mvc     __PT_INT_PARM_LONG(8,%r11),__LC_TRANS_EXC_CODE
 612         xc      __PT_FLAGS(8,%r11),__PT_FLAGS(%r11)
 613         stg     %r10,__PT_ARGS(%r11)
 614         tm      __LC_PGM_ILC+3,0x80     # check for per exception
 615         jz      4f
 616         tmhh    %r8,0x0001              # kernel per event ?
 617         jz      .Lpgm_kprobe
 618         oi      __PT_FLAGS+7(%r11),_PIF_PER_TRAP
 619         mvc     __THREAD_per_address(8,%r14),__LC_PER_ADDRESS
 620         mvc     __THREAD_per_cause(2,%r14),__LC_PER_CODE
 621         mvc     __THREAD_per_paid(1,%r14),__LC_PER_ACCESS_ID
 622 4:      REENABLE_IRQS
 623         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 624         larl    %r1,pgm_check_table
 625         llgh    %r10,__PT_INT_CODE+2(%r11)
 626         nill    %r10,0x007f
 627         sll     %r10,2
 628         je      .Lpgm_return
 629         lgf     %r9,0(%r10,%r1)         # load address of handler routine
 630         lgr     %r2,%r11                # pass pointer to pt_regs
 631         BASR_EX %r14,%r9                # branch to interrupt-handler
 632 .Lpgm_return:
 633         LOCKDEP_SYS_EXIT
 634         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 635         jno     .Lsysc_restore
 636         j       .Lsysc_tif
 637
 638 #
 639 # PER event in supervisor state, must be kprobes
 640 #
 641 .Lpgm_kprobe:
 642         REENABLE_IRQS
 643         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 644         lgr     %r2,%r11                # pass pointer to pt_regs
 645         brasl   %r14,do_per_trap
 646         j       .Lpgm_return
 647
 648 #
 649 # single stepped system call
 650 #
 651 .Lpgm_svcper:
 652         mvc     __LC_RETURN_PSW(8),__LC_SVC_NEW_PSW
 653         larl    %r14,.Lsysc_per
 654         stg     %r14,__LC_RETURN_PSW+8
 655         lghi    %r14,_PIF_SYSCALL | _PIF_PER_TRAP
 656         lpswe   __LC_RETURN_PSW         # branch to .Lsysc_per and enable irqs
 657
 658 /*
 659  * IO interrupt handler routine
 660  */
 661 ENTRY(io_int_handler)
 662         STCK    __LC_INT_CLOCK
 663         stpt    __LC_ASYNC_ENTER_TIMER
 664         BPOFF
 665         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 666         lg      %r10,__LC_LAST_BREAK
 667         lg      %r12,__LC_THREAD_INFO
 668         larl    %r13,cleanup_critical
 669         lmg     %r8,%r9,__LC_IO_OLD_PSW
 670         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_ENTER_TIMER
 671         stmg    %r0,%r7,__PT_R0(%r11)
 672         # clear user controlled registers to prevent speculative use
 673         xgr     %r0,%r0
 674         xgr     %r1,%r1
 675         xgr     %r2,%r2
 676         xgr     %r3,%r3
 677         xgr     %r4,%r4
 678         xgr     %r5,%r5
 679         xgr     %r6,%r6
 680         xgr     %r7,%r7
 681         xgr     %r10,%r10
 682         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 683         stmg    %r8,%r9,__PT_PSW(%r11)
 684         mvc     __PT_INT_CODE(12,%r11),__LC_SUBCHANNEL_ID
 685         xc      __PT_FLAGS(8,%r11),__PT_FLAGS(%r11)
 686         TSTMSK  __LC_CPU_FLAGS,_CIF_IGNORE_IRQ
 687         jo      .Lio_restore
 688         TRACE_IRQS_OFF
 689         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 690 .Lio_loop:
 691         lgr     %r2,%r11                # pass pointer to pt_regs
 692         lghi    %r3,IO_INTERRUPT
 693         tm      __PT_INT_CODE+8(%r11),0x80      # adapter interrupt ?
 694         jz      .Lio_call
 695         lghi    %r3,THIN_INTERRUPT
 696 .Lio_call:
 697         brasl   %r14,do_IRQ
 698         TSTMSK  __LC_MACHINE_FLAGS,MACHINE_FLAG_LPAR
 699         jz      .Lio_return
 700         tpi     0
 701         jz      .Lio_return
 702         mvc     __PT_INT_CODE(12,%r11),__LC_SUBCHANNEL_ID
 703         j       .Lio_loop
 704 .Lio_return:
 705         LOCKDEP_SYS_EXIT
 706         TRACE_IRQS_ON
 707 .Lio_tif:
 708         TSTMSK  __TI_flags(%r12),_TIF_WORK
 709         jnz     .Lio_work               # there is work to do (signals etc.)
 710         TSTMSK  __LC_CPU_FLAGS,_CIF_WORK
 711         jnz     .Lio_work
 712 .Lio_restore:
 713         lg      %r14,__LC_VDSO_PER_CPU
 714         lmg     %r0,%r10,__PT_R0(%r11)
 715         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r11)
 716         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 717         jno     .Lio_exit_kernel
 718         BPEXIT  __TI_flags(%r12),_TIF_ISOLATE_BP
 719 .Lio_exit_timer:
 720         stpt    __LC_EXIT_TIMER
 721         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
 722 .Lio_exit_kernel:
 723         lmg     %r11,%r15,__PT_R11(%r11)
 724         lpswe   __LC_RETURN_PSW
 725 .Lio_done:
 726
 727 #
 728 # There is work todo, find out in which context we have been interrupted:
 729 # 1) if we return to user space we can do all _TIF_WORK work
 730 # 2) if we return to kernel code and kvm is enabled check if we need to
 731 #    modify the psw to leave SIE
 732 # 3) if we return to kernel code and preemptive scheduling is enabled check
 733 #    the preemption counter and if it is zero call preempt_schedule_irq
 734 # Before any work can be done, a switch to the kernel stack is required.
 735 #
 736 .Lio_work:
 737         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
 738         jo      .Lio_work_user          # yes -> do resched & signal
 739 #ifdef CONFIG_PREEMPT
 740         # check for preemptive scheduling
 741         icm     %r0,15,__TI_precount(%r12)
 742         jnz     .Lio_restore            # preemption is disabled
 743         TSTMSK  __TI_flags(%r12),_TIF_NEED_RESCHED
 744         jno     .Lio_restore
 745         # switch to kernel stack
 746         lg      %r1,__PT_R15(%r11)
 747         aghi    %r1,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
 748         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 749         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 750         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 751         lgr     %r15,%r1
 752         # TRACE_IRQS_ON already done at .Lio_return, call
 753         # TRACE_IRQS_OFF to keep things symmetrical
 754         TRACE_IRQS_OFF
 755         brasl   %r14,preempt_schedule_irq
 756         j       .Lio_return
 757 #else
 758         j       .Lio_restore
 759 #endif
 760
 761 #
 762 # Need to do work before returning to userspace, switch to kernel stack
 763 #
 764 .Lio_work_user:
 765         lg      %r1,__LC_KERNEL_STACK
 766         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
 767         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
 768         la      %r11,STACK_FRAME_OVERHEAD(%r1)
 769         lgr     %r15,%r1
 770
 771 #
 772 # One of the work bits is on. Find out which one.
 773 #
 774 .Lio_work_tif:
 775         TSTMSK  __LC_CPU_FLAGS,_CIF_MCCK_PENDING
 776         jo      .Lio_mcck_pending
 777         TSTMSK  __TI_flags(%r12),_TIF_NEED_RESCHED
 778         jo      .Lio_reschedule
 779         TSTMSK  __TI_flags(%r12),_TIF_SIGPENDING
 780         jo      .Lio_sigpending
 781         TSTMSK  __TI_flags(%r12),_TIF_NOTIFY_RESUME
 782         jo      .Lio_notify_resume
 783         TSTMSK  __LC_CPU_FLAGS,_CIF_FPU
 784         jo      .Lio_vxrs
 785         TSTMSK  __LC_CPU_FLAGS,_CIF_ASCE
 786         jo      .Lio_uaccess
 787         j       .Lio_return             # beware of critical section cleanup
 788
 789 #
 790 # _CIF_MCCK_PENDING is set, call handler
 791 #
 792 .Lio_mcck_pending:
 793         # TRACE_IRQS_ON already done at .Lio_return
 794         brasl   %r14,s390_handle_mcck   # TIF bit will be cleared by handler
 795         TRACE_IRQS_OFF
 796         j       .Lio_return
 797
 798 #
 799 # _CIF_ASCE is set, load user space asce
 800 #
 801 .Lio_uaccess:
 802         ni      __LC_CPU_FLAGS+7,255-_CIF_ASCE
 803         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
 804         j       .Lio_return
 805
 806 #
 807 # CIF_FPU is set, restore floating-point controls and floating-point registers.
 808 #
 809 .Lio_vxrs:
 810         larl    %r14,.Lio_return
 811         jg      load_fpu_regs
 812
 813 #
 814 # _TIF_NEED_RESCHED is set, call schedule
 815 #
 816 .Lio_reschedule:
 817         # TRACE_IRQS_ON already done at .Lio_return
 818         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 819         brasl   %r14,schedule           # call scheduler
 820         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 821         TRACE_IRQS_OFF
 822         j       .Lio_return
 823
 824 #
 825 # _TIF_SIGPENDING or is set, call do_signal
 826 #
 827 .Lio_sigpending:
 828         # TRACE_IRQS_ON already done at .Lio_return
 829         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 830         lgr     %r2,%r11                # pass pointer to pt_regs
 831         brasl   %r14,do_signal
 832         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 833         TRACE_IRQS_OFF
 834         j       .Lio_return
 835
 836 #
 837 # _TIF_NOTIFY_RESUME or is set, call do_notify_resume
 838 #
 839 .Lio_notify_resume:
 840         # TRACE_IRQS_ON already done at .Lio_return
 841         ssm     __LC_SVC_NEW_PSW        # reenable interrupts
 842         lgr     %r2,%r11                # pass pointer to pt_regs
 843         brasl   %r14,do_notify_resume
 844         ssm     __LC_PGM_NEW_PSW        # disable I/O and ext. interrupts
 845         TRACE_IRQS_OFF
 846         j       .Lio_return
 847
 848 /*
 849  * External interrupt handler routine
 850  */
 851 ENTRY(ext_int_handler)
 852         STCK    __LC_INT_CLOCK
 853         stpt    __LC_ASYNC_ENTER_TIMER
 854         BPOFF
 855         stmg    %r8,%r15,__LC_SAVE_AREA_ASYNC
 856         lg      %r10,__LC_LAST_BREAK
 857         lg      %r12,__LC_THREAD_INFO
 858         larl    %r13,cleanup_critical
 859         lmg     %r8,%r9,__LC_EXT_OLD_PSW
 860         SWITCH_ASYNC __LC_SAVE_AREA_ASYNC,__LC_ASYNC_ENTER_TIMER
 861         stmg    %r0,%r7,__PT_R0(%r11)
 862         # clear user controlled registers to prevent speculative use
 863         xgr     %r0,%r0
 864         xgr     %r1,%r1
 865         xgr     %r2,%r2
 866         xgr     %r3,%r3
 867         xgr     %r4,%r4
 868         xgr     %r5,%r5
 869         xgr     %r6,%r6
 870         xgr     %r7,%r7
 871         xgr     %r10,%r10
 872         mvc     __PT_R8(64,%r11),__LC_SAVE_AREA_ASYNC
 873         stmg    %r8,%r9,__PT_PSW(%r11)
 874         lghi    %r1,__LC_EXT_PARAMS2
 875         mvc     __PT_INT_CODE(4,%r11),__LC_EXT_CPU_ADDR
 876         mvc     __PT_INT_PARM(4,%r11),__LC_EXT_PARAMS
 877         mvc     __PT_INT_PARM_LONG(8,%r11),0(%r1)
 878         xc      __PT_FLAGS(8,%r11),__PT_FLAGS(%r11)
 879         TSTMSK  __LC_CPU_FLAGS,_CIF_IGNORE_IRQ
 880         jo      .Lio_restore
 881         TRACE_IRQS_OFF
 882         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
 883         lgr     %r2,%r11                # pass pointer to pt_regs
 884         lghi    %r3,EXT_INTERRUPT
 885         brasl   %r14,do_IRQ
 886         j       .Lio_return
 887
 888 /*
 889  * Load idle PSW. The second "half" of this function is in .Lcleanup_idle.
 890  */
 891 ENTRY(psw_idle)
 892         stg     %r14,(__SF_GPRS+8*8)(%r15)
 893         stg     %r3,__SF_EMPTY(%r15)
 894         larl    %r1,.Lpsw_idle_lpsw+4
 895         stg     %r1,__SF_EMPTY+8(%r15)
 896 #ifdef CONFIG_SMP
 897         larl    %r1,smp_cpu_mtid
 898         llgf    %r1,0(%r1)
 899         ltgr    %r1,%r1
 900         jz      .Lpsw_idle_stcctm
 901         .insn   rsy,0xeb0000000017,%r1,5,__SF_EMPTY+16(%r15)
 902 .Lpsw_idle_stcctm:
 903 #endif
 904         BPON
 905         STCK    __CLOCK_IDLE_ENTER(%r2)
 906         stpt    __TIMER_IDLE_ENTER(%r2)
 907 .Lpsw_idle_lpsw:
 908         lpswe   __SF_EMPTY(%r15)
 909         BR_EX   %r14
 910 .Lpsw_idle_end:
 911
 912 /*
 913  * Store floating-point controls and floating-point or vector register
 914  * depending whether the vector facility is available.  A critical section
 915  * cleanup assures that the registers are stored even if interrupted for
 916  * some other work.  The CIF_FPU flag is set to trigger a lazy restore
 917  * of the register contents at return from io or a system call.
 918  */
 919 ENTRY(save_fpu_regs)
 920         lg      %r2,__LC_CURRENT
 921         aghi    %r2,__TASK_thread
 922         TSTMSK  __LC_CPU_FLAGS,_CIF_FPU
 923         jo      .Lsave_fpu_regs_exit
 924         stfpc   __THREAD_FPU_fpc(%r2)
 925 .Lsave_fpu_regs_fpc_end:
 926         lg      %r3,__THREAD_FPU_regs(%r2)
 927         TSTMSK  __LC_MACHINE_FLAGS,MACHINE_FLAG_VX
 928         jz      .Lsave_fpu_regs_fp        # no -> store FP regs
 929 .Lsave_fpu_regs_vx_low:
 930         VSTM    %v0,%v15,0,%r3            # vstm 0,15,0(3)
 931 .Lsave_fpu_regs_vx_high:
 932         VSTM    %v16,%v31,256,%r3         # vstm 16,31,256(3)
 933         j       .Lsave_fpu_regs_done      # -> set CIF_FPU flag
 934 .Lsave_fpu_regs_fp:
 935         std     0,0(%r3)
 936         std     1,8(%r3)
 937         std     2,16(%r3)
 938         std     3,24(%r3)
 939         std     4,32(%r3)
 940         std     5,40(%r3)
 941         std     6,48(%r3)
 942         std     7,56(%r3)
 943         std     8,64(%r3)
 944         std     9,72(%r3)
 945         std     10,80(%r3)
 946         std     11,88(%r3)
 947         std     12,96(%r3)
 948         std     13,104(%r3)
 949         std     14,112(%r3)
 950         std     15,120(%r3)
 951 .Lsave_fpu_regs_done:
 952         oi      __LC_CPU_FLAGS+7,_CIF_FPU
 953 .Lsave_fpu_regs_exit:
 954         BR_EX   %r14
 955 .Lsave_fpu_regs_end:
 956
 957 /*
 958  * Load floating-point controls and floating-point or vector registers.
 959  * A critical section cleanup assures that the register contents are
 960  * loaded even if interrupted for some other work.
 961  *
 962  * There are special calling conventions to fit into sysc and io return work:
 963  *      %r15:   <kernel stack>
 964  * The function requires:
 965  *      %r4
 966  */
 967 load_fpu_regs:
 968         lg      %r4,__LC_CURRENT
 969         aghi    %r4,__TASK_thread
 970         TSTMSK  __LC_CPU_FLAGS,_CIF_FPU
 971         jno     .Lload_fpu_regs_exit
 972         lfpc    __THREAD_FPU_fpc(%r4)
 973         TSTMSK  __LC_MACHINE_FLAGS,MACHINE_FLAG_VX
 974         lg      %r4,__THREAD_FPU_regs(%r4)      # %r4 <- reg save area
 975         jz      .Lload_fpu_regs_fp              # -> no VX, load FP regs
 976 .Lload_fpu_regs_vx:
 977         VLM     %v0,%v15,0,%r4
 978 .Lload_fpu_regs_vx_high:
 979         VLM     %v16,%v31,256,%r4
 980         j       .Lload_fpu_regs_done
 981 .Lload_fpu_regs_fp:
 982         ld      0,0(%r4)
 983         ld      1,8(%r4)
 984         ld      2,16(%r4)
 985         ld      3,24(%r4)
 986         ld      4,32(%r4)
 987         ld      5,40(%r4)
 988         ld      6,48(%r4)
 989         ld      7,56(%r4)
 990         ld      8,64(%r4)
 991         ld      9,72(%r4)
 992         ld      10,80(%r4)
 993         ld      11,88(%r4)
 994         ld      12,96(%r4)
 995         ld      13,104(%r4)
 996         ld      14,112(%r4)
 997         ld      15,120(%r4)
 998 .Lload_fpu_regs_done:
 999         ni      __LC_CPU_FLAGS+7,255-_CIF_FPU
1000 .Lload_fpu_regs_exit:
1001         BR_EX   %r14
1002 .Lload_fpu_regs_end:
1003
1004 .L__critical_end:
1005
1006 /*
1007  * Machine check handler routines
1008  */
1009 ENTRY(mcck_int_handler)
1010         STCK    __LC_MCCK_CLOCK
1011         BPOFF
1012         la      %r1,4095                # revalidate r1
1013         spt     __LC_CPU_TIMER_SAVE_AREA-4095(%r1)      # revalidate cpu timer
1014         lmg     %r0,%r15,__LC_GPREGS_SAVE_AREA-4095(%r1)# revalidate gprs
1015         lg      %r10,__LC_LAST_BREAK
1016         lg      %r12,__LC_THREAD_INFO
1017         larl    %r13,cleanup_critical
1018         lmg     %r8,%r9,__LC_MCK_OLD_PSW
1019         TSTMSK  __LC_MCCK_CODE,MCCK_CODE_SYSTEM_DAMAGE
1020         jo      .Lmcck_panic            # yes -> rest of mcck code invalid
1021         lghi    %r14,__LC_CPU_TIMER_SAVE_AREA
1022         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
1023         TSTMSK  __LC_MCCK_CODE,MCCK_CODE_CPU_TIMER_VALID
1024         jo      3f
1025         la      %r14,__LC_SYNC_ENTER_TIMER
1026         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
1027         jl      0f
1028         la      %r14,__LC_ASYNC_ENTER_TIMER
1029 0:      clc     0(8,%r14),__LC_EXIT_TIMER
1030         jl      1f
1031         la      %r14,__LC_EXIT_TIMER
1032 1:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
1033         jl      2f
1034         la      %r14,__LC_LAST_UPDATE_TIMER
1035 2:      spt     0(%r14)
1036         mvc     __LC_MCCK_ENTER_TIMER(8),0(%r14)
1037 3:      TSTMSK  __LC_MCCK_CODE,(MCCK_CODE_PSW_MWP_VALID|MCCK_CODE_PSW_IA_VALID)
1038         jno     .Lmcck_panic            # no -> skip cleanup critical
1039         SWITCH_ASYNC __LC_GPREGS_SAVE_AREA+64,__LC_MCCK_ENTER_TIMER
1040 .Lmcck_skip:
1041         lghi    %r14,__LC_GPREGS_SAVE_AREA+64
1042         stmg    %r0,%r7,__PT_R0(%r11)
1043         # clear user controlled registers to prevent speculative use
1044         xgr     %r0,%r0
1045         xgr     %r1,%r1
1046         xgr     %r2,%r2
1047         xgr     %r3,%r3
1048         xgr     %r4,%r4
1049         xgr     %r5,%r5
1050         xgr     %r6,%r6
1051         xgr     %r7,%r7
1052         xgr     %r10,%r10
1053         mvc     __PT_R8(64,%r11),0(%r14)
1054         stmg    %r8,%r9,__PT_PSW(%r11)
1055         xc      __PT_FLAGS(8,%r11),__PT_FLAGS(%r11)
1056         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
1057         lgr     %r2,%r11                # pass pointer to pt_regs
1058         brasl   %r14,s390_do_machine_check
1059         tm      __PT_PSW+1(%r11),0x01   # returning to user ?
1060         jno     .Lmcck_return
1061         lg      %r1,__LC_KERNEL_STACK   # switch to kernel stack
1062         mvc     STACK_FRAME_OVERHEAD(__PT_SIZE,%r1),0(%r11)
1063         xc      __SF_BACKCHAIN(8,%r1),__SF_BACKCHAIN(%r1)
1064         la      %r11,STACK_FRAME_OVERHEAD(%r1)
1065         lgr     %r15,%r1
1066         ssm     __LC_PGM_NEW_PSW        # turn dat on, keep irqs off
1067         TSTMSK  __LC_CPU_FLAGS,_CIF_MCCK_PENDING
1068         jno     .Lmcck_return
1069         TRACE_IRQS_OFF
1070         brasl   %r14,s390_handle_mcck
1071         TRACE_IRQS_ON
1072 .Lmcck_return:
1073         lg      %r14,__LC_VDSO_PER_CPU
1074         lmg     %r0,%r10,__PT_R0(%r11)
1075         mvc     __LC_RETURN_MCCK_PSW(16),__PT_PSW(%r11) # move return PSW
1076         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
1077         jno     0f
1078         BPEXIT  __TI_flags(%r12),_TIF_ISOLATE_BP
1079         stpt    __LC_EXIT_TIMER
1080         mvc     __VDSO_ECTG_BASE(16,%r14),__LC_EXIT_TIMER
1081 0:      lmg     %r11,%r15,__PT_R11(%r11)
1082         lpswe   __LC_RETURN_MCCK_PSW
1083
1084 .Lmcck_panic:
1085         lg      %r15,__LC_PANIC_STACK
1086         aghi    %r15,-(STACK_FRAME_OVERHEAD + __PT_SIZE)
1087         j       .Lmcck_skip
1088
1089 #
1090 # PSW restart interrupt handler
1091 #
1092 ENTRY(restart_int_handler)
1093         TSTMSK  __LC_MACHINE_FLAGS,MACHINE_FLAG_LPP
1094         jz      0f
1095         .insn   s,0xb2800000,__LC_LPP
1096 0:      stg     %r15,__LC_SAVE_AREA_RESTART
1097         lg      %r15,__LC_RESTART_STACK
1098         aghi    %r15,-__PT_SIZE                 # create pt_regs on stack
1099         xc      0(__PT_SIZE,%r15),0(%r15)
1100         stmg    %r0,%r14,__PT_R0(%r15)
1101         mvc     __PT_R15(8,%r15),__LC_SAVE_AREA_RESTART
1102         mvc     __PT_PSW(16,%r15),__LC_RST_OLD_PSW # store restart old psw
1103         aghi    %r15,-STACK_FRAME_OVERHEAD      # create stack frame on stack
1104         xc      0(STACK_FRAME_OVERHEAD,%r15),0(%r15)
1105         lg      %r1,__LC_RESTART_FN             # load fn, parm & source cpu
1106         lg      %r2,__LC_RESTART_DATA
1107         lg      %r3,__LC_RESTART_SOURCE
1108         ltgr    %r3,%r3                         # test source cpu address
1109         jm      1f                              # negative -> skip source stop
1110 0:      sigp    %r4,%r3,SIGP_SENSE              # sigp sense to source cpu
1111         brc     10,0b                           # wait for status stored
1112 1:      basr    %r14,%r1                        # call function
1113         stap    __SF_EMPTY(%r15)                # store cpu address
1114         llgh    %r3,__SF_EMPTY(%r15)
1115 2:      sigp    %r4,%r3,SIGP_STOP               # sigp stop to current cpu
1116         brc     2,2b
1117 3:      j       3b
1118
1119         .section .kprobes.text, "ax"
1120
1121 #ifdef CONFIG_CHECK_STACK
1122 /*
1123  * The synchronous or the asynchronous stack overflowed. We are dead.
1124  * No need to properly save the registers, we are going to panic anyway.
1125  * Setup a pt_regs so that show_trace can provide a good call trace.
1126  */
1127 stack_overflow:
1128         lg      %r15,__LC_PANIC_STACK   # change to panic stack
1129         la      %r11,STACK_FRAME_OVERHEAD(%r15)
1130         stmg    %r0,%r7,__PT_R0(%r11)
1131         stmg    %r8,%r9,__PT_PSW(%r11)
1132         mvc     __PT_R8(64,%r11),0(%r14)
1133         stg     %r10,__PT_ORIG_GPR2(%r11) # store last break to orig_gpr2
1134         xc      __SF_BACKCHAIN(8,%r15),__SF_BACKCHAIN(%r15)
1135         lgr     %r2,%r11                # pass pointer to pt_regs
1136         jg      kernel_stack_overflow
1137 #endif
1138
1139 cleanup_critical:
1140 #if IS_ENABLED(CONFIG_KVM)
1141         clg     %r9,BASED(.Lcleanup_table_sie)  # .Lsie_gmap
1142         jl      0f
1143         clg     %r9,BASED(.Lcleanup_table_sie+8)# .Lsie_done
1144         jl      .Lcleanup_sie
1145 #endif
1146         clg     %r9,BASED(.Lcleanup_table)      # system_call
1147         jl      0f
1148         clg     %r9,BASED(.Lcleanup_table+8)    # .Lsysc_do_svc
1149         jl      .Lcleanup_system_call
1150         clg     %r9,BASED(.Lcleanup_table+16)   # .Lsysc_tif
1151         jl      0f
1152         clg     %r9,BASED(.Lcleanup_table+24)   # .Lsysc_restore
1153         jl      .Lcleanup_sysc_tif
1154         clg     %r9,BASED(.Lcleanup_table+32)   # .Lsysc_done
1155         jl      .Lcleanup_sysc_restore
1156         clg     %r9,BASED(.Lcleanup_table+40)   # .Lio_tif
1157         jl      0f
1158         clg     %r9,BASED(.Lcleanup_table+48)   # .Lio_restore
1159         jl      .Lcleanup_io_tif
1160         clg     %r9,BASED(.Lcleanup_table+56)   # .Lio_done
1161         jl      .Lcleanup_io_restore
1162         clg     %r9,BASED(.Lcleanup_table+64)   # psw_idle
1163         jl      0f
1164         clg     %r9,BASED(.Lcleanup_table+72)   # .Lpsw_idle_end
1165         jl      .Lcleanup_idle
1166         clg     %r9,BASED(.Lcleanup_table+80)   # save_fpu_regs
1167         jl      0f
1168         clg     %r9,BASED(.Lcleanup_table+88)   # .Lsave_fpu_regs_end
1169         jl      .Lcleanup_save_fpu_regs
1170         clg     %r9,BASED(.Lcleanup_table+96)   # load_fpu_regs
1171         jl      0f
1172         clg     %r9,BASED(.Lcleanup_table+104)  # .Lload_fpu_regs_end
1173         jl      .Lcleanup_load_fpu_regs
1174 0:      BR_EX   %r14,%r11
1175
1176         .align  8
1177 .Lcleanup_table:
1178         .quad   system_call
1179         .quad   .Lsysc_do_svc
1180         .quad   .Lsysc_tif
1181         .quad   .Lsysc_restore
1182         .quad   .Lsysc_done
1183         .quad   .Lio_tif
1184         .quad   .Lio_restore
1185         .quad   .Lio_done
1186         .quad   psw_idle
1187         .quad   .Lpsw_idle_end
1188         .quad   save_fpu_regs
1189         .quad   .Lsave_fpu_regs_end
1190         .quad   load_fpu_regs
1191         .quad   .Lload_fpu_regs_end
1192
1193 #if IS_ENABLED(CONFIG_KVM)
1194 .Lcleanup_table_sie:
1195         .quad   .Lsie_gmap
1196         .quad   .Lsie_done
1197
1198 .Lcleanup_sie:
1199         BPENTER __SF_EMPTY+24(%r15),(_TIF_ISOLATE_BP|_TIF_ISOLATE_BP_GUEST)
1200         lg      %r9,__SF_EMPTY(%r15)            # get control block pointer
1201         ni      __SIE_PROG0C+3(%r9),0xfe        # no longer in SIE
1202         lctlg   %c1,%c1,__LC_USER_ASCE          # load primary asce
1203         larl    %r9,sie_exit                    # skip forward to sie_exit
1204         BR_EX   %r14,%r11
1205 #endif
1206
1207 .Lcleanup_system_call:
1208         # check if stpt has been executed
1209         clg     %r9,BASED(.Lcleanup_system_call_insn)
1210         jh      0f
1211         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
1212         cghi    %r11,__LC_SAVE_AREA_ASYNC
1213         je      0f
1214         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_MCCK_ENTER_TIMER
1215 0:      # check if stmg has been executed
1216         clg     %r9,BASED(.Lcleanup_system_call_insn+8)
1217         jh      0f
1218         mvc     __LC_SAVE_AREA_SYNC(64),0(%r11)
1219 0:      # check if base register setup + TIF bit load has been done
1220         clg     %r9,BASED(.Lcleanup_system_call_insn+16)
1221         jhe     0f
1222         # set up saved registers r10 and r12
1223         stg     %r10,16(%r11)           # r10 last break
1224         stg     %r12,32(%r11)           # r12 thread-info pointer
1225 0:      # check if the user time update has been done
1226         clg     %r9,BASED(.Lcleanup_system_call_insn+24)
1227         jh      0f
1228         lg      %r15,__LC_EXIT_TIMER
1229         slg     %r15,__LC_SYNC_ENTER_TIMER
1230         alg     %r15,__LC_USER_TIMER
1231         stg     %r15,__LC_USER_TIMER
1232 0:      # check if the system time update has been done
1233         clg     %r9,BASED(.Lcleanup_system_call_insn+32)
1234         jh      0f
1235         lg      %r15,__LC_LAST_UPDATE_TIMER
1236         slg     %r15,__LC_EXIT_TIMER
1237         alg     %r15,__LC_SYSTEM_TIMER
1238         stg     %r15,__LC_SYSTEM_TIMER
1239 0:      # update accounting time stamp
1240         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
1241         # do LAST_BREAK
1242         lg      %r9,16(%r11)
1243         srag    %r9,%r9,23
1244         jz      0f
1245         mvc     __TI_last_break(8,%r12),16(%r11)
1246 0:      BPENTER __TI_flags(%r12),_TIF_ISOLATE_BP
1247         # set up saved register r11
1248         lg      %r15,__LC_KERNEL_STACK
1249         la      %r9,STACK_FRAME_OVERHEAD(%r15)
1250         stg     %r9,24(%r11)            # r11 pt_regs pointer
1251         # fill pt_regs
1252         mvc     __PT_R8(64,%r9),__LC_SAVE_AREA_SYNC
1253         stmg    %r0,%r7,__PT_R0(%r9)
1254         mvc     __PT_PSW(16,%r9),__LC_SVC_OLD_PSW
1255         mvc     __PT_INT_CODE(4,%r9),__LC_SVC_ILC
1256         xc      __PT_FLAGS(8,%r9),__PT_FLAGS(%r9)
1257         mvi     __PT_FLAGS+7(%r9),_PIF_SYSCALL
1258         # setup saved register r15
1259         stg     %r15,56(%r11)           # r15 stack pointer
1260         # set new psw address and exit
1261         larl    %r9,.Lsysc_do_svc
1262         BR_EX   %r14,%r11
1263 .Lcleanup_system_call_insn:
1264         .quad   system_call
1265         .quad   .Lsysc_stmg
1266         .quad   .Lsysc_per
1267         .quad   .Lsysc_vtime+36
1268         .quad   .Lsysc_vtime+42
1269
1270 .Lcleanup_sysc_tif:
1271         larl    %r9,.Lsysc_tif
1272         BR_EX   %r14,%r11
1273
1274 .Lcleanup_sysc_restore:
1275         # check if stpt has been executed
1276         clg     %r9,BASED(.Lcleanup_sysc_restore_insn)
1277         jh      0f
1278         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1279         cghi    %r11,__LC_SAVE_AREA_ASYNC
1280         je      0f
1281         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
1282 0:      clg     %r9,BASED(.Lcleanup_sysc_restore_insn+8)
1283         je      1f
1284         lg      %r9,24(%r11)            # get saved pointer to pt_regs
1285         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
1286         mvc     0(64,%r11),__PT_R8(%r9)
1287         lmg     %r0,%r7,__PT_R0(%r9)
1288 1:      lmg     %r8,%r9,__LC_RETURN_PSW
1289         BR_EX   %r14,%r11
1290 .Lcleanup_sysc_restore_insn:
1291         .quad   .Lsysc_exit_timer
1292         .quad   .Lsysc_done - 4
1293
1294 .Lcleanup_io_tif:
1295         larl    %r9,.Lio_tif
1296         BR_EX   %r14,%r11
1297
1298 .Lcleanup_io_restore:
1299         # check if stpt has been executed
1300         clg     %r9,BASED(.Lcleanup_io_restore_insn)
1301         jh      0f
1302         mvc     __LC_EXIT_TIMER(8),__LC_MCCK_ENTER_TIMER
1303 0:      clg     %r9,BASED(.Lcleanup_io_restore_insn+8)
1304         je      1f
1305         lg      %r9,24(%r11)            # get saved r11 pointer to pt_regs
1306         mvc     __LC_RETURN_PSW(16),__PT_PSW(%r9)
1307         mvc     0(64,%r11),__PT_R8(%r9)
1308         lmg     %r0,%r7,__PT_R0(%r9)
1309 1:      lmg     %r8,%r9,__LC_RETURN_PSW
1310         BR_EX   %r14,%r11
1311 .Lcleanup_io_restore_insn:
1312         .quad   .Lio_exit_timer
1313         .quad   .Lio_done - 4
1314
1315 .Lcleanup_idle:
1316         # copy interrupt clock & cpu timer
1317         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_INT_CLOCK
1318         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_ASYNC_ENTER_TIMER
1319         cghi    %r11,__LC_SAVE_AREA_ASYNC
1320         je      0f
1321         mvc     __CLOCK_IDLE_EXIT(8,%r2),__LC_MCCK_CLOCK
1322         mvc     __TIMER_IDLE_EXIT(8,%r2),__LC_MCCK_ENTER_TIMER
1323 0:      # check if stck & stpt have been executed
1324         clg     %r9,BASED(.Lcleanup_idle_insn)
1325         jhe     1f
1326         mvc     __CLOCK_IDLE_ENTER(8,%r2),__CLOCK_IDLE_EXIT(%r2)
1327         mvc     __TIMER_IDLE_ENTER(8,%r2),__TIMER_IDLE_EXIT(%r2)
1328 1:      # calculate idle cycles
1329 #ifdef CONFIG_SMP
1330         clg     %r9,BASED(.Lcleanup_idle_insn)
1331         jl      3f
1332         larl    %r1,smp_cpu_mtid
1333         llgf    %r1,0(%r1)
1334         ltgr    %r1,%r1
1335         jz      3f
1336         .insn   rsy,0xeb0000000017,%r1,5,__SF_EMPTY+80(%r15)
1337         larl    %r3,mt_cycles
1338         ag      %r3,__LC_PERCPU_OFFSET
1339         la      %r4,__SF_EMPTY+16(%r15)
1340 2:      lg      %r0,0(%r3)
1341         slg     %r0,0(%r4)
1342         alg     %r0,64(%r4)
1343         stg     %r0,0(%r3)
1344         la      %r3,8(%r3)
1345         la      %r4,8(%r4)
1346         brct    %r1,2b
1347 #endif
1348 3:      # account system time going idle
1349         lg      %r9,__LC_STEAL_TIMER
1350         alg     %r9,__CLOCK_IDLE_ENTER(%r2)
1351         slg     %r9,__LC_LAST_UPDATE_CLOCK
1352         stg     %r9,__LC_STEAL_TIMER
1353         mvc     __LC_LAST_UPDATE_CLOCK(8),__CLOCK_IDLE_EXIT(%r2)
1354         lg      %r9,__LC_SYSTEM_TIMER
1355         alg     %r9,__LC_LAST_UPDATE_TIMER
1356         slg     %r9,__TIMER_IDLE_ENTER(%r2)
1357         stg     %r9,__LC_SYSTEM_TIMER
1358         mvc     __LC_LAST_UPDATE_TIMER(8),__TIMER_IDLE_EXIT(%r2)
1359         # prepare return psw
1360         nihh    %r8,0xfcfd              # clear irq & wait state bits
1361         lg      %r9,48(%r11)            # return from psw_idle
1362         BR_EX   %r14,%r11
1363 .Lcleanup_idle_insn:
1364         .quad   .Lpsw_idle_lpsw
1365
1366 .Lcleanup_save_fpu_regs:
1367         larl    %r9,save_fpu_regs
1368         BR_EX   %r14,%r11
1369
1370 .Lcleanup_load_fpu_regs:
1371         larl    %r9,load_fpu_regs
1372         BR_EX   %r14,%r11
1373
1374 /*
1375  * Integer constants
1376  */
1377         .align  8
1378 .Lcritical_start:
1379         .quad   .L__critical_start
1380 .Lcritical_length:
1381         .quad   .L__critical_end - .L__critical_start
1382 #if IS_ENABLED(CONFIG_KVM)
1383 .Lsie_critical_start:
1384         .quad   .Lsie_gmap
1385 .Lsie_critical_length:
1386         .quad   .Lsie_done - .Lsie_gmap
1387 #endif
1388         .section .rodata, "a"
1389 #define SYSCALL(esame,emu)      .long esame
1390         .globl  sys_call_table
1391 sys_call_table:
1392 #include "syscalls.S"
1393 #undef SYSCALL
1394
1395 #ifdef CONFIG_COMPAT
1396
1397 #define SYSCALL(esame,emu)      .long emu
1398         .globl  sys_call_table_emu
1399 sys_call_table_emu:
1400 #include "syscalls.S"
1401 #undef SYSCALL
1402 #endif