arch/x86/lib/checksum_32.S

   1 /*
   2  * INET         An implementation of the TCP/IP protocol suite for the LINUX
   3  *              operating system.  INET is implemented using the  BSD Socket
   4  *              interface as the means of communication with the user level.
   5  *
   6  *              IP/TCP/UDP checksumming routines
   7  *
   8  * Authors:     Jorge Cwik, <jorge@laser.satlink.net>
   9  *              Arnt Gulbrandsen, <agulbra@nvg.unit.no>
  10  *              Tom May, <ftom@netcom.com>
  11  *              Pentium Pro/II routines:
  12  *              Alexander Kjeldaas <astor@guardian.no>
  13  *              Finn Arne Gangstad <finnag@guardian.no>
  14  *              Lots of code moved from tcp.c and ip.c; see those files
  15  *              for more names.
  16  *
  17  * Changes:     Ingo Molnar, converted csum_partial_copy() to 2.1 exception
  18  *                           handling.
  19  *              Andi Kleen,  add zeroing on error
  20  *                   converted to pure assembler
  21  *
  22  *              This program is free software; you can redistribute it and/or
  23  *              modify it under the terms of the GNU General Public License
  24  *              as published by the Free Software Foundation; either version
  25  *              2 of the License, or (at your option) any later version.
  26  */
  27
  28 #include <linux/linkage.h>
  29 #include <asm/errno.h>
  30 #include <asm/asm.h>
  31 #include <asm/nospec-branch.h>
  32
  33 /*
  34  * computes a partial checksum, e.g. for TCP/UDP fragments
  35  */
  36
  37 /*
  38 unsigned int csum_partial(const unsigned char * buff, int len, unsigned int sum)
  39  */
  40
  41 .text
  42
  43 #ifndef CONFIG_X86_USE_PPRO_CHECKSUM
  44
  45           /*
  46            * Experiments with Ethernet and SLIP connections show that buff
  47            * is aligned on either a 2-byte or 4-byte boundary.  We get at
  48            * least a twofold speedup on 486 and Pentium if it is 4-byte aligned.
  49            * Fortunately, it is easy to convert 2-byte alignment to 4-byte
  50            * alignment for the unrolled loop.
  51            */
  52 ENTRY(csum_partial)
  53         pushl %esi
  54         pushl %ebx
  55         movl 20(%esp),%eax      # Function arg: unsigned int sum
  56         movl 16(%esp),%ecx      # Function arg: int len
  57         movl 12(%esp),%esi      # Function arg: unsigned char *buff
  58         testl $3, %esi          # Check alignment.
  59         jz 2f                   # Jump if alignment is ok.
  60         testl $1, %esi          # Check alignment.
  61         jz 10f                  # Jump if alignment is boundary of 2 bytes.
  62
  63         # buf is odd
  64         dec %ecx
  65         jl 8f
  66         movzbl (%esi), %ebx
  67         adcl %ebx, %eax
  68         roll $8, %eax
  69         inc %esi
  70         testl $2, %esi
  71         jz 2f
  72 10:
  73         subl $2, %ecx           # Alignment uses up two bytes.
  74         jae 1f                  # Jump if we had at least two bytes.
  75         addl $2, %ecx           # ecx was < 2.  Deal with it.
  76         jmp 4f
  77 1:      movw (%esi), %bx
  78         addl $2, %esi
  79         addw %bx, %ax
  80         adcl $0, %eax
  81 2:
  82         movl %ecx, %edx
  83         shrl $5, %ecx
  84         jz 2f
  85         testl %esi, %esi
  86 1:      movl (%esi), %ebx
  87         adcl %ebx, %eax
  88         movl 4(%esi), %ebx
  89         adcl %ebx, %eax
  90         movl 8(%esi), %ebx
  91         adcl %ebx, %eax
  92         movl 12(%esi), %ebx
  93         adcl %ebx, %eax
  94         movl 16(%esi), %ebx
  95         adcl %ebx, %eax
  96         movl 20(%esi), %ebx
  97         adcl %ebx, %eax
  98         movl 24(%esi), %ebx
  99         adcl %ebx, %eax
 100         movl 28(%esi), %ebx
 101         adcl %ebx, %eax
 102         lea 32(%esi), %esi
 103         dec %ecx
 104         jne 1b
 105         adcl $0, %eax
 106 2:      movl %edx, %ecx
 107         andl $0x1c, %edx
 108         je 4f
 109         shrl $2, %edx           # This clears CF
 110 3:      adcl (%esi), %eax
 111         lea 4(%esi), %esi
 112         dec %edx
 113         jne 3b
 114         adcl $0, %eax
 115 4:      andl $3, %ecx
 116         jz 7f
 117         cmpl $2, %ecx
 118         jb 5f
 119         movw (%esi),%cx
 120         leal 2(%esi),%esi
 121         je 6f
 122         shll $16,%ecx
 123 5:      movb (%esi),%cl
 124 6:      addl %ecx,%eax
 125         adcl $0, %eax
 126 7:
 127         testb $1, 12(%esp)
 128         jz 8f
 129         roll $8, %eax
 130 8:
 131         popl %ebx
 132         popl %esi
 133         ret
 134 ENDPROC(csum_partial)
 135
 136 #else
 137
 138 /* Version for PentiumII/PPro */
 139
 140 ENTRY(csum_partial)
 141         pushl %esi
 142         pushl %ebx
 143         movl 20(%esp),%eax      # Function arg: unsigned int sum
 144         movl 16(%esp),%ecx      # Function arg: int len
 145         movl 12(%esp),%esi      # Function arg: const unsigned char *buf
 146
 147         testl $3, %esi
 148         jnz 25f
 149 10:
 150         movl %ecx, %edx
 151         movl %ecx, %ebx
 152         andl $0x7c, %ebx
 153         shrl $7, %ecx
 154         addl %ebx,%esi
 155         shrl $2, %ebx
 156         negl %ebx
 157         lea 45f(%ebx,%ebx,2), %ebx
 158         testl %esi, %esi
 159         JMP_NOSPEC %ebx
 160
 161         # Handle 2-byte-aligned regions
 162 20:     addw (%esi), %ax
 163         lea 2(%esi), %esi
 164         adcl $0, %eax
 165         jmp 10b
 166 25:
 167         testl $1, %esi
 168         jz 30f
 169         # buf is odd
 170         dec %ecx
 171         jl 90f
 172         movzbl (%esi), %ebx
 173         addl %ebx, %eax
 174         adcl $0, %eax
 175         roll $8, %eax
 176         inc %esi
 177         testl $2, %esi
 178         jz 10b
 179
 180 30:     subl $2, %ecx
 181         ja 20b
 182         je 32f
 183         addl $2, %ecx
 184         jz 80f
 185         movzbl (%esi),%ebx      # csumming 1 byte, 2-aligned
 186         addl %ebx, %eax
 187         adcl $0, %eax
 188         jmp 80f
 189 32:
 190         addw (%esi), %ax        # csumming 2 bytes, 2-aligned
 191         adcl $0, %eax
 192         jmp 80f
 193
 194 40:
 195         addl -128(%esi), %eax
 196         adcl -124(%esi), %eax
 197         adcl -120(%esi), %eax
 198         adcl -116(%esi), %eax
 199         adcl -112(%esi), %eax
 200         adcl -108(%esi), %eax
 201         adcl -104(%esi), %eax
 202         adcl -100(%esi), %eax
 203         adcl -96(%esi), %eax
 204         adcl -92(%esi), %eax
 205         adcl -88(%esi), %eax
 206         adcl -84(%esi), %eax
 207         adcl -80(%esi), %eax
 208         adcl -76(%esi), %eax
 209         adcl -72(%esi), %eax
 210         adcl -68(%esi), %eax
 211         adcl -64(%esi), %eax
 212         adcl -60(%esi), %eax
 213         adcl -56(%esi), %eax
 214         adcl -52(%esi), %eax
 215         adcl -48(%esi), %eax
 216         adcl -44(%esi), %eax
 217         adcl -40(%esi), %eax
 218         adcl -36(%esi), %eax
 219         adcl -32(%esi), %eax
 220         adcl -28(%esi), %eax
 221         adcl -24(%esi), %eax
 222         adcl -20(%esi), %eax
 223         adcl -16(%esi), %eax
 224         adcl -12(%esi), %eax
 225         adcl -8(%esi), %eax
 226         adcl -4(%esi), %eax
 227 45:
 228         lea 128(%esi), %esi
 229         adcl $0, %eax
 230         dec %ecx
 231         jge 40b
 232         movl %edx, %ecx
 233 50:     andl $3, %ecx
 234         jz 80f
 235
 236         # Handle the last 1-3 bytes without jumping
 237         notl %ecx               # 1->2, 2->1, 3->0, higher bits are masked
 238         movl $0xffffff,%ebx     # by the shll and shrl instructions
 239         shll $3,%ecx
 240         shrl %cl,%ebx
 241         andl -128(%esi),%ebx    # esi is 4-aligned so should be ok
 242         addl %ebx,%eax
 243         adcl $0,%eax
 244 80:
 245         testb $1, 12(%esp)
 246         jz 90f
 247         roll $8, %eax
 248 90:
 249         popl %ebx
 250         popl %esi
 251         ret
 252 ENDPROC(csum_partial)
 253
 254 #endif
 255
 256 /*
 257 unsigned int csum_partial_copy_generic (const char *src, char *dst,
 258                                   int len, int sum, int *src_err_ptr, int *dst_err_ptr)
 259  */
 260
 261 /*
 262  * Copy from ds while checksumming, otherwise like csum_partial
 263  *
 264  * The macros SRC and DST specify the type of access for the instruction.
 265  * thus we can call a custom exception handler for all access types.
 266  *
 267  * FIXME: could someone double-check whether I haven't mixed up some SRC and
 268  *        DST definitions? It's damn hard to trigger all cases.  I hope I got
 269  *        them all but there's no guarantee.
 270  */
 271
 272 #define SRC(y...)                       \
 273         9999: y;                        \
 274         _ASM_EXTABLE(9999b, 6001f)
 275
 276 #define DST(y...)                       \
 277         9999: y;                        \
 278         _ASM_EXTABLE(9999b, 6002f)
 279
 280 #ifndef CONFIG_X86_USE_PPRO_CHECKSUM
 281
 282 #define ARGBASE 16
 283 #define FP              12
 284
 285 ENTRY(csum_partial_copy_generic)
 286         subl  $4,%esp
 287         pushl %edi
 288         pushl %esi
 289         pushl %ebx
 290         movl ARGBASE+16(%esp),%eax      # sum
 291         movl ARGBASE+12(%esp),%ecx      # len
 292         movl ARGBASE+4(%esp),%esi       # src
 293         movl ARGBASE+8(%esp),%edi       # dst
 294
 295         testl $2, %edi                  # Check alignment.
 296         jz 2f                           # Jump if alignment is ok.
 297         subl $2, %ecx                   # Alignment uses up two bytes.
 298         jae 1f                          # Jump if we had at least two bytes.
 299         addl $2, %ecx                   # ecx was < 2.  Deal with it.
 300         jmp 4f
 301 SRC(1:  movw (%esi), %bx        )
 302         addl $2, %esi
 303 DST(    movw %bx, (%edi)        )
 304         addl $2, %edi
 305         addw %bx, %ax
 306         adcl $0, %eax
 307 2:
 308         movl %ecx, FP(%esp)
 309         shrl $5, %ecx
 310         jz 2f
 311         testl %esi, %esi
 312 SRC(1:  movl (%esi), %ebx       )
 313 SRC(    movl 4(%esi), %edx      )
 314         adcl %ebx, %eax
 315 DST(    movl %ebx, (%edi)       )
 316         adcl %edx, %eax
 317 DST(    movl %edx, 4(%edi)      )
 318
 319 SRC(    movl 8(%esi), %ebx      )
 320 SRC(    movl 12(%esi), %edx     )
 321         adcl %ebx, %eax
 322 DST(    movl %ebx, 8(%edi)      )
 323         adcl %edx, %eax
 324 DST(    movl %edx, 12(%edi)     )
 325
 326 SRC(    movl 16(%esi), %ebx     )
 327 SRC(    movl 20(%esi), %edx     )
 328         adcl %ebx, %eax
 329 DST(    movl %ebx, 16(%edi)     )
 330         adcl %edx, %eax
 331 DST(    movl %edx, 20(%edi)     )
 332
 333 SRC(    movl 24(%esi), %ebx     )
 334 SRC(    movl 28(%esi), %edx     )
 335         adcl %ebx, %eax
 336 DST(    movl %ebx, 24(%edi)     )
 337         adcl %edx, %eax
 338 DST(    movl %edx, 28(%edi)     )
 339
 340         lea 32(%esi), %esi
 341         lea 32(%edi), %edi
 342         dec %ecx
 343         jne 1b
 344         adcl $0, %eax
 345 2:      movl FP(%esp), %edx
 346         movl %edx, %ecx
 347         andl $0x1c, %edx
 348         je 4f
 349         shrl $2, %edx                   # This clears CF
 350 SRC(3:  movl (%esi), %ebx       )
 351         adcl %ebx, %eax
 352 DST(    movl %ebx, (%edi)       )
 353         lea 4(%esi), %esi
 354         lea 4(%edi), %edi
 355         dec %edx
 356         jne 3b
 357         adcl $0, %eax
 358 4:      andl $3, %ecx
 359         jz 7f
 360         cmpl $2, %ecx
 361         jb 5f
 362 SRC(    movw (%esi), %cx        )
 363         leal 2(%esi), %esi
 364 DST(    movw %cx, (%edi)        )
 365         leal 2(%edi), %edi
 366         je 6f
 367         shll $16,%ecx
 368 SRC(5:  movb (%esi), %cl        )
 369 DST(    movb %cl, (%edi)        )
 370 6:      addl %ecx, %eax
 371         adcl $0, %eax
 372 7:
 373 5000:
 374
 375 # Exception handler:
 376 .section .fixup, "ax"
 377
 378 6001:
 379         movl ARGBASE+20(%esp), %ebx     # src_err_ptr
 380         movl $-EFAULT, (%ebx)
 381
 382         # zero the complete destination - computing the rest
 383         # is too much work
 384         movl ARGBASE+8(%esp), %edi      # dst
 385         movl ARGBASE+12(%esp), %ecx     # len
 386         xorl %eax,%eax
 387         rep ; stosb
 388
 389         jmp 5000b
 390
 391 6002:
 392         movl ARGBASE+24(%esp), %ebx     # dst_err_ptr
 393         movl $-EFAULT,(%ebx)
 394         jmp 5000b
 395
 396 .previous
 397
 398         popl %ebx
 399         popl %esi
 400         popl %edi
 401         popl %ecx                       # equivalent to addl $4,%esp
 402         ret
 403 ENDPROC(csum_partial_copy_generic)
 404
 405 #else
 406
 407 /* Version for PentiumII/PPro */
 408
 409 #define ROUND1(x) \
 410         SRC(movl x(%esi), %ebx  )       ;       \
 411         addl %ebx, %eax                 ;       \
 412         DST(movl %ebx, x(%edi)  )       ;
 413
 414 #define ROUND(x) \
 415         SRC(movl x(%esi), %ebx  )       ;       \
 416         adcl %ebx, %eax                 ;       \
 417         DST(movl %ebx, x(%edi)  )       ;
 418
 419 #define ARGBASE 12
 420
 421 ENTRY(csum_partial_copy_generic)
 422         pushl %ebx
 423         pushl %edi
 424         pushl %esi
 425         movl ARGBASE+4(%esp),%esi       #src
 426         movl ARGBASE+8(%esp),%edi       #dst
 427         movl ARGBASE+12(%esp),%ecx      #len
 428         movl ARGBASE+16(%esp),%eax      #sum
 429 #       movl %ecx, %edx
 430         movl %ecx, %ebx
 431         movl %esi, %edx
 432         shrl $6, %ecx
 433         andl $0x3c, %ebx
 434         negl %ebx
 435         subl %ebx, %esi
 436         subl %ebx, %edi
 437         lea  -1(%esi),%edx
 438         andl $-32,%edx
 439         lea 3f(%ebx,%ebx), %ebx
 440         testl %esi, %esi
 441         JMP_NOSPEC %ebx
 442 1:      addl $64,%esi
 443         addl $64,%edi
 444         SRC(movb -32(%edx),%bl) ; SRC(movb (%edx),%bl)
 445         ROUND1(-64) ROUND(-60) ROUND(-56) ROUND(-52)
 446         ROUND (-48) ROUND(-44) ROUND(-40) ROUND(-36)
 447         ROUND (-32) ROUND(-28) ROUND(-24) ROUND(-20)
 448         ROUND (-16) ROUND(-12) ROUND(-8)  ROUND(-4)
 449 3:      adcl $0,%eax
 450         addl $64, %edx
 451         dec %ecx
 452         jge 1b
 453 4:      movl ARGBASE+12(%esp),%edx      #len
 454         andl $3, %edx
 455         jz 7f
 456         cmpl $2, %edx
 457         jb 5f
 458 SRC(    movw (%esi), %dx         )
 459         leal 2(%esi), %esi
 460 DST(    movw %dx, (%edi)         )
 461         leal 2(%edi), %edi
 462         je 6f
 463         shll $16,%edx
 464 5:
 465 SRC(    movb (%esi), %dl         )
 466 DST(    movb %dl, (%edi)         )
 467 6:      addl %edx, %eax
 468         adcl $0, %eax
 469 7:
 470 .section .fixup, "ax"
 471 6001:   movl    ARGBASE+20(%esp), %ebx  # src_err_ptr
 472         movl $-EFAULT, (%ebx)
 473         # zero the complete destination (computing the rest is too much work)
 474         movl ARGBASE+8(%esp),%edi       # dst
 475         movl ARGBASE+12(%esp),%ecx      # len
 476         xorl %eax,%eax
 477         rep; stosb
 478         jmp 7b
 479 6002:   movl ARGBASE+24(%esp), %ebx     # dst_err_ptr
 480         movl $-EFAULT, (%ebx)
 481         jmp  7b
 482 .previous
 483
 484         popl %esi
 485         popl %edi
 486         popl %ebx
 487         ret
 488 ENDPROC(csum_partial_copy_generic)
 489
 490 #undef ROUND
 491 #undef ROUND1
 492
 493 #endif