arch/x86/boot/compressed/head_32.S

   1 /*
   2  *  linux/boot/head.S
   3  *
   4  *  Copyright (C) 1991, 1992, 1993  Linus Torvalds
   5  */
   6
   7 /*
   8  *  head.S contains the 32-bit startup code.
   9  *
  10  * NOTE!!! Startup happens at absolute address 0x00001000, which is also where
  11  * the page directory will exist. The startup code will be overwritten by
  12  * the page directory. [According to comments etc elsewhere on a compressed
  13  * kernel it will end up at 0x1000 + 1Mb I hope so as I assume this. - AC]
  14  *
  15  * Page 0 is deliberately kept safe, since System Management Mode code in
  16  * laptops may need to access the BIOS data stored there.  This is also
  17  * useful for future device drivers that either access the BIOS via VM86
  18  * mode.
  19  */
  20
  21 /*
  22  * High loaded stuff by Hans Lermen & Werner Almesberger, Feb. 1996
  23  */
  24         .text
  25
  26 #include <linux/init.h>
  27 #include <linux/linkage.h>
  28 #include <asm/segment.h>
  29 #include <asm/page_types.h>
  30 #include <asm/boot.h>
  31 #include <asm/asm-offsets.h>
  32 #include <asm/bootparam.h>
  33
  34 /*
  35  * The 32-bit x86 assembler in binutils 2.26 will generate R_386_GOT32X
  36  * relocation to get the symbol address in PIC.  When the compressed x86
  37  * kernel isn't built as PIC, the linker optimizes R_386_GOT32X
  38  * relocations to their fixed symbol addresses.  However, when the
  39  * compressed x86 kernel is loaded at a different address, it leads
  40  * to the following load failure:
  41  *
  42  *   Failed to allocate space for phdrs
  43  *
  44  * during the decompression stage.
  45  *
  46  * If the compressed x86 kernel is relocatable at run-time, it should be
  47  * compiled with -fPIE, instead of -fPIC, if possible and should be built as
  48  * Position Independent Executable (PIE) so that linker won't optimize
  49  * R_386_GOT32X relocation to its fixed symbol address.  Older
  50  * linkers generate R_386_32 relocations against locally defined symbols,
  51  * _bss, _ebss, _got, _egot and _end, in PIE.  It isn't wrong, just less
  52  * optimal than R_386_RELATIVE.  But the x86 kernel fails to properly handle
  53  * R_386_32 relocations when relocating the kernel.  To generate
  54  * R_386_RELATIVE relocations, we mark _bss, _ebss, _got, _egot and _end as
  55  * hidden:
  56  */
  57         .hidden _bss
  58         .hidden _ebss
  59         .hidden _got
  60         .hidden _egot
  61         .hidden _end
  62
  63         __HEAD
  64 ENTRY(startup_32)
  65 #ifdef CONFIG_EFI_STUB
  66         jmp     preferred_addr
  67
  68         /*
  69          * We don't need the return address, so set up the stack so
  70          * efi_main() can find its arguments.
  71          */
  72 ENTRY(efi_pe_entry)
  73         add     $0x4, %esp
  74
  75         call    1f
  76 1:      popl    %esi
  77         subl    $1b, %esi
  78
  79         popl    %ecx
  80         movl    %ecx, efi32_config(%esi)        /* Handle */
  81         popl    %ecx
  82         movl    %ecx, efi32_config+8(%esi)      /* EFI System table pointer */
  83
  84         /* Relocate efi_config->call() */
  85         leal    efi32_config(%esi), %eax
  86         add     %esi, 32(%eax)
  87         pushl   %eax
  88
  89         call    make_boot_params
  90         cmpl    $0, %eax
  91         je      fail
  92         movl    %esi, BP_code32_start(%eax)
  93         popl    %ecx
  94         pushl   %eax
  95         pushl   %ecx
  96         jmp     2f              /* Skip efi_config initialization */
  97
  98 ENTRY(efi32_stub_entry)
  99         add     $0x4, %esp
 100         popl    %ecx
 101         popl    %edx
 102
 103         call    1f
 104 1:      popl    %esi
 105         subl    $1b, %esi
 106
 107         movl    %ecx, efi32_config(%esi)        /* Handle */
 108         movl    %edx, efi32_config+8(%esi)      /* EFI System table pointer */
 109
 110         /* Relocate efi_config->call() */
 111         leal    efi32_config(%esi), %eax
 112         add     %esi, 32(%eax)
 113         pushl   %eax
 114 2:
 115         call    efi_main
 116         cmpl    $0, %eax
 117         movl    %eax, %esi
 118         jne     2f
 119 fail:
 120         /* EFI init failed, so hang. */
 121         hlt
 122         jmp     fail
 123 2:
 124         movl    BP_code32_start(%esi), %eax
 125         leal    preferred_addr(%eax), %eax
 126         jmp     *%eax
 127
 128 preferred_addr:
 129 #endif
 130         cld
 131         /*
 132          * Test KEEP_SEGMENTS flag to see if the bootloader is asking
 133          * us to not reload segments
 134          */
 135         testb   $KEEP_SEGMENTS, BP_loadflags(%esi)
 136         jnz     1f
 137
 138         cli
 139         movl    $__BOOT_DS, %eax
 140         movl    %eax, %ds
 141         movl    %eax, %es
 142         movl    %eax, %fs
 143         movl    %eax, %gs
 144         movl    %eax, %ss
 145 1:
 146
 147 /*
 148  * Calculate the delta between where we were compiled to run
 149  * at and where we were actually loaded at.  This can only be done
 150  * with a short local call on x86.  Nothing  else will tell us what
 151  * address we are running at.  The reserved chunk of the real-mode
 152  * data at 0x1e4 (defined as a scratch field) are used as the stack
 153  * for this calculation. Only 4 bytes are needed.
 154  */
 155         leal    (BP_scratch+4)(%esi), %esp
 156         call    1f
 157 1:      popl    %ebp
 158         subl    $1b, %ebp
 159
 160 /*
 161  * %ebp contains the address we are loaded at by the boot loader and %ebx
 162  * contains the address where we should move the kernel image temporarily
 163  * for safe in-place decompression.
 164  */
 165
 166 #ifdef CONFIG_RELOCATABLE
 167         movl    %ebp, %ebx
 168         movl    BP_kernel_alignment(%esi), %eax
 169         decl    %eax
 170         addl    %eax, %ebx
 171         notl    %eax
 172         andl    %eax, %ebx
 173         cmpl    $LOAD_PHYSICAL_ADDR, %ebx
 174         jae     1f
 175 #endif
 176         movl    $LOAD_PHYSICAL_ADDR, %ebx
 177 1:
 178
 179         /* Target address to relocate to for decompression */
 180         movl    BP_init_size(%esi), %eax
 181         subl    $_end, %eax
 182         addl    %eax, %ebx
 183
 184         /* Set up the stack */
 185         leal    boot_stack_end(%ebx), %esp
 186
 187         /* Zero EFLAGS */
 188         pushl   $0
 189         popfl
 190
 191 /*
 192  * Copy the compressed kernel to the end of our buffer
 193  * where decompression in place becomes safe.
 194  */
 195         pushl   %esi
 196         leal    (_bss-4)(%ebp), %esi
 197         leal    (_bss-4)(%ebx), %edi
 198         movl    $(_bss - startup_32), %ecx
 199         shrl    $2, %ecx
 200         std
 201         rep     movsl
 202         cld
 203         popl    %esi
 204
 205 /*
 206  * Jump to the relocated address.
 207  */
 208         leal    relocated(%ebx), %eax
 209         jmp     *%eax
 210 ENDPROC(startup_32)
 211
 212         .text
 213 relocated:
 214
 215 /*
 216  * Clear BSS (stack is currently empty)
 217  */
 218         xorl    %eax, %eax
 219         leal    _bss(%ebx), %edi
 220         leal    _ebss(%ebx), %ecx
 221         subl    %edi, %ecx
 222         shrl    $2, %ecx
 223         rep     stosl
 224
 225 /*
 226  * Adjust our own GOT
 227  */
 228         leal    _got(%ebx), %edx
 229         leal    _egot(%ebx), %ecx
 230 1:
 231         cmpl    %ecx, %edx
 232         jae     2f
 233         addl    %ebx, (%edx)
 234         addl    $4, %edx
 235         jmp     1b
 236 2:
 237
 238 /*
 239  * Do the extraction, and jump to the new kernel..
 240  */
 241                                 /* push arguments for extract_kernel: */
 242         pushl   $z_output_len   /* decompressed length, end of relocs */
 243
 244         movl    BP_init_size(%esi), %eax
 245         subl    $_end, %eax
 246         movl    %ebx, %ebp
 247         subl    %eax, %ebp
 248         pushl   %ebp            /* output address */
 249
 250         pushl   $z_input_len    /* input_len */
 251         leal    input_data(%ebx), %eax
 252         pushl   %eax            /* input_data */
 253         leal    boot_heap(%ebx), %eax
 254         pushl   %eax            /* heap area */
 255         pushl   %esi            /* real mode pointer */
 256         call    extract_kernel  /* returns kernel location in %eax */
 257         addl    $24, %esp
 258
 259 /*
 260  * Jump to the extracted kernel.
 261  */
 262         xorl    %ebx, %ebx
 263         jmp     *%eax
 264
 265 #ifdef CONFIG_EFI_STUB
 266         .data
 267 efi32_config:
 268         .fill 4,8,0
 269         .long efi_call_phys
 270         .long 0
 271         .byte 0
 272 #endif
 273
 274 /*
 275  * Stack and heap for uncompression
 276  */
 277         .bss
 278         .balign 4
 279 boot_heap:
 280         .fill BOOT_HEAP_SIZE, 1, 0
 281 boot_stack:
 282         .fill BOOT_STACK_SIZE, 1, 0
 283 boot_stack_end: