arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 #else
  38 OUTPUT_ARCH(i386:x86-64)
  39 ENTRY(phys_startup_64)
  40 #endif
  41
  42 jiffies = jiffies_64;
  43
  44 #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45 /*
  46  * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47  * we retain large page mappings for boundaries spanning kernel text, rodata
  48  * and data sections.
  49  *
  50  * However, kernel identity mappings will have different RWX permissions
  51  * to the pages mapping to text and to the pages padding (which are freed) the
  52  * text section. Hence kernel identity mappings will be broken to smaller
  53  * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54  * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55  * as well as retain 2MB large page mappings for kernel text.
  56  */
  57 #define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59 #define X64_ALIGN_DEBUG_RODATA_END                              \
  60                 . = ALIGN(HPAGE_SIZE);                          \
  61                 __end_rodata_hpage_align = .;
  62
  63 #else
  64
  65 #define X64_ALIGN_DEBUG_RODATA_BEGIN
  66 #define X64_ALIGN_DEBUG_RODATA_END
  67
  68 #endif
  69
  70 PHDRS {
  71         text PT_LOAD FLAGS(5);          /* R_E */
  72         data PT_LOAD FLAGS(6);          /* RW_ */
  73 #ifdef CONFIG_X86_64
  74 #ifdef CONFIG_SMP
  75         percpu PT_LOAD FLAGS(6);        /* RW_ */
  76 #endif
  77         init PT_LOAD FLAGS(7);          /* RWE */
  78 #endif
  79         note PT_NOTE FLAGS(0);          /* ___ */
  80 }
  81
  82 SECTIONS
  83 {
  84 #ifdef CONFIG_X86_32
  85         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  86         phys_startup_32 = startup_32 - LOAD_OFFSET;
  87 #else
  88         . = __START_KERNEL;
  89         phys_startup_64 = startup_64 - LOAD_OFFSET;
  90 #endif
  91
  92         /* Text and read-only data */
  93         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  94                 _text = .;
  95                 /* bootstrapping code */
  96                 HEAD_TEXT
  97                 . = ALIGN(8);
  98                 _stext = .;
  99                 TEXT_TEXT
 100                 SCHED_TEXT
 101                 LOCK_TEXT
 102                 KPROBES_TEXT
 103                 ENTRY_TEXT
 104                 IRQENTRY_TEXT
 105                 *(.fixup)
 106                 *(.gnu.warning)
 107
 108 #ifdef CONFIG_RETPOLINE
 109                 __indirect_thunk_start = .;
 110                 *(.text.__x86.indirect_thunk)
 111                 __indirect_thunk_end = .;
 112 #endif
 113
 114                 /* End of text section */
 115                 _etext = .;
 116         } :text = 0x9090
 117
 118         NOTES :text :note
 119
 120         EXCEPTION_TABLE(16) :text = 0x9090
 121
 122 #if defined(CONFIG_DEBUG_RODATA)
 123         /* .text should occupy whole number of pages */
 124         . = ALIGN(PAGE_SIZE);
 125 #endif
 126         X64_ALIGN_DEBUG_RODATA_BEGIN
 127         RO_DATA(PAGE_SIZE)
 128         X64_ALIGN_DEBUG_RODATA_END
 129
 130         /* Data */
 131         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 132                 /* Start of data section */
 133                 _sdata = .;
 134
 135                 /* init_task */
 136                 INIT_TASK_DATA(THREAD_SIZE)
 137
 138 #ifdef CONFIG_X86_32
 139                 /* 32 bit has nosave before _edata */
 140                 NOSAVE_DATA
 141 #endif
 142
 143                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 144
 145                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 146
 147                 DATA_DATA
 148                 CONSTRUCTORS
 149
 150                 /* rarely changed data like cpu maps */
 151                 READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 152
 153                 /* End of data section */
 154                 _edata = .;
 155         } :data
 156
 157
 158         . = ALIGN(PAGE_SIZE);
 159         __vvar_page = .;
 160
 161         .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 162                 /* work around gold bug 13023 */
 163                 __vvar_beginning_hack = .;
 164
 165                 /* Place all vvars at the offsets in asm/vvar.h. */
 166 #define EMIT_VVAR(name, offset)                         \
 167                 . = __vvar_beginning_hack + offset;     \
 168                 *(.vvar_ ## name)
 169 #define __VVAR_KERNEL_LDS
 170 #include <asm/vvar.h>
 171 #undef __VVAR_KERNEL_LDS
 172 #undef EMIT_VVAR
 173
 174                 /*
 175                  * Pad the rest of the page with zeros.  Otherwise the loader
 176                  * can leave garbage here.
 177                  */
 178                 . = __vvar_beginning_hack + PAGE_SIZE;
 179         } :data
 180
 181        . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 182
 183         /* Init code and data - will be freed after init */
 184         . = ALIGN(PAGE_SIZE);
 185         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 186                 __init_begin = .; /* paired with __init_end */
 187         }
 188
 189 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 190         /*
 191          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 192          * output PHDR, so the next output section - .init.text - should
 193          * start another segment - init.
 194          */
 195         PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 196         ASSERT(SIZEOF(.data..percpu) < CONFIG_PHYSICAL_START,
 197                "per-CPU data too large - increase CONFIG_PHYSICAL_START")
 198 #endif
 199
 200         INIT_TEXT_SECTION(PAGE_SIZE)
 201 #ifdef CONFIG_X86_64
 202         :init
 203 #endif
 204
 205         /*
 206          * Section for code used exclusively before alternatives are run. All
 207          * references to such code must be patched out by alternatives, normally
 208          * by using X86_FEATURE_ALWAYS CPU feature bit.
 209          *
 210          * See static_cpu_has() for an example.
 211          */
 212         .altinstr_aux : AT(ADDR(.altinstr_aux) - LOAD_OFFSET) {
 213                 *(.altinstr_aux)
 214         }
 215
 216         INIT_DATA_SECTION(16)
 217
 218         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 219                 __x86_cpu_dev_start = .;
 220                 *(.x86_cpu_dev.init)
 221                 __x86_cpu_dev_end = .;
 222         }
 223
 224 #ifdef CONFIG_X86_INTEL_MID
 225         .x86_intel_mid_dev.init : AT(ADDR(.x86_intel_mid_dev.init) - \
 226                                                                 LOAD_OFFSET) {
 227                 __x86_intel_mid_dev_start = .;
 228                 *(.x86_intel_mid_dev.init)
 229                 __x86_intel_mid_dev_end = .;
 230         }
 231 #endif
 232
 233         /*
 234          * start address and size of operations which during runtime
 235          * can be patched with virtualization friendly instructions or
 236          * baremetal native ones. Think page table operations.
 237          * Details in paravirt_types.h
 238          */
 239         . = ALIGN(8);
 240         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 241                 __parainstructions = .;
 242                 *(.parainstructions)
 243                 __parainstructions_end = .;
 244         }
 245
 246         /*
 247          * struct alt_inst entries. From the header (alternative.h):
 248          * "Alternative instructions for different CPU types or capabilities"
 249          * Think locking instructions on spinlocks.
 250          */
 251         . = ALIGN(8);
 252         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 253                 __alt_instructions = .;
 254                 *(.altinstructions)
 255                 __alt_instructions_end = .;
 256         }
 257
 258         /*
 259          * And here are the replacement instructions. The linker sticks
 260          * them as binary blobs. The .altinstructions has enough data to
 261          * get the address and the length of them to patch the kernel safely.
 262          */
 263         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 264                 *(.altinstr_replacement)
 265         }
 266
 267         /*
 268          * struct iommu_table_entry entries are injected in this section.
 269          * It is an array of IOMMUs which during run time gets sorted depending
 270          * on its dependency order. After rootfs_initcall is complete
 271          * this section can be safely removed.
 272          */
 273         .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 274                 __iommu_table = .;
 275                 *(.iommu_table)
 276                 __iommu_table_end = .;
 277         }
 278
 279         . = ALIGN(8);
 280         .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 281                 __apicdrivers = .;
 282                 *(.apicdrivers);
 283                 __apicdrivers_end = .;
 284         }
 285
 286         . = ALIGN(8);
 287         /*
 288          * .exit.text is discard at runtime, not link time, to deal with
 289          *  references from .altinstructions and .eh_frame
 290          */
 291         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 292                 EXIT_TEXT
 293         }
 294
 295         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 296                 EXIT_DATA
 297         }
 298
 299 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 300         PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 301 #endif
 302
 303         . = ALIGN(PAGE_SIZE);
 304
 305         /* freed after init ends here */
 306         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 307                 __init_end = .;
 308         }
 309
 310         /*
 311          * smp_locks might be freed after init
 312          * start/end must be page aligned
 313          */
 314         . = ALIGN(PAGE_SIZE);
 315         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 316                 __smp_locks = .;
 317                 *(.smp_locks)
 318                 . = ALIGN(PAGE_SIZE);
 319                 __smp_locks_end = .;
 320         }
 321
 322 #ifdef CONFIG_X86_64
 323         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 324                 NOSAVE_DATA
 325         }
 326 #endif
 327
 328         /* BSS */
 329         . = ALIGN(PAGE_SIZE);
 330         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 331                 __bss_start = .;
 332                 *(.bss..page_aligned)
 333                 *(.bss)
 334                 . = ALIGN(PAGE_SIZE);
 335                 __bss_stop = .;
 336         }
 337
 338         . = ALIGN(PAGE_SIZE);
 339         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 340                 __brk_base = .;
 341                 . += 64 * 1024;         /* 64k alignment slop space */
 342                 *(.brk_reservation)     /* areas brk users have reserved */
 343                 __brk_limit = .;
 344         }
 345
 346         _end = .;
 347
 348         STABS_DEBUG
 349         DWARF_DEBUG
 350
 351         /* Sections to be discarded */
 352         DISCARDS
 353         /DISCARD/ : { *(.eh_frame) }
 354 }
 355
 356
 357 #ifdef CONFIG_X86_32
 358 /*
 359  * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 360  */
 361 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 362            "kernel image bigger than KERNEL_IMAGE_SIZE");
 363 #else
 364 /*
 365  * Per-cpu symbols which need to be offset from __per_cpu_load
 366  * for the boot processor.
 367  */
 368 #define INIT_PER_CPU(x) init_per_cpu__##x = ABSOLUTE(x) + __per_cpu_load
 369 INIT_PER_CPU(gdt_page);
 370 INIT_PER_CPU(irq_stack_union);
 371
 372 /*
 373  * Build-time check on the image size:
 374  */
 375 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 376            "kernel image bigger than KERNEL_IMAGE_SIZE");
 377
 378 #ifdef CONFIG_SMP
 379 . = ASSERT((irq_stack_union == 0),
 380            "irq_stack_union is not at start of per-cpu area");
 381 #endif
 382
 383 #endif /* CONFIG_X86_32 */
 384
 385 #ifdef CONFIG_KEXEC_CORE
 386 #include <asm/kexec.h>
 387
 388 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 389            "kexec control code size is too big");
 390 #endif
 391